Gets inter-character position closest to a specified point in the client area
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetCharPosFromXY ( $hWnd, $iX, $iY )
| $hWnd | Handle to the control |
| $iX | horizontal coordinate relative to left side of control |
| $iY | vertical coordinate relative to top of control |
| Success: | the 0-based character index of the character nearest the specified point (index of the character at the edge of the control if the specified point is beyond text). |
| Failure: | 0 and sets the @error flag to non-zero. |
| @error: | 101 - $hWnd is not a handle 102 - $iX is not a number 103 - $iY is not a number -1 - ($iX,$iY) outside client area |
_GUICtrlRichEdit_GetXYFromCharPos
Search EM_CHARFROMPOS in MSDN Library.
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>
Global $g_idLblMsg
Example()
Func Example()
Local $hGui, $iMsg, $aiPos, $idBtnNext, $hRichEdit, $iStep = 0
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$idBtnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState(@SW_SHOW)
_GUICtrlRichEdit_AppendText($hRichEdit, @CRLF & "This is appended text.")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
; GUIDelete() ; is OK too
Exit
Case $iMsg = $idBtnNext
$iStep += 1
Switch $iStep
Case 1
$aiPos = _GUICtrlRichEdit_GetXYFromCharPos($hRichEdit, 20)
Report("1.The coordinates of inter-character position 20 are (" & $aiPos[0] & "," & $aiPos[1] & ")")
Case 2
Report("2.The inter-character position at or nearest coordinates (" & $aiPos[0] & "," & $aiPos[1] & ")" & @CRLF & _
"is " & _GUICtrlRichEdit_GetCharPosFromXY($hRichEdit, $aiPos[0], $aiPos[1]))
GUICtrlSetState($idBtnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Example
Func Report($sMsg)
GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc ;==>Report