Com error in _IEAttach with embedded IE

[Nine]

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <IE.au3>

$oIE = _IECreateEmbedded ()
GUICreate("Embedded Web control Test", 640, 580)
GUICtrlCreateObj($oIE, 10, 40, 600, 360)
GUISetState()
_IENavigate ($oIE, "http://www.autoitscript.com")
$oIEatt = _IEAttach ("Embedded","embedded")
MsgBox ($MB_SYSTEMMODAL,"",IsObj ($oIEatt))
$oObj = _IETagNameGetCollection ($oIEatt, "li")
MsgBox ($MB_SYSTEMMODAL,"",$oObj.length)

While 1
        Switch GUIGetMsg()
                Case $GUI_EVENT_CLOSE
                        ExitLoop
        EndSwitch
WEnd

Ends up with a COM error :

"C:\Program Files (x86)\AutoIt3\Include\IE.au3" (3066) : ==> The requested action with this object has failed.:
Return $oIE.Document.parentwindow
Return $oIE.Document ^ERROR

But if you remove .Document.parentwindow from the Func IEControlGetObjFromHWND () it works fine...

[mLipok]

There is many work done in IE.au3 UDF in the background, which stuck because of documenting, given changes.

To solve this problem please try to change in function:
IEControlGetObjFromHWND()

this last few lines in the following way:

        If IsObj($aRet[4]) Then
                Local $oIE = $aRet[4].Script()
                ; $oIE is now a valid IDispatch object
                If ObjName($oIE, $OBJ_NAME) = 'HTMLWindow2' Then Return $oIE
                Local $oDocument = $oIE.Document
                If @error then Return SetError(@error, @extended, 0)
                Return $oDocument.parentwindow
        Else
                Return SetError(1, $aRet[0], 0)
        EndIf
EndFunc   ;==>__IEControlGetObjFromHWND

And back with results.

[Nine]

Working :)

[mLipok]

Fixed by revision [12331] in version: 3.3.15.4