Enter text string longer than 256 characters in InputBox?

[Evolutionnext]

I control my Autoit script with a handheld QR-code reader, that contains specific commands in the text. It enters these as one text string (like keyboard entry) and then presses ENTER.

 

The problem I have is, that the text is longer than 256 characters, so InputBox truncates it. Is there a way to extend the limit or ose another form of entry, without having to enter fragments of the text separately (which the barcode reader can not do)?

[Musashi]

16 minutes ago, Evolutionnext said:

The problem I have is, that the text is longer than 256 characters, so InputBox truncates it

Does it have to be an InputBox, or would  GUICtrlCreateInput  also be possible ?

[Danyfirex]

You could probably use a custom inputbox here.

 

 

Saludos

 

[spudw2k]

I don't seem to have the 256 char limit; seems to be about 30000 characters. 

What version of AutoIt are you using?  Are you able to post a reproducer script so we can take a look?

 

[Musashi]

At least in version 3.3.14.0 , which I (still) use, characters will be truncated.

Local $sAnswer = InputBox("Input :", "QR-Code-Reader :", "", "", 600, 150)

; String to paste :
 ;1111111111111111111111111111111111111111111111112222222222222222222222222222222222222222222222222233333333333333333333333333333333333333333333333333444444444444444444444444444444444444444444444444445555555555555555555555555555555555555555555555555566666666666666666666666666666666666666666666666666777777777777777777777777777777777777777777777777778888888888888888888888888888888888888888888888888899999999999999999999999999999999999999999999999999

MsgBox(4096, "InputBox Result :", $sAnswer)
ConsoleWrite($sAnswer & @CRLF)
ConsoleWrite("Length Answer = " & StringLen($sAnswer) & @CRLF)

 

[pixelsearch]

As just wrote Musashi, the resulting string returned by InputBox is truncated when too long.
You can probably type thousands of characters in the InputBox (I pasted 50 times "1234567890 " which is 50*11 length because of the space I added to separate the blocks, so it was 550 characters typed) and they where all in the box when controlling them (ctrl + right key moved from one block to the other, stop at 49, manually controlled the last one was 50th)

But look at the result after validation :

So max returned seems to be 255 (not 256 as stipulated by OP or 254 as read in the help file)
ConsoleWrite also indicates 255. Tested on AutoIt 3.3.14.5  &  3.3.16.0

ConsoleWrite(">> StringLen($sResult) = " & StringLen($sResult) & @crlf)
>> StringLen($sResult) = 255

 

Edited March 10, 2022 by pixelsearch

[Musashi]

43 minutes ago, pixelsearch said:

So max returned seems to be 255 (not 256 as stipulated by OP or 254 as read in the help file)

Yes, I can confirm that as well .

Since you also tested it with the latest versions of AutoIt, I am a bit surprised that @spudw2k wrote :

5 hours ago, spudw2k said:

I don't seem to have the 256 char limit; seems to be about 30000 characters.

[pixelsearch]

Maybe he didn't test the return value, but only the fact he could paste much more than 255 in the box ?

He'll tell us... maybe 

[Melba23]

Hi,

Have you tried using _GUICtrlEdit_SetLimitText to set a higher limit? An input control is just a single-line edit control.

M23

[pixelsearch]

Hi M23,
Great idea. Let me try that on an InputBox, especially I already tried it successfully since 2018 in an edit control in RegExpQuickTester (LazyCat + w0uter + mLipok for preventing CPU overheat) :

; 26 dec 2018 : replaced GUICtrlSendMsg($ebTest, $EM_LIMITTEXT, -1, 0) from 5 nov 2018, with _GUICtrlEdit_SetLimitText($ebTest, -1)

; GUICtrlSendMsg($ebTest, $EM_LIMITTEXT, -1, 0)   ; added to allow unlimited text size in edit control : ini file won't store this control anymore, a separate txt file will.
_GUICtrlEdit_SetLimitText($ebTest, -1) ; 26 dec 2018, seems better than precedent

 

[pixelsearch]

I tried M23's idea with no success : how to retrieve the InputBox handle when InputBox is a blocking function ?

I couldn't use AdlibRegister for that reason. As _GUICtrlEdit_SetLimitText requires a Control ID/Handle, it didn't work for me. Maybe someone will have another idea, that would be great !

The solution is probably to forget InputBox and use an input control, as suggested in several preceding posts.

Edited March 10, 2022 by pixelsearch

[Musashi]

16 minutes ago, pixelsearch said:

I tried M23's idea with no success : how to retrieve the InputBox handle when InputBox is a blocking function ?

I couldn't use AdlibRegister for that reason. As _GUICtrlEdit_SetLimitText requires a Control ID/Handle, it didn't work for me. Maybe someone will have another idea, that would be great !

The solution is probably to forget InputBox and use an input control, as suggested in several preceding posts.

I came to the same conclusion but was not brave enough to write it . With controls like GUICtrlCreateInput you have a handle/controlID and can use _GUICtrlEdit_SetLimitText without problems. With InputBox this corresponding access is missing (but I don't want to exclude that experts know a workaround for this).

[pixelsearch]

Martin's script looks very interesting to check "live" what's currently being typed inside InputBox

That guy often delivers nice scripts... well, that's the reason why they are MVPs 

Edited March 10, 2022 by pixelsearch
typo

[Melba23]

Hi,

Quote

I came to the same conclusion but was not brave enough to write it

Do not be afraid to say something in these cases - I am neither omniscient nor prone to retaliation!

M23

[pixelsearch]

Based on Martin's script, 330 char's returned, but well... not sure it's worthwhile to complicate it like this, when a simple input control would do it without timers & the whole register gang :

; Based on Martin's script :
; https://www.autoitscript.com/forum/topic/71070-inputbox-tecting-changes/?tab=comments#comment-520293

Global $answer2
Local $handle = DllCallbackRegister("_ReadIPBox", "int", "")
Local $SetTimer = DllCall("User32.dll", "int", "SetTimer", _
    "hwnd", 0, "int", 0, "int", 500, "ptr", DllCallbackGetPtr($handle))[0]

Local $answer = InputBox("Question", "Where were you born?", "Planet Earth")

DllCallbackFree($handle)
DllCall("user32.dll", "int", "KillTimer", "hwnd", 0, "int", $SetTimer)

MsgBox(0, "InputBox 'fake return' (len = " & StringLen($answer2) & ")", $answer2)

;================
Func _ReadIPBox()
    If WinExists("Question") Then
        $answer2 = ControlCommand("Question","Where were you born?","Edit1","GetLine", 1)
        ; ConsoleWrite($answer2 & @CRLF)
    EndIf
EndFunc

Edited March 10, 2022 by pixelsearch

[Nine]

Here another way to interact with an input box :

#include <WinAPISys.au3>
#include <GuiEdit.au3>
#include <WinAPIConstants.au3>
#include <WinAPIProc.au3>

Example()

Func Example()
  Local $hProc = DllCallbackRegister(CbtHookProc, "int", "int;int;int")
  Global $hHook = _WinAPI_SetWindowsHookEx($WH_CBT, DllCallbackGetPtr($hProc), 0, _WinAPI_GetCurrentThreadId())
  Local $iRet = InputBox("Test", "Test")
  ConsoleWrite(StringLen($iRet) & @CRLF)
  _WinAPI_UnhookWindowsHookEx($hHook)
  DllCallbackFree($hProc)
EndFunc   ;==>Example

Func CbtHookProc($nCode, $wParam, $lParam)
  If $nCode = 5 Then ; 5=HCBT_ACTIVATE
    $hWnd = HWnd($wParam)
    ControlSetText($hWnd, "", "Static1", "Cooler stuff here")
    ControlSetText($hWnd, "", "Button1", "Alright now")
    ControlSetText($hWnd, "", "Button2", "Forget it !")
    $hCtrl = ControlGetHandle($hWnd, "", "Edit1")
    ConsoleWrite($hWnd & "/" & $hCtrl & @CRLF)
    _GUICtrlEdit_SetLimitText($hCtrl, 500)     ; does not work
  EndIf
  Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
EndFunc   ;==>CbtHookProc

As you can see, we can modify pretty much everything we want, except the text limit (although the informations are exact as per au3info ).  Which makes me say, that AutoIt truncates it to 255 characters (maybe because of its buffer size).  It is in fact 256 (not 255) because you need to have a chr(0) at the end. 

[pixelsearch]

That's impressive, bravo Nine 
I've never been "hooked" on this hook chain (it seems complicated !) but see how it allows to do great things in your script. I really should try it on some personal examples.

If I got it right, it's not Jon's limitation, but that limitation of 255 chars seem to come directly from Microsoft InputBox, see what their link indicates concerning InputBox :

The text box accepts only 255 characters. The return string is truncated to 254 characters

Strange MS indicates 254 characters too, when all tests return 255 valid chars (as in my very 1st pic far above)

Edited March 10, 2022 by pixelsearch

[Nine]

Yes you are right, that is a MS limitation (sorry AutoIt). 

Hooks are quite fun.  You can achieve many things very elegantly since it based on event notifications. 

In fact, I just tested another way, very cool result (using your previous idea)

Func CbtHookProc($nCode, $wParam, $lParam)
  If $nCode = 5 Then ; 5=HCBT_ACTIVATE
    $hWnd = HWnd($wParam)
    ControlSetText($hWnd, "", "Static1", "Cooler stuff here")
    ControlSetText($hWnd, "", "Button1", "Alright now")
    ControlSetText($hWnd, "", "Button2", "Forget it !")
    $hCtrl = ControlGetHandle($hWnd, "", "Edit1")
    ConsoleWrite($hWnd & "/" & $hCtrl & @CRLF)
    _GUICtrlEdit_SetLimitText($hCtrl, 500)     ; does not work
  ElseIf $nCode = 4 Then ; HCBT_DESTROYWND
    $hWnd = HWnd($wParam)
    ConsoleWrite(StringLen(ControlGetText($hWnd, "" ,"Edit1")) & @CRLF) ; works perfect when user clicks OK
  EndIf
  Return _WinAPI_CallNextHookEx($hHook, $nCode, $wParam, $lParam)
EndFunc   ;==>CbtHookProc

Edited March 10, 2022 by Nine

[pixelsearch]

I added 2 lines 

ElseIf $nCode = 0 And @WDAY = 5 Then
    Return 1 ; no move/resize on Thursday's

 

[spudw2k]

18 hours ago, pixelsearch said:

Maybe he didn't test the return value, but only the fact he could paste much more than 255 in the box ?

He'll tell us... maybe 

Ah, yes.  I assumed the limitation with filling the edit control.  The result is indeed truncated to 255 characters.  Interesting behavior.  ControlGetText and _GUICTrlEdit_GetText seem to work fine.  I wonder what method is being used to return the value.