Function Reference

_GUICtrlListBox_GetSelCount

Retrieves the total number of selected items

#include <GuiListBox.au3>
_GUICtrlListBox_GetSelCount ( $hWnd )

Parameters

$hWnd Control ID/Handle to the control

Return Value

Success: the count of selected items.
Failure: -1 if Control ID/Handle is invalid.

Example

#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
        Local $idListBox

        ; Create GUI
        GUICreate("List Box Get Sel Count", 400, 296)
        $idListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($LBS_STANDARD, $LBS_EXTENDEDSEL))
        GUISetState(@SW_SHOW)

        ; Add strings
        _GUICtrlListBox_BeginUpdate($idListBox)
        For $iI = 1 To 9
                _GUICtrlListBox_AddString($idListBox, StringFormat("%03d : Random string", Random(1, 100, 1)))
        Next
        _GUICtrlListBox_EndUpdate($idListBox)

        ; Select a few items
        _GUICtrlListBox_SetSel($idListBox, 3)
        _GUICtrlListBox_SetSel($idListBox, 4)
        _GUICtrlListBox_SetSel($idListBox, 5)

        ; Show the item selection count
        MsgBox($MB_SYSTEMMODAL, "Information", "Items Selected: " & _GUICtrlListBox_GetSelCount($idListBox))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
EndFunc   ;==>Example