Disabled dummy control reacts on accelerators

[Synix <cross.fire@…>]

I noticed that in previous versions (3.3.12.0) $GUI_DISABLE didn't have any effect on accelerators. This is fixed in the beta, but unfortunately not completely.
Testing 3.3.13.19, $GUI_DISABLE disables accelerators for controls like buttons, but not for dummy controls.

This should not work:

#include <GUIConstantsEx.au3>

GUICreate("Hit Enter in this GUI")
$idDummy = GUICtrlCreateDummy()
GUICtrlSetState($idDummy, $GUI_DISABLE)
Global $aArray[1][2] = [["{ENTER}", $idDummy]]
GUISetAccelerators($aArray)
GUISetState()

While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			Exit
		Case $idDummy
			MsgBox(0, "Dummy", "Entered")
	EndSwitch
WEnd

Another thing that I think should not be possible and may be related to this is GUICtrlSendToDummy:
GUICtrlSendToDummy() triggers events on disabled dummy controls, which I guess shouldn't be possible as well.

[Melba23]

What you are actually saying is that Dummy controls do not honour the $GUI_* states. Which does not surprise me in the slightest as I imagine that they are but a simple entry in the internal AutoIt control array, and do not exist as far as Windows is concerned so there is nothing on which Windows can apply the state.

It seems to me that if you want to "disable/enable" dummy controls then you need to delete/recreate them as necessary.

M23

[Synix <cross.fire@…>]

But I can use and work with GUICtrlSetState and GUICtrlGetState on Dummy Controls without any problems o.O

[Synix <cross.fire@…>]

Quick example:

#include <GUIConstantsEx.au3>

GUICreate("Hit Enter in this GUI")
$idButton = GUICtrlCreateButton("hit me", 5, 5)
$idDummy = GUICtrlCreateDummy()
Global $aArray[1][2] = [["{ENTER}", $idDummy]]
GUISetAccelerators($aArray)
GUISetState()

While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			Exit
		Case $idButton
			If BitAND(GUICtrlGetState($idDummy), $GUI_DISABLE) = $GUI_DISABLE Then
				GUICtrlSetState($idDummy, $GUI_ENABLE)
			Else
				GUICtrlSetState($idDummy, $GUI_DISABLE)
			EndIf
			MsgBox(0, "", "Dummy state is " & (BitAND(GUICtrlGetState($idDummy), $GUI_DISABLE) = $GUI_DISABLE ? "disabled" : "enabled"))
	EndSwitch
WEnd

I guess the dummy control always should have the same behaviour as its native counterparts. That's why I reported the wrong behavior from my first example.

[Melba23]

Point made.

M23

[Jpm]

Hi,
It works for me with current release
Cheers

[mLipok]

Confirmed.
Tested with modified script:

#include <GUIConstantsEx.au3>

_Example()

Func _Example()
        GUICreate("Hit Enter in this GUI")
        Local $idDummy = GUICtrlCreateDummy()
        Local $aArray[1][2] = [["{F10}", $idDummy]]
        GUICtrlSetState($idDummy, $GUI_DISABLE)
        GUISetAccelerators($aArray)
        GUISetState()

        While 1
                Switch GUIGetMsg()
                        Case $GUI_EVENT_CLOSE
                                Exit
                        Case $idDummy
                                If BitAND(GUICtrlGetState($idDummy), $GUI_DISABLE) = $GUI_DISABLE Then
                                        GUICtrlSetState($idDummy, $GUI_ENABLE)
                                Else
                                        GUICtrlSetState($idDummy, $GUI_DISABLE)
                                EndIf
                                MsgBox(0, "", "Dummy state is " & (BitAND(GUICtrlGetState($idDummy), $GUI_DISABLE) = $GUI_DISABLE ? "disabled" : "enabled"))
                EndSwitch
        WEnd
EndFunc   ;==>_Example