Function Reference

_GUICtrlHeader_GetItemFormat

Returns the format of the item

#include <GuiHeader.au3>
_GUICtrlHeader_GetItemFormat ( $hWnd, $iIndex )

Parameters

$hWnd Handle to the control
$iIndex 0-based item index

Return Value

Returns the item format:
    HDF_CENTER - The item's contents are centered
    HDF_LEFT - The item's contents are left-aligned.
    HDF_RIGHT - The item's contents are right-aligned.
    HDF_BITMAP - The item displays a bitmap.
    HDF_BITMAP_ON_RIGHT - The bitmap appears to the right of text.
    HDF_OWNERDRAW - The control's owner draws the item.
    HDF_STRING - The item displays a string.
    HDF_IMAGE - Display an image from an image list
    HDF_RTLREADING - Text will read in the opposite direction
    HDF_SORTDOWN - Draw a down-arrow on this item
    HDF_SORTUP - Draw an up-arrow on this item

Related

_GUICtrlHeader_SetItemFormat

Example

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>
#include <GuiImageList.au3>
#include <WinAPIGdi.au3>

Global $g_idMemo

Example()

Func Example()
        Local $hGUI, $hHeader, $hImage

        ; Create GUI
        $hGUI = GUICreate("Header", 400, 300)
        $hHeader = _GUICtrlHeader_Create($hGUI)
        _GUICtrlHeader_SetUnicodeFormat($hHeader, True)
        $g_idMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
        GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
        GUISetState(@SW_SHOW)

        ; Create an image list with images
        $hImage = _GUIImageList_Create(11, 11)
        _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 11, 11))
        _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 11, 11))
        _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 11, 11))
        _GUICtrlHeader_SetImageList($hHeader, $hImage)

        ; Add columns
        _GUICtrlHeader_AddItem($hHeader, "Column 0", 100, 0, 0)
        _GUICtrlHeader_AddItem($hHeader, "Column 1", 100, 0, 1)
        _GUICtrlHeader_AddItem($hHeader, "Column 2", 100, 0, 2)
        _GUICtrlHeader_AddItem($hHeader, "Column 3", 100)

        ; Set column 0 format
        _GUICtrlHeader_SetItemFormat($hHeader, 0, BitOR($HDF_CENTER, $HDF_STRING))

        ; Show column 0 format
        MemoWrite("Column 0 format: " & "0x" & Hex(_GUICtrlHeader_GetItemFormat($hHeader, 0)))

        Sleep(1000)

        ; Set column 0 format
        _GUICtrlHeader_SetItemFormat($hHeader, 0, BitOR($HDF_LEFT, $HDF_STRING, $HDF_IMAGE))

        ; Show column 0 format
        MemoWrite("Column 0 format: " & "0x" & Hex(_GUICtrlHeader_GetItemFormat($hHeader, 0)))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Write a line to the memo control
Func MemoWrite($sMessage)
        GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite