Returns the bounding rectangle for a tree item
#include <GuiTreeView.au3>
_GUICtrlTreeView_DisplayRectEx ( $hWnd, $hItem [, $bTextOnly = False] )
| $hWnd | Control ID/Handle to the control |
| $hItem | Handle to the item whose rectangle will be returned |
| $bTextOnly | [optional] If the True, the bounding rectangle includes only the text of the item. Otherwise, it includes the entire line that the item occupies. |
| Success: | a $tagRECT structure that holds the bounding rectangle. The coordinates are relative to the upper left corner of the control. |
| Failure: | sets the @error flag to non-zero. |
$tagRECT, _GUICtrlTreeView_DisplayRect
#AutoIt3Wrapper_UseX64=y
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
Example()
Func Example()
GUICreate("TreeView Display RectEx (v" & @AutoItVersion & ")", 400, 300)
Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
GUISetState(@SW_SHOW)
; Set ANSI format
;~ _GUICtrlTreeView_SetUnicodeFormat($idTreeView, False)
Local $hImage = _GUIImageList_Create(16, 16, 5, 3)
_GUIImageList_AddIcon($hImage, "shell32.dll", 110)
_GUIImageList_AddIcon($hImage, "shell32.dll", 131)
_GUIImageList_AddIcon($hImage, "shell32.dll", 165)
_GUIImageList_AddIcon($hImage, "shell32.dll", 168)
_GUIImageList_AddIcon($hImage, "shell32.dll", 137)
_GUIImageList_AddIcon($hImage, "shell32.dll", 146)
_GUICtrlTreeView_SetNormalImageList($idTreeView, $hImage)
Local $aidItem[6]
For $x = 0 To _GUIImageList_GetImageCount($hImage) - 1
$aidItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $idTreeView)
Next
Local $tRECT = _GUICtrlTreeView_DisplayRectEx($idTreeView, $aidItem[2])
MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item 2 Rectangle : [%d, %d, %d, %d]", DllStructGetData($tRECT, "Left"), _
DllStructGetData($tRECT, "Top"), DllStructGetData($tRECT, "Right"), DllStructGetData($tRECT, "Bottom")))
_GUICtrlTreeView_SelectItem($idTreeView, $aidItem[2])
; Loop until the user exits.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example