Select a string in the list of a ComboBox
#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetCurSel ( $hWnd [, $iIndex = -1] )
| $hWnd | Handle to the control |
| $iIndex | [optional] Specifies the 0-based index of the string to select |
| Success: | True. |
| Failure: | False. |
If $iIndex is –1, any current selection in the list is removed and the edit control is cleared.
If $iIndex is greater than the number of items in the list or if $iIndex is –1, the return value is -1 and the selection is cleared.
#include <GuiComboBoxEx.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
Example()
Func Example()
; Create GUI
Local $hGUI = GUICreate("ComboBoxEx Get/Set Cur Sel (v" & @AutoItVersion & ")", 400, 300)
Local $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100, BitOR($CBS_SIMPLE, $WS_VSCROLL, $WS_BORDER))
GUISetState(@SW_SHOW)
Local $hImage = _GUIImageList_Create(16, 16, 5, 3)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
_GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
_GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
_GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)
_GUICtrlComboBoxEx_InitStorage($hCombo, 100, 320)
_GUICtrlComboBoxEx_BeginUpdate($hCombo)
For $x = 0 To 99
_GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : string", $x), Random(0, 8, 1), Random(0, 8, 1), Random(0, 8, 1))
Next
_GUICtrlComboBoxEx_EndUpdate($hCombo)
; Set Cur Sel
_GUICtrlComboBoxEx_SetCurSel($hCombo, Random(0, 99, 1))
; Get Cur Sel
MsgBox($MB_SYSTEMMODAL, "Information", "Current Sel: " & _GUICtrlComboBoxEx_GetCurSel($hCombo))
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>Example