Function Reference

_GUICtrlComboBoxEx_SetItem

Sets some or all of a item's attributes

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetItem ( $hWnd, $sText [, $iIndex = 0 [, $iImage = -1 [, $iSelectedImage = -1 [, $iOverlayImage = -1 [, $iIndent = -1 [, $iParam = -1]]]]]] )

Parameters

$hWnd Handle to the control
$sText Item text. See remark.
$iIndex [optional] The 0-based index of the item
$iImage [optional] 0-based index of the item's icon in the control's image list
$iSelectedImage [optional] 0-based index of the item's icon in the control's image list
$iOverlayImage [optional] 0-based index of the item's icon in the control's image list
$iIndent [optional] Number of image widths to indent the item. A single indentation equals the width of an image.
$iParam [optional] Value specific to the item

Return Value

Success: True.
Failure: False.

Remarks

If a notification callback is needed, you have to specify $sText = -1 (LPSTR_TEXTCALLBACK).

Related

_GUICtrlComboBoxEx_GetItem, _GUICtrlComboBoxEx_SetItemEx

Example

#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>

Global $g_idMemo

Example()

Func Example()
        Local $hGUI, $hImage, $aItem, $hCombo

        ; Create GUI
        $hGUI = GUICreate("ComboBoxEx Get/Set Item (v" & @AutoItVersion & ")", 400, 300)
        $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
        $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
        GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
        GUISetState(@SW_SHOW)

        $hImage = _GUIImageList_Create(16, 16, 5, 3)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
        _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

        For $x = 0 To 8
                _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : string", $x), $x, $x)
        Next

        ;Set Item indent
        _GUICtrlComboBoxEx_SetItemIndent($hCombo, 1, 1)

        $aItem = _GUICtrlComboBoxEx_GetItem($hCombo, 1)
        MemoWrite("Item Text : " & $aItem[0])
        MemoWrite("Item Len ..........................: " & $aItem[1])
        MemoWrite("# image widths to indent ..........: " & $aItem[2])
        MemoWrite("0-based item image index .......: " & $aItem[3])
        MemoWrite("0-based item state image index .: " & $aItem[4])
        MemoWrite("0-based item image overlay index: " & $aItem[5])
        MemoWrite("Item application defined value ....: " & $aItem[6])

        ; Change item 1
        MsgBox($MB_SYSTEMMODAL, "Information", "Changing item 1")
        _GUICtrlComboBoxEx_SetItem($hCombo, "New Item 1", 1)

        ; show drop down
        _GUICtrlComboBoxEx_ShowDropDown($hCombo, True)

        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Write a line to the memo control
Func MemoWrite($sMessage)
        GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite