Adds a new item
#include <GuiTreeView.au3>
_GUICtrlTreeView_AddChild ( $hWnd, $hParent, $sText [, $iImage = -1 [, $iSelImage = -1]] )
| $hWnd | Control ID/Handle to the control |
| $hParent | Parent item |
| $sText | Text of the item |
| $iImage | [optional] 0-based index of the item's icon in the control's image list |
| $iSelImage | [optional] 0-based index of the item's icon in the control's image list |
| Success: | the handle to the new item. |
| Failure: | 0. |
The item is added as a child of $hParent. It is added to the end of $hParent's list of child items.
If the control is sorted, this function inserts the item in the correct sort order position, rather than as the last child of $hParent.
_GUICtrlTreeView_AddChildFirst
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>
Example()
Func Example()
GUICreate("TreeView Add Child (v" & @AutoItVersion & ")", 400, 300)
Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
GUISetState(@SW_SHOW)
Local $hImage = _GUIImageList_Create(16, 16, 5, 3)
_GUIImageList_AddIcon($hImage, "shell32.dll", 110)
_GUIImageList_AddIcon($hImage, "shell32.dll", 131)
_GUIImageList_AddIcon($hImage, "shell32.dll", 165)
_GUIImageList_AddIcon($hImage, "shell32.dll", 168)
_GUIImageList_AddIcon($hImage, "shell32.dll", 137)
_GUIImageList_AddIcon($hImage, "shell32.dll", 146)
_GUICtrlTreeView_SetNormalImageList($idTreeView, $hImage)
_GUICtrlTreeView_BeginUpdate($idTreeView)
Local $hItem, $iImage
For $x = 0 To 4
$iImage = Random(0, 5, 1)
$hItem = _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] New Item", $x), $iImage, $iImage)
For $y = 0 To 3
$iImage = Random(0, 5, 1)
_GUICtrlTreeView_AddChild($idTreeView, $hItem, StringFormat("[%02d] New Child", $y), $iImage, $iImage)
Next
Next
_GUICtrlTreeView_EndUpdate($idTreeView)
; Loop until the user exits.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example