Retrieves information about the state of the specified button
#include <GuiToolbar.au3>
_GUICtrlToolbar_GetButtonState ( $hWnd, $iCommandID )
| $hWnd | Handle to the control |
| $iCommandID | Button command ID |
| Success: | Button state. Can be one or more of the following $TBSTATE_CHECKED - The button has the $TBSTYLE_CHECK style and is being clicked $TBSTATE_PRESSED - The button is being clicked $TBSTATE_ENABLED - The button accepts user input $TBSTATE_HIDDEN - The button is not visible and cannot receive user input $TBSTATE_INDETERMINATE - The button is grayed $TBSTATE_WRAP - The button is followed by a line break $TBSTATE_ELLIPSES - The button's text is cut off and an ellipsis is displayed $TBSTATE_MARKED - The button is marked |
| Failure: | -1. |
_GUICtrlToolbar_SetButtonState
#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>
Global $g_idMemo
Example()
Func Example()
; Create GUI
Local $hGUI = GUICreate("Toolbar Get/Set Button State (v" & @AutoItVersion & ")", 400, 300)
Local $hToolbar = _GUICtrlToolbar_Create($hGUI)
$g_idMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
GUISetState(@SW_SHOW)
; Add standard system bitmaps
Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
Case 0
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
Case 2
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
EndSwitch
; Add buttons
Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp
_GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
_GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
_GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)
; Show Save button state
MemoWrite("Save button state: " & _GUICtrlToolbar_GetButtonState($hToolbar, $e_idSave))
Sleep(1000)
; Set Save button state
Local $bBalloon = _GUICtrlToolbar_SetButtonState($hToolbar, $e_idSave, BitOR($TBSTATE_ENABLED, $TBSTATE_PRESSED))
MemoWrite("Set button state: " & $bBalloon)
; Show Save button state
MemoWrite("Save button state: " & _GUICtrlToolbar_GetButtonState($hToolbar, $e_idSave))
; Loop until the user exits.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>Example
; Write message to memo
Func MemoWrite($sMessage = "")
GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite