Function Reference

_Date_Time_FileTimeToArray

Decode a file time to an array

#include <Date.au3>
_Date_Time_FileTimeToArray ( ByRef $tFileTime )

Parameters

$tFileTime $tagFILETIME structure

Return Value

Returns an array with the following format:
    [0] - Month
    [1] - Day
    [2] - Year
    [3] - Hour
    [4] - Minutes
    [5] - Seconds
    [6] - Milliseconds
    [7] - Day of week

Related

$tagFILETIME

Example

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
        Local $tFile, $aFile, $sFile

        ; Create GUI
        GUICreate("Time", 400, 300)
        $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
        GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
        GUISetState(@SW_SHOW)

        ; Encode a file time
        $tFile = _Date_Time_EncodeFileTime(@MON, @MDAY, @YEAR, @HOUR, @MIN, @SEC)
        $aFile = _Date_Time_FileTimeToArray($tFile)
        $sFile = StringFormat("%02d/%02d/%04d %02d:%02d:%02d", $aFile[0], $aFile[1], $aFile[2], $aFile[3], $aFile[4], $aFile[5])
        MemoWrite("Current date/time .: " & $sFile)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Write a line to the memo control
Func MemoWrite($sMessage)
        GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite