Sets the state of the specified menu item's check mark attribute to either selected or clear
#include <GuiMenu.au3>
_GUICtrlMenu_CheckMenuItem ( $hMenu, $iItem [, $bCheck = True [, $bByPos = True]] )
| $hMenu | Handle of the menu |
| $iItem | Identifier or position of the menu item to check |
| $bCheck | [optional] True to set the check mark, False to remove it |
| $bByPos | [optional] Menu identifier flag: True - $iItem is a 0-based item position False - $iItem is a menu item identifier |
| Success: | the previous state of the menu item (either $MF_CHECKED or $MF_UNCHECKED). |
| Failure: | -1. |
An item in a menu bar cannot have a check mark. The $iItem parameter identifies a item that opens a submenu or a command item.
For an item that opens a submenu, the $Item parameter must specify the position of the item.
For a command item, the $Item parameter can specify either the item's position or its identifier.
Search CheckMenuItem in MSDN Library.
#include <GUIConstantsEx.au3>
#include <GuiMenu.au3>
Example()
Func Example()
Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idExit, $e_idCut, $e_idCopy, $e_idPaste, $e_idAbout
; Create GUI
$hGUI = GUICreate("Menu", 400, 300)
; Create File menu
$hFile = _GUICtrlMenu_CreateMenu()
_GUICtrlMenu_InsertMenuItem($hFile, 0, "&New", $e_idNew)
_GUICtrlMenu_InsertMenuItem($hFile, 1, "&Open", $e_idOpen)
_GUICtrlMenu_InsertMenuItem($hFile, 2, "&Save", $e_idSave)
_GUICtrlMenu_InsertMenuItem($hFile, 3, "", 0)
_GUICtrlMenu_InsertMenuItem($hFile, 4, "E&xit", $e_idExit)
; Create Edit menu
$hEdit = _GUICtrlMenu_CreateMenu()
_GUICtrlMenu_InsertMenuItem($hEdit, 0, "&Cut", $e_idCut)
_GUICtrlMenu_InsertMenuItem($hEdit, 1, "C&opy", $e_idCopy)
_GUICtrlMenu_InsertMenuItem($hEdit, 2, "&Paste", $e_idPaste)
; Create Help menu
$hHelp = _GUICtrlMenu_CreateMenu()
_GUICtrlMenu_InsertMenuItem($hHelp, 0, "&About", $e_idAbout)
; Create Main menu
$hMain = _GUICtrlMenu_CreateMenu()
_GUICtrlMenu_InsertMenuItem($hMain, 0, "&File", 0, $hFile)
_GUICtrlMenu_InsertMenuItem($hMain, 1, "&Edit", 0, $hEdit)
_GUICtrlMenu_InsertMenuItem($hMain, 2, "&Help", 0, $hHelp)
; Set window menu
_GUICtrlMenu_SetMenu($hGUI, $hMain)
GUISetState(@SW_SHOW)
; Check About menu item
_GUICtrlMenu_CheckMenuItem($hHelp, 0)
; Loop until the user exits.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>Example