Function Reference

_GUICtrlMonthCal_SetMonthDelta

Sets the scroll rate for a month calendar control

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_SetMonthDelta ( $hWnd, $iDelta )

Parameters

$hWnd Control ID/Handle to the control
$iDelta Value representing the number of months to be set as the control's scroll rate.
If this value is zero, the month delta is reset to the default which is the number of months displayed in the control.

Return Value

Returns an INT value that represents the previous scroll rate.

Related

_GUICtrlMonthCal_GetMonthDelta

Example

#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
        ; Create GUI
        GUICreate("Month Calendar Get/Set Month Delta (v" & @AutoItVersion & ")", 420, 300)
        Local $idMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, BitOR($WS_BORDER, $MCS_MULTISELECT), 0x00000000)

        ; Create memo control
        $g_idMemo = GUICtrlCreateEdit("", 4, 168, 412, 128, 0)
        GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
        GUISetState(@SW_SHOW)

        ; Get/Set month delta
        _GUICtrlMonthCal_SetMonthDelta($idMonthCal, 2)
        MemoWrite("Month delta: " & _GUICtrlMonthCal_GetMonthDelta($idMonthCal))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
EndFunc   ;==>Example

; Write message to memo
Func MemoWrite($sMessage)
        GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite