Checks a specified menu item and makes it a radio item
#include <GuiMenu.au3>
_GUICtrlMenu_CheckRadioItem ( $hMenu, $iFirst, $iLast, $iCheck [, $bByPos = True] )
| $hMenu | Handle of the menu |
| $iFirst | Identifier or position of the first menu item in the group |
| $iLast | Identifier or position of the last menu item in the group |
| $iCheck | Identifier or position of the menu item to check |
| $bByPos | [optional] Menu identifier flag: True - $iFirst, $iLast and $iCheck are a 0-based item position False - $iFirst, $iLast and $iCheck are a menu item identifier |
| Success: | True. |
| Failure: | False. |
This function sets the $MFT_RADIOCHECK type flag and the $MFS_CHECKED state for the item specified by $iCheck and, at the same time, clears both flags for all other items in the group. The checked item is displayed using a bullet bitmap instead of a check-mark bitmap.
Search CheckMenuRadioItem in MSDN Library.
#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>
Example()
Func Example()
Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idExit, $e_idCut, $e_idCopy, $e_idPaste, $e_idAbout
; Create GUI
$hGUI = GUICreate("Menu", 400, 300)
; Create File menu
$hFile = _GUICtrlMenu_CreateMenu()
_GUICtrlMenu_InsertMenuItem($hFile, 0, "&New", $e_idNew)
_GUICtrlMenu_InsertMenuItem($hFile, 1, "&Open", $e_idOpen)
_GUICtrlMenu_InsertMenuItem($hFile, 2, "&Save", $e_idSave)
_GUICtrlMenu_InsertMenuItem($hFile, 3, "", 0)
_GUICtrlMenu_InsertMenuItem($hFile, 4, "E&xit", $e_idExit)
; Create Edit menu
$hEdit = _GUICtrlMenu_CreateMenu()
_GUICtrlMenu_InsertMenuItem($hEdit, 0, "&Cut", $e_idCut)
_GUICtrlMenu_InsertMenuItem($hEdit, 1, "C&opy", $e_idCopy)
_GUICtrlMenu_InsertMenuItem($hEdit, 2, "&Paste", $e_idPaste)
; Create Help menu
$hHelp = _GUICtrlMenu_CreateMenu()
_GUICtrlMenu_InsertMenuItem($hHelp, 0, "&About", $e_idAbout)
; Create Main menu
$hMain = _GUICtrlMenu_CreateMenu()
_GUICtrlMenu_InsertMenuItem($hMain, 0, "&File", 0, $hFile)
_GUICtrlMenu_InsertMenuItem($hMain, 1, "&Edit", 0, $hEdit)
_GUICtrlMenu_InsertMenuItem($hMain, 2, "&Help", 0, $hHelp)
; Set window menu
_GUICtrlMenu_SetMenu($hGUI, $hMain)
GUISetState(@SW_SHOW)
; Check Open menu item
_GUICtrlMenu_CheckRadioItem($hFile, 0, 4, 2)
; Loop until the user exits.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>Example