Function Reference

_GUICtrlListBox_GetCount

Retrieves the number of items

#include <GuiListBox.au3>
_GUICtrlListBox_GetCount ( $hWnd )

Parameters

$hWnd Control ID/Handle to the control

Return Value

Success: the number of items in the list box.
Failure: -1.

Example

#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
        Local $idListBox

        ; Create GUI
        GUICreate("List Box Get Count", 400, 296)
        $idListBox = GUICtrlCreateList("", 2, 2, 396, 296)

        GUISetState(@SW_SHOW)

        ; Add strings
        _GUICtrlListBox_BeginUpdate($idListBox)
        For $iI = 1 To 9
                _GUICtrlListBox_AddString($idListBox, StringFormat("%03d : Random string", Random(1, 100, 1)))
        Next
        _GUICtrlListBox_EndUpdate($idListBox)

        ; Get item count
        MsgBox($MB_SYSTEMMODAL, "Information", "Item count: " & _GUICtrlListBox_GetCount($idListBox))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
EndFunc   ;==>Example