Retrieves a string from the string pool
#include <GuiToolbar.au3>
_GUICtrlToolbar_GetString ( $hWnd, $iIndex )
| $hWnd | Handle to the control |
| $iIndex | Index of the string |
This message returns the specified string from the control's string pool. It does not necessarily correspond to the text string currently being displayed by a button.
To retrieve a button's current text string, send use _GUICtrlToolbar_GetButtonText().
_GUICtrlToolbar_AddString, _GUICtrlToolbar_GetButtonText
#include "Extras\HelpFileInternals.au3"
#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsStylesConstants.au3>
Example()
Func Example()
; Create GUI
Local $hGUI = GUICreate("Toolbar Get String (v" & @AutoItVersion & ")", 400, 300)
Local $hToolbar = _GUICtrlToolbar_Create($hGUI)
_MemoCreate(2, 45, 396, 262, $WS_VSCROLL)
GUISetState(@SW_SHOW)
; Set ANSI format
;~ _GUICtrlToolbar_SetUnicodeFormat($hToolbar, False)
; Add standard system bitmaps
Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
Case 0
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
Case 2
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
EndSwitch
; Add strings
Local $aStrings[4]
$aStrings[0] = _GUICtrlToolbar_AddString($hToolbar, "&New")
$aStrings[1] = _GUICtrlToolbar_AddString($hToolbar, "&Open")
$aStrings[2] = _GUICtrlToolbar_AddString($hToolbar, "&Save")
$aStrings[3] = _GUICtrlToolbar_AddString($hToolbar, "&Help")
; Add buttons
Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idHelp
_GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW, $aStrings[0])
_GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN, $aStrings[1])
_GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE, $aStrings[2])
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $e_idHelp, $STD_HELP, $aStrings[3])
; Get string 2 text
_MemoWrite("String 2 text .: " & _GUICtrlToolbar_GetString($hToolbar, 2))
; Loop until the user exits.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>Example