Indicates whether the item is expanded
#include <GuiTreeView.au3>
_GUICtrlTreeView_GetExpanded ( $hWnd, $hItem )
| $hWnd | Control ID/Handle to the control |
| $hItem | Handle to the item |
| True: | item is expanded. |
| False: | item is not expanded. |
#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
Example()
Func Example()
GUICreate("TreeView Get Expanded (v" & @AutoItVersion & ")", 400, 300)
Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
GUISetState(@SW_SHOW)
_GUICtrlTreeView_BeginUpdate($idTreeView)
Local $aidItem[6]
For $x = 0 To UBound($aidItem) - 1
$aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $idTreeView)
For $y = 0 To 2
GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $y), $aidItem[$x])
Next
Next
_GUICtrlTreeView_EndUpdate($idTreeView)
Local $hRandomItem = Random(0, UBound($aidItem) - 1, 1)
MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item %d Expanded? %s", $hRandomItem, _GUICtrlTreeView_GetExpanded($idTreeView, $aidItem[$hRandomItem])))
_GUICtrlTreeView_Expand($idTreeView, $aidItem[$hRandomItem])
MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item %d Expanded? %s", $hRandomItem, _GUICtrlTreeView_GetExpanded($idTreeView, $aidItem[$hRandomItem])))
; Loop until the user exits.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example