#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
        GUICreate("TreeView Get ImageList Icon Handle (v" & @AutoItVersion & ")", 400, 300)

        Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
        Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
        GUISetState(@SW_SHOW)

        Local $hImage = _GUIImageList_Create(16, 16, 5, 3)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
        _GUICtrlTreeView_SetNormalImageList($idTreeView, $hImage)

        _GUICtrlTreeView_BeginUpdate($idTreeView)
        Local $ahItem[6]
        For $x = 0 To _GUIImageList_GetImageCount($hImage) - 1
                $ahItem[$x] = _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] New Item", $x), $x, $x)
        Next
        _GUICtrlTreeView_EndUpdate($idTreeView)

        Local $hRandomImage = 4;Random(0, _GUIImageList_GetImageCount($hImage) - 1, 1)
        MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("ImageList Icon Handle for Image %d: %s", $hRandomImage, _GUICtrlTreeView_GetImageListIconHandle($idTreeView, $hRandomImage)))
        _GUICtrlTreeView_SelectItem($idTreeView, $ahItem[4])

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
EndFunc   ;==>Example