Function Reference

_GUICtrlToolbar_EnableButton

Enables or disables the specified button

#include <GuiToolbar.au3>
_GUICtrlToolbar_EnableButton ( $hWnd, $iCommandID [, $bEnable = True] )

Parameters

$hWnd Handle to the control
$iCommandID Button command ID
$bEnable [optional] Enable flag:
    True - Button will be enabled
    False - Button will be disabled

Return Value

Success: True.
Failure: False.

Related

_GUICtrlToolbar_HideButton

Example

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
        Local $hGUI, $hToolbar
        Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

        ; Create GUI
        $hGUI = GUICreate("Toolbar", 400, 300)
        $hToolbar = _GUICtrlToolbar_Create($hGUI)
        GUISetState(@SW_SHOW)

        ; Add standard system bitmaps
        _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

        ; Add buttons
        _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
        _GUICtrlToolbar_AddButtonSep($hToolbar)
        _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

        ; Disable Help button
        _GUICtrlToolbar_EnableButton($hToolbar, $idHelp, False)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example