Function Reference

_GUICtrlTab_GetItemText

Retrieves the text of a tab

#include <GuiTab.au3>
_GUICtrlTab_GetItemText ( $hWnd, $iIndex )

Parameters

$hWnd Control ID/Handle to the control
$iIndex 0-based item index

Return Value

Returns the tab text.

Related

_GUICtrlTab_SetItemText

Example

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
        ; Create GUI
        GUICreate("Tab Control Get/Set Item Text (v" & @AutoItVersion & ")", 400, 300)
        Local $idTab = GUICtrlCreateTab(2, 2, 396, 296)
        GUISetState(@SW_SHOW)

        ; Add tabs
        _GUICtrlTab_InsertItem($idTab, 0, "Tab 0")
        _GUICtrlTab_InsertItem($idTab, 1, "Tab 1")
        _GUICtrlTab_InsertItem($idTab, 2, "Tab 2")

        ; Get/Set tab 0 text
        _GUICtrlTab_SetItemText($idTab, 0, "New Text")
        MsgBox($MB_SYSTEMMODAL, "Information", "Tab 0 text: " & _GUICtrlTab_GetItemText($idTab, 0))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
EndFunc   ;==>Example