Function Reference

_GUICtrlTab_SetExtendedStyle

Sets the extended styles that are currently in use

#include <GuiTab.au3>
_GUICtrlTab_SetExtendedStyle ( $hWnd, $iStyle )

Parameters

$hWnd Control ID/Handle to the control
$iStyle Extended styles currently in use:
    $TCS_EX_FLATSEPARATORS - The control will draw separators between the tab items
    $TCS_EX_REGISTERDROP - The control generates TCN_GETOBJECT notification messages to request a drop target object when an object is dragged over the tab items.

Return Value

Returns the previous extended styles.

Related

_GUICtrlTab_GetExtendedStyle

Example

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
        ; Create GUI
        GUICreate("Tab Get/Set Extended Style (v" & @AutoItVersion & ")", 400, 300)
        Local $idTab = GUICtrlCreateTab(2, 2, 396, 296, BitOR($TCS_BUTTONS, $TCS_FLATBUTTONS))
        GUISetState(@SW_SHOW)

        ; Add tabs
        _GUICtrlTab_InsertItem($idTab, 0, "Tab 0")
        _GUICtrlTab_InsertItem($idTab, 1, "Tab 1")
        _GUICtrlTab_InsertItem($idTab, 2, "Tab 2")

        ; Get/Set extended styles
        _GUICtrlTab_SetExtendedStyle($idTab, $TCS_EX_FLATSEPARATORS)
        MsgBox($MB_SYSTEMMODAL, "Information", "Extended styles: 0x" & Hex(_GUICtrlTab_GetExtendedStyle($idTab)))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
EndFunc   ;==>Example