Retrieves the length, in characters, of a line
#include <GuiEdit.au3>
_GUICtrlEdit_LineLength ( $hWnd [, $iIndex = -1] )
| $hWnd | Control ID/Handle to the control |
| $iIndex | [optional] Specifies the 0-based line index of the line whose length is to be retrieved |
| Success: | the length, in TCHARs, of the line specified by the $iIndex parameter. |
| Failure: | 0, if $iIndex is greater than the number of characters in the control. |
$iIndex = –1 specifies the current line number (the line that contains the caret).
#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>
Example()
Func Example()
Local $hStatusBar, $idEdit, $hGUI
Local $sWow64 = ""
If @AutoItX64 Then $sWow64 = "\Wow6432Node"
Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"
Local $aPartRightSide[2] = [378, -1], $iRandom
; Create GUI
$hGUI = GUICreate("Edit Line Length", 400, 300)
$idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
$hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
_GUICtrlStatusBar_SetIcon($hStatusBar, 1, 97, "shell32.dll")
GUISetState(@SW_SHOW)
; Set Margins
_GUICtrlEdit_SetMargins($idEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)
; Set Text
_GUICtrlEdit_SetText($idEdit, FileRead($sFile))
; Line Length
$iRandom = Random(0, 7, 1)
_GUICtrlStatusBar_SetText($hStatusBar, "Length: " & _GUICtrlEdit_LineLength($idEdit, $iRandom) & " chars on Line Index: " & $iRandom)
; Loop until the user exits.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example