Draw an arc
#include <GDIPlus.au3>
_GDIPlus_GraphicsDrawArc ( $hGraphics, $nX, $nY, $nWidth, $nHeight, $fStartAngle, $fSweepAngle [, $hPen = 0] )
| $hGraphics | Handle to a Graphics object |
| $nX | The X coordinate of the upper left corner of the rectangle that bounds the ellipse in which to draw the arc |
| $nY | The Y coordinate of the upper left corner of the rectangle that bounds the ellipse in which to draw the arc |
| $nWidth | The width of the rectangle that bounds the ellipse in which to draw the arc |
| $nHeight | The height of the rectangle that bounds the ellipse in which to draw the arc |
| $fStartAngle | The angle between the X axis and the starting point of the arc |
| $fSweepAngle | The angle between the starting and ending points of the arc |
| $hPen | [optional] Handle to a pen object that is used to draw the arc. If 0, a solid black pen with a width of 1 will be used. |
| Success: | True. |
| Failure: | False and sets the @error flag to non-zero, @extended may contain GPSTATUS error code ($GPIP_ERR* see GPIPlusConstants.au3). |
Search GdipDrawArc in MSDN Library.
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
Example()
Func Example()
Local $hGUI, $hGraphic
; Create GUI
$hGUI = GUICreate("GDI+", 400, 300)
GUISetState(@SW_SHOW)
; Draw arcs
_GDIPlus_Startup()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
_GDIPlus_GraphicsDrawArc($hGraphic, 160, 100, 10, 10, 180, 360)
_GDIPlus_GraphicsDrawArc($hGraphic, 180, 100, 10, 10, 180, 360)
_GDIPlus_GraphicsDrawArc($hGraphic, 160, 104, 30, 30, 160, -140)
_GDIPlus_GraphicsDrawArc($hGraphic, 140, 80, 70, 70, 180, 360)
; Loop until the user exits.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
; Clean up resources
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_Shutdown()
EndFunc ;==>Example
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
Example()
Func Example()
_GDIPlus_Startup() ;initialize GDI+
Local Const $iWidth = 600, $iHeight = 600, $iBgColor = 0x303030 ;$iBGColor format RRGGBB
Local $hGUI = GUICreate("GDI+ Example (" & @ScriptName & ")", $iWidth, $iHeight) ;create a test GUI
GUISetBkColor($iBgColor, $hGUI) ;set GUI background color
GUISetState(@SW_SHOW)
;create buffered graphics frame set for smoother gfx object movements
Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI) ;create a graphics object from a window handle
_GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ;sets the graphics object rendering quality (antialiasing)
Local $hPen = _GDIPlus_PenCreate(0xFFFF8080, 32) ;color format AARRGGBB (hex)
_GDIPlus_GraphicsDrawArc($hGraphics, 100.5, 100.5, 400.25, 400.25, -45.5, 270.5, $hPen)
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
;cleanup GDI+ resources
_GDIPlus_PenDispose($hPen)
_GDIPlus_GraphicsDispose($hGraphics)
_GDIPlus_Shutdown()
GUIDelete($hGUI)
EndFunc ;==>Example