Sets the padding control
#include <GuiToolbar.au3>
_GUICtrlToolbar_SetPadding ( $hWnd, $iCX, $iCY )
| $hWnd | Handle to the control |
| $iCX | The horizontal padding, in pixels |
| $iCY | The vertical padding, in pixels |
The padding values are used to create a blank area between the edge of the button and the button's image and/or text.
The horizontal padding value is applied to both the right and left of the button and the vertical padding value is applied to both the top and bottom of the button.
Padding is only applied to buttons that have the $BTNS_AUTOSIZE style.
#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>
Global $g_idMemo
Example()
Func Example()
Local $hGUI, $hToolbar, $aPad
Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp
; Create GUI
$hGUI = GUICreate("Toolbar", 400, 300)
$hToolbar = _GUICtrlToolbar_Create($hGUI)
$g_idMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
GUISetState(@SW_SHOW)
; Add standard system bitmaps
Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
Case 0
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
Case 2
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
EndSwitch
; Add buttons
_GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
_GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
_GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)
; Set control padding
_GUICtrlToolbar_SetPadding($hToolbar, 2, 3)
; Show control padding
$aPad = _GUICtrlToolbar_GetPadding($hToolbar)
MemoWrite("Horizontal padding : " & $aPad[0])
MemoWrite("Vertical padding ..: " & $aPad[1])
; Loop until the user exits.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>Example
; Write message to memo
Func MemoWrite($sMessage = "")
GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite