Add CryptGenRandom Function to Crypt.au3 UDF

[wraithdu]

Here's the function:

; #FUNCTION# ===================================================================
; Name...........: _Crypt_GenRandom
; Description ...: Fill a buffer with cryptographically random data.
; Syntax.........: _Crypt_GenRandom($pBuffer, $iSize)
; Parameters ....: $pBuffer - Pointer to buffer to fill with random data.
;                  $iSize - Size of the buffer pointed to by $pBuffer.
; Return values .: Success - Returns True
;                  Failure - Returns False and sets @error.
; Author ........: Erik Pilsits (wraithdu)
; Modified ......:
; Remarks .......: 
; Related .......: 
; Link ..........: @@MsdnLink@@ CryptGenRandom
; Example .......: Yes
; ==============================================================================
Func _Crypt_GenRandom($pBuffer, $iSize)
    _Crypt_Startup()
    Local $aRet = DllCall(__Crypt_DllHandle(), "bool", "CryptGenRandom", "handle", __Crypt_Context(), "dword", $iSize, "ptr", $pBuffer)
    Local $nError = @error
    _Crypt_Shutdown()
    If $nError Or (Not $aRet[0]) Then
        Return SetError(1, 0, False)
    Else
        Return True
    EndIf
EndFunc   ;==>_Crypt_GenRandom

[TicketCleanup]

Automatic ticket cleanup.

[wraithdu]

I goofed a parameter. The first parameter should be $pBuffer.

Also this should be added to the Remarks:

MSDN notes about the buffer: Optionally, the application can fill this buffer with data to use as an auxiliary random seed.

[wraithdu]

Example:

#include <Crypt.au3>
; generate 16 bytes of random data
Local $buff = DllStructCreate("byte[16]")
_Crypt_GenRandom(DllStructGetPtr($buff), DllStructGetSize($buff))
MsgBox(0, "Random data:", DllStructGetData($buff, 1))

[AdmiralAlkex]

Whoever commits this need to remove the DllStructGetPtr() and fix the dll call.

Seems okay otherwise, so I'm assigning it to me and giving you a few days to comment if there's anything else.

[guinness]

What was the outcome of this?

[AdmiralAlkex]

This ticket is referenced in revision: [7512]

[AdmiralAlkex]

This ticket is referenced in revision: [7513]

[AdmiralAlkex]

Added by revision [7514] in version: 3.3.9.5

[AdmiralAlkex]

Replying to guinness:

What was the outcome of this?

The Vogons did it.