Server 2022 @OSVersion returns WIN_2019

[anonymous]

Server 2022 was recently released just wanted to bring it to your attention. @OSVersion tested on beta 3.3.15.4

[mLipok]

btw.
Can anyone test it on Windows 11 as well ?

[J-Paul Mesnage]

Hi,
as I don't have access to server 2022,
can you give me the msgbox result of the following script.
For the time being the MSDN doc does not describe the corresponding value.
For Win11 perhaps we need to wait October 5th
Thanks for the help

; Dec, Int, Number Constants
Global Const $NUMBER_AUTO = 0
Global Const $NUMBER_32BIT = 1
Global Const $NUMBER_64BIT = 2
Global Const $NUMBER_DOUBLE = 3

Global Const $tagOSVERSIONINFO = 'struct;dword OSVersionInfoSize;dword MajorVersion;dword MinorVersion;dword BuildNumber;dword PlatformId;wchar CSDVersion[128];endstruct'

ConsoleWrite('Windows version: ' & _WinAPI_GetVersion() & @CRLF)

Func _WinAPI_GetVersion()
	Local $tOSVI = DllStructCreate($tagOSVERSIONINFO)
	DllStructSetData($tOSVI, 1, DllStructGetSize($tOSVI))

	Local $aCall = DllCall('kernel32.dll', 'bool', 'GetVersionExW', 'struct*', $tOSVI)
	If @error Or Not $aCall[0] Then Return SetError(@error, @extended, 0)

	MsgBox(0, "OSVERSIONINFO", "MajorVersion = " &DllStructGetData($tOSVI, "MajorVersion") & @CRLF & _
			"MinorVersion = " &DllStructGetData($tOSVI, "MinorVersion") & @CRLF & _
			"BuildNumber = " &DllStructGetData($tOSVI, "BuildNumber"))

	Return Number(DllStructGetData($tOSVI, "MajorVersion") & "." & DllStructGetData($tOSVI, "MinorVersion"), $NUMBER_DOUBLE)
EndFunc   ;==>_WinAPI_GetVersion

[mLipok]

Replying to Jpm:

For Win11 perhaps we need to wait October 5th

Time was ticking and oops it's today.

Windows 11 gives me such results:

MajorVersion = 10
MinorVersion = 0
BuildNumber = 22000

​https://www.autoitscript.com/forum/topic/206774-windows11autoit-chat-room-for-experience-exchange/?do=findComment&comment=1490352

[J-Paul Mesnage]

Thanks for Win11
Please post the same for Server 2022

[mLipok]

Going to download:
​https://www.microsoft.com/en-us/evalcenter/evaluate-windows-server-2022
And use HyperV to test it

[mLipok]

Results on Windows2022

[mLipok]

This was tested on:
Windows Server 2022 Datacenter Evaluation
MajorVersion = 10
MinorVersion = 0
BuildNumber = 20348

[J-Paul Mesnage]

Thanks
Fix sent to Jon

[Jon]

Added by revision [12627] in version: 3.3.15.5

[mLipok]

For future testing purposes, I am posting a revised test script here:

#AutoIt3Wrapper_Change2CUI=y
; Dec, Int, Number Constants
Global Const $NUMBER_AUTO = 0
Global Const $NUMBER_32BIT = 1
Global Const $NUMBER_64BIT = 2
Global Const $NUMBER_DOUBLE = 3

Global Const $tagOSVERSIONINFO = "struct;dword OSVersionInfoSize;dword MajorVersion;dword MinorVersion;dword BuildNumber;dword PlatformId;wchar CSDVersion[128];endstruct"

Global $sInformation = _
                "AutoIt version: " & @AutoItVersion & @CRLF & _
                "Windows version: " & _WinAPI_GetVersion() & @CRLF & "  Build: " & @extended & @CRLF & _
                "@OSVersion: " & @OSVersion & @CRLF & _
                "@OSType: " & @OSType & @CRLF & _
                ""

ConsoleWrite($sInformation & @CRLF)
ClipPut($sInformation)

Func _WinAPI_GetVersion()
        Local $tOSVI = DllStructCreate($tagOSVERSIONINFO)
        DllStructSetData($tOSVI, 1, DllStructGetSize($tOSVI))

        Local $aCall = DllCall('kernel32.dll', 'bool', 'GetVersionExW', 'struct*', $tOSVI)
        If @error Or Not $aCall[0] Then Return SetError(@error, @extended, 0)

        MsgBox(0, "OSVERSIONINFO", "MajorVersion = " & DllStructGetData($tOSVI, "MajorVersion") & @CRLF & _
                        "MinorVersion = " & DllStructGetData($tOSVI, "MinorVersion") & @CRLF & _
                        "BuildNumber = " & DllStructGetData($tOSVI, "BuildNumber"))

        Return SetError(0, Number(DllStructGetData($tOSVI, "BuildNumber")), Number(DllStructGetData($tOSVI, "MajorVersion") & "." & DllStructGetData($tOSVI, "MinorVersion"), $NUMBER_DOUBLE))
EndFunc   ;==>_WinAPI_GetVersion

This is related to discussion from here:
​https://www.autoitscript.com/forum/topic/207634-autoit-v33155-beta/?do=findComment&comment=1497796

My current results are:

AutoIt version: 3.3.15.5
Windows version: 10
	Build: 22000
@OSVersion: UNKNOWN
@OSType: WIN32_NT