Function Reference

_GUICtrlListBox_GetSelItems

Fills a buffer with an array of selected items

#include <GuiListBox.au3>
_GUICtrlListBox_GetSelItems ( $hWnd )

Parameters

$hWnd Control ID/Handle to the control

Return Value

Returns an array with the following format:
    [0] - Total items in array
    [1] - Index of the selected item
    [2] - Index of the selected item
    [n] - Index of the selected item

Related

_GUICtrlListBox_GetSelItemsText

Example

#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
        Local $sItems, $aItems, $idListBox

        ; Create GUI
        GUICreate("List Box Get Sel Items", 400, 296)
        $idListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($LBS_STANDARD, $LBS_EXTENDEDSEL))
        GUISetState(@SW_SHOW)

        ; Add strings
        _GUICtrlListBox_BeginUpdate($idListBox)
        For $iI = 1 To 9
                _GUICtrlListBox_AddString($idListBox, StringFormat("%03d : Random string", Random(1, 100, 1)))
        Next
        _GUICtrlListBox_EndUpdate($idListBox)

        ; Select a few items
        _GUICtrlListBox_SetSel($idListBox, 3)
        _GUICtrlListBox_SetSel($idListBox, 4)
        _GUICtrlListBox_SetSel($idListBox, 5)

        ; Get indexes of selected items
        $aItems = _GUICtrlListBox_GetSelItems($idListBox)
        For $iI = 1 To $aItems[0]
                If $iI > 1 Then $sItems &= ", "
                $sItems &= $aItems[$iI]
        Next
        MsgBox($MB_SYSTEMMODAL, "Information", "Items Selected: " & $sItems)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
EndFunc   ;==>Example