_StringProper

[Xenobiologist]

The func will only work this letters [a-zA-Z]. There are languages which use something like öäü.

Func _StringProper($s_Str)
	Local $iX = 0
	Local $CapNext = 1
	Local $s_nStr = ""
	Local $s_CurChar
	For $iX = 1 To StringLen($s_Str)
		$s_CurChar = StringMid($s_Str, $iX, 1)
		Select
			Case $CapNext = 1
				If StringRegExp($s_CurChar, '[a-zA-Z]') Then
					$s_CurChar = StringUpper($s_CurChar)
					$CapNext = 0
				EndIf
			Case Not StringRegExp($s_CurChar, '[a-zA-Z]')
				$CapNext = 1
			Case Else
				$s_CurChar = StringLower($s_CurChar)
		EndSelect
		$s_nStr &= $s_CurChar
	Next
	Return ($s_nStr)
EndFunc   ;==>_StringProper

Mega

[TicketCleanup]

Automatic ticket cleanup.

[Valik]

I think that \b may be useful here for finding word start positions so that the letter can be passed to StringUpper(). Just something to think about for whoever tries to fix this.

[Jos]

Replying to Valik:

I think that \b may be useful here for finding word start positions so that the letter can be passed to StringUpper(). Just something to think about for whoever tries to fix this.

Changing the test to this seems to work fine:
StringRegExp($s_CurChar, '[a-zA-ZÀ-ÿ"]')

Does anybody see any issues with that ?

Whole new UDF:

Func _StringProper($s_Str)
	Local $iX = 0
	Local $CapNext = 1
	Local $s_nStr = ""
	Local $s_CurChar
	For $iX = 1 To StringLen($s_Str)
		$s_CurChar = StringMid($s_Str, $iX, 1)
		Select
			Case $CapNext = 1
				If StringRegExp($s_CurChar, '[a-zA-ZÀ-ÿ"]') Then
					$s_CurChar = StringUpper($s_CurChar)
					$CapNext = 0
				EndIf
			Case Not StringRegExp($s_CurChar, '[a-zA-ZÀ-ÿ]')
				$CapNext = 1
			Case Else
				$s_CurChar = StringLower($s_CurChar)
		EndSelect
		$s_nStr &= $s_CurChar
	Next
	Return ($s_nStr)
EndFunc   ;==>_StringProper

[Jos]

See a extra DoubleQuote slipped into the first regex. should be:

If StringRegExp($s_CurChar, '[a-zA-ZÀ-ÿ]') Then

[Jpm]

Replying to Jos:

See a extra DoubleQuote slipped into the first regex. should be:

If StringRegExp($s_CurChar, '[a-zA-ZÀ-ÿ]') Then

only people using šœž or Ÿ will have objections

[Jos]

Replying to Jpm:

Replying to Jos:

See a extra DoubleQuote slipped into the first regex. should be:

If StringRegExp($s_CurChar, '[a-zA-ZÀ-ÿ]') Then

only people using šœž or Ÿ will have objections

Ok, have added those 4 characters too. next will commit the update.

[Jos]

Fixed in version: 3.2.11.2