Adding a sort of _IEAttributeGet function to IE.UDF

[j0kky]

There is no way to get the "class" (or other kind of) attribute value of an element using only IE Management UDF.
It can be solved just adding a simple function as:

Line
1	#include <IE.au3>
2
3	_Example()
4
5	Func _Example()
6	Local $oIE = _IECreate("www.autoitscript.com")
7	Local $oBody = $oIE.document.body
8	ConsoleWrite('! "Class" = ' & _IEAttributeGet($oBody, "class") & @CRLF)
9	EndFunc ;==>_Example
10
11	Func _IEAttributeGet($obj, $attr)
12	Return $obj.GetAttribute($attr)
13	EndFunc ;==>_IEAttributeGet
14

[mLipok]

Here is my proposal:

Line
1	#include <IE.au3>
2
3	_Example()
4
5	Func _Example()
6	Local $oIE = _IECreate("www.autoitscript.com")
7	Local $oElement = $oIE.document.body
8	ConsoleWrite('! "Class" = ' & _IEAttributeGet($oElement, "class") & @CRLF)
9	EndFunc ;==>_Example
10
11	Func _IEAttributeGet(ByRef $oObject, $sAttributeName)
12	If Not IsObj($oObject) Then
13	__IEConsoleWriteError("Error", "_IEPropertyGet", "$_IESTATUS_InvalidDataType")
14	Return SetError($_IESTATUS_InvalidDataType, 1, 0)
15	ElseIf Not __IEIsObjType($oObject, "browserdom") Then
16	__IEConsoleWriteError("Error", "_IEPropertyGet", "$_IESTATUS_InvalidObjectType")
17	Return SetError($_IESTATUS_InvalidObjectType, 2, 0)
18	ElseIf __IEIsObjType($oObject, "browser") Or __IEIsObjType($oObject, "document") Or __IEIsObjType($oObject, "documentcontainer") Then
19	__IEConsoleWriteError("Error", "_IEPropertyGet", "$_IESTATUS_InvalidObjectType")
20	Return SetError($_IESTATUS_InvalidObjectType, 3, 0)
21	Else
22	Local $sAttributeValue = $oObject.GetAttribute($sAttributeName)
23	If @error Then
24	Return SetError($_IESTATUS_NoMatch, 4, 0)
25	Else
26	Return SetError($_IESTATUS_Success, 0, $sAttributeValue)
27	EndIf
28	EndIf
29	EndFunc ;==>_IEAttributeGet