_GUICtrlListView_ClickItem issue ?

[pixelsearch]

Hi everybody
In the script below, this is what happens when you click the Button :
1) If the horizontal scrollbar was on the left side, then all is good.
2) If the horizontal scrollbar was moved to the middle (or to the right) then the GUI disappears in the background after you clicked the button.

#include <GuiListView.au3>
#include <GuiConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 400)

$idListView = GUICtrlCreateListView("Col0|Col1|Col2|Col3|Col4|Col5|Col6|Col7|Col8|Col9", 10, 10, 480, 300)
For $i = 0 To 9
    _GUICtrlListView_SetColumnWidth($idListView, $i, 200)
Next
$idItem = GUICtrlCreateListViewItem("0|1|2|3|4|5|6|7|8|9", $idListview)

$idButton = GUICtrlCreateButton("Click me", 200, 340, 85, 25)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop

        Case $idButton ; click when scrollbar is on left, then with scrollbar on right
            _GUICtrlListView_ClickItem($idListView, 0)
    EndSwitch
WEnd

GUIDelete($hGui)

Is it a known behavior of _GUICtrlListView_ClickItem ?
Thanks

[spudw2k]

Interesting behaviour.  It appears the way the function works is by finding the rectangle area of the indexed item, then clicking in the center of it.  You can see that when you drag the slider to the right as you described, the rectangle area is outside of the window area--if you change the mouse move parameter to true you can see exactly where it is clicking.  Behind the scenes, the MouseMove parameter always moves the mouse there to click, then moves it back if the parameter is False.

As a workaround, I would suggest using ControlFocus & _GUICtrlListView_SetItemSelected; you might also have to use EnsureVisible. 

If you absolutely have to click it then you might have to get a little creative and get the item rectangle coordinates, but instead of clicking the X position, just click the Y position and reference the control X position.

 

[pixelsearch]

Thanks @spudw2k for the confirmation, It's hard to believe it never happened to anyone else during all these years.
I faced this issue in this post 3 days ago. As the problem appeared after having added a ghost column 0 at the left of the LV in a complicated script, then it wasn't easy to know what was the exact cause.

Before presenting the simple script above, I did this to debug :

Script "2u", search "a" (for example), context menu "Show all rows" => F3 to start the search

Modify function _GUICtrlListView_ClickItem() in a COPY of GuiListView.au3
Insert a ConsoleWrite between each of its lines :

Func _GUICtrlListView_ClickItem($hWnd, $iIndex, $sButton = "left", $bMove = False, $iClicks = 1, $iSpeed = 1)
    If Not IsHWnd($hWnd) Then $hWnd = GUICtrlGetHandle($hWnd)

    ConsoleWrite("1  " & WinActive("[ACTIVE]") & @crlf)
    _GUICtrlListView_EnsureVisible($hWnd, $iIndex, False)
    ConsoleWrite("2  " & WinActive("[ACTIVE]") & @crlf)
    Local $tRECT = _GUICtrlListView_GetItemRectEx($hWnd, $iIndex, $LVIR_LABEL)
    ConsoleWrite("3  " & WinActive("[ACTIVE]") & @crlf)
    Local $tPoint = _WinAPI_PointFromRect($tRECT, True)
etc...

Launch script "2u"

Horizontal Scrollbar on the left, Console display :

1  0x02070622
2  0x02070622
3  0x02070622
4  0x02070622
5  0x02070622
6  0x02070622
7  0x02070622
8  0x02070622
9  0x02070622
10 0x02070622
11 0x02070622
12 0x02070622
13 0x02070622
14 0x02070622
15 0x02070622
16 0x02070622

Horizontal Scrollbar on the right, Console display :

1  0x02070622
2  0x02070622
3  0x02070622
4  0x02070622
5  0x02070622
6  0x02070622
7  0x02070622
8  0x02070622
9  0x02070622
10 0x02070622
11 0x02070622
12 0x006F04FC => change of handle, GUI is no more the active window
13 0x006F04FC
14 0x006F04FC
15 0x006F04FC
16 0x006F04FC

So issue happens between step 11 and 12 when F3 is pressed and Horizontal Scrollbar is on the right (GUI is no more the active window)
In the function _GUICtrlListView_ClickItem(), the line between step 11 and 12 is :

MouseClick($sButton, $iX, $iY, $iClicks, $iSpeed)

I added just after it :

ConsoleWrite("$sButton = " & $sButton & "   $iX = " & $iX & "   $iY = " & $iY & "   $iClicks = " & $iClicks & "   $iSpeed = " & $iSpeed & @crlf)

Example of result when ok (Horizontal Scrollbar on the left)

$sButton = left   $iX = 202   $iY = 130   $iClicks = 1   $iSpeed = 1

Example of result when bad behavior (Horizontal Scrollbar on the right) and the GUI disappears (I restored it from the tray in the pic below) :

$sButton = left   $iX = 106   $iY = 160   $iClicks = 1   $iSpeed = 1

So I moved the horizontal scrollbar 78 pixels on the right and the function clicks on 96 pixels (202-106) on the left, outside GUI (coords to be reconfirmed)

55 minutes ago, spudw2k said:

f you absolutely have to click it then you might have to get a little creative

Count on me for that

Now I have to add a little post in the other thread, linking to this one, so LarsJ won't investigate in case he reads it.
Thanks for your confirmation & advices.

[Danyfirex]

Hello, I fixed like this:

expandcollapse popup

#include <GuiListView.au3>
#include <GuiConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 400)

$idListView = GUICtrlCreateListView("Col0|Col1|Col2|Col3|Col4|Col5|Col6|Col7|Col8|Col9", 10, 10, 480, 300)
For $i = 1 To 9
    _GUICtrlListView_SetColumnWidth($idListView, $i, 200)
Next
$idItem1 = GUICtrlCreateListViewItem("0|1|2|3|4|5|6|7|8|9", $idListView)
$idItem2 = GUICtrlCreateListViewItem("0|1|2|3|4|5|6|7|8|9", $idListView)

$idButton = GUICtrlCreateButton("Click me", 200, 340, 85, 25)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop

        Case $idButton ; click when scrollbar is on left, then with scrollbar on right
            _GUICtrlListView_ClickItemMod($idListView, 0)
    EndSwitch
WEnd

GUIDelete($hGUI)


Func _GUICtrlListView_ClickItemMod($hWnd, $iIndex, $sButton = "left", $bMove = False, $iClicks = 1, $iSpeed = 1)
    If Not IsHWnd($hWnd) Then $hWnd = GUICtrlGetHandle($hWnd)

    _GUICtrlListView_EnsureVisible($hWnd, $iIndex, False)
    Local $tRECT = _GUICtrlListView_GetItemRectEx($hWnd, $iIndex, $LVIR_LABEL)
    Local $tPoint = _WinAPI_PointFromRect($tRECT, True)
    Local $iXPlus = DllStructGetData($tRECT, "Left") < 0 ? DllStructGetData($tRECT, "Left") * -1 : 0
    $tPoint = _WinAPI_ClientToScreen($hWnd, $tPoint)
    Local $iX, $iY
    _WinAPI_GetXYFromPoint($tPoint, $iX, $iY)
    Local $iMode = Opt("MouseCoordMode", 1)
    If Not $bMove Then
        Local $aPos = MouseGetPos()
        _WinAPI_ShowCursor(False)
        MouseClick($sButton, $iX + $iXPlus, $iY, $iClicks, $iSpeed)
        MouseMove($aPos[0], $aPos[1], 0)
        _WinAPI_ShowCursor(True)
    Else
        MouseClick($sButton, $iX + $iXPlus, $iY, $iClicks, $iSpeed)
    EndIf
    Opt("MouseCoordMode", $iMode)
EndFunc   ;==>_GUICtrlListView_ClickItemMod

 

Saludos

[pixelsearch]

Hello @Danyfirex

Thanks for your input.
But In my case (column 0 hidden), _GUICtrlListView_ClickItemMod() isn't quite enough to have the row selected when the horizontal scrollbar has been moved to the right (even just a bit).

After adding 2 ConsoleWrite to _GUICtrlListView_ClickItemMod() , here are the results :

Local $tRECT = ...
ConsoleWrite('DllStructGetData($tRECT, "Left") = ' & DllStructGetData($tRECT, "Left") & @crlf)

MouseClick(...)
ConsoleWrite("$iX = " & $iX & "   $iXPlus = " & $iXPlus & "   $iX + $iXPlus = " & $iX + $iXPlus & "   $iY = " & $iY & @crlf)

We launch the script (the one in your post) and drag column 0 divider to the left, so column 0 is now hidden, then :

1) With horizontal scrollbar completely to the left, we click the button and the row becomes selected :

DllStructGetData($tRECT, "Left") = 4
$iX = 277   $iXPlus = 0   $iX + $iXPlus = 277   $iY = 222

2) Deselect the row, then with horizontal scrollbar dragged just a little bit to the right, button clicked, row is not selected  :

DllStructGetData($tRECT, "Left") = -16
$iX = 257   $iXPlus = 16   $iX + $iXPlus = 273   $iY = 222

Maybe the rough solution would be to add sometimes 4 pixels to $iXPlus ?

Edit : here is a result that show a case where 273 should be "readjusted" to 277 :

DllStructGetData($tRECT, "Left") = 4
$iX = 277   $iXPlus = 0   $iX + $iXPlus = 277   $iY = 222
DllStructGetData($tRECT, "Left") = 0
$iX = 273   $iXPlus = 0   $iX + $iXPlus = 273   $iY = 222

 

Edited June 16, 2021 by pixelsearch

[Nine]

May be this ?

Func _GUICtrlListView_ClickItemMod($hWnd, $iIndex, $sButton = "left", $bMove = False, $iClicks = 1, $iSpeed = 1)
    If Not IsHWnd($hWnd) Then $hWnd = GUICtrlGetHandle($hWnd)

    _GUICtrlListView_EnsureVisible($hWnd, $iIndex, False)
    Local $tRECT = _GUICtrlListView_GetItemRectEx($hWnd, $iIndex, $LVIR_LABEL)
    Local $tPoint = _WinAPI_PointFromRect($tRECT, True)
    $tPoint = _WinAPI_ClientToScreen($hWnd, $tPoint)
    Local $iX, $iY
    _WinAPI_GetXYFromPoint($tPoint, $iX, $iY)
    Local $tCtrl = _WinAPI_GetWindowInfo($hWnd)
    $iX = DllStructGetData($tCtrl, 'rClient', 1) + 4

    Local $iMode = Opt("MouseCoordMode", 1)
    If Not $bMove Then
        Local $aPos = MouseGetPos()
        _WinAPI_ShowCursor(False)
        MouseClick($sButton, $iX, $iY, $iClicks, $iSpeed)
        MouseMove($aPos[0], $aPos[1], 0)
        _WinAPI_ShowCursor(True)
    Else
        MouseClick($sButton, $iX, $iY, $iClicks, $iSpeed)
    EndIf
    Opt("MouseCoordMode", $iMode)
EndFunc   ;==>_GUICtrlListView_ClickItemMod

 

[mLipok]

Is it win64 ?

Maybe it is similar issue which @LarsJ help me fix recently but with treeview... ?

Edited June 16, 2021 by mLipok

[pixelsearch]

@mLipok no it's not win64, but you know, LarsJ often got in his scripts this "4 pixels thing" when it comes to column 0, for example in one of his scripts :

If $iSubItem Then
    aRect = _GUICtrlListView_GetSubItemRect( $hListView, $iItem, $iSubItem ) ; Subitem rectangle
Else ; $iSubItem = 0, the listview item, first column
    ; This calculation of $aRect for the listview item is necessary to get
    ; things to work properly if $LVS_EX_HEADERDRAGDROP style is applied.
    $aRect = _GUICtrlListView_GetItemRect( $hListView, $iItem, 2 ) ; 2 - The bounding rectangle of the item text
    $aRect[0] -= 4
EndIf

And yes, I also got the $LVS_EX_HEADERDRAGDROP style

@Nine where do you find these incredible messages ?
I never heard of WINDOWINFO structure until now and it seems so useful, thanks for sharing !

So with your function, results look promising in all cases :

============
Col 0 hidden
============

Scrollbar placed at left :
$iX = 277
$iX = 279   $iY = 222

Scrollbar placed at Right :
$iX = -1047
$iX = 279   $iY = 222

=============
Col 0 visible
=============

Scrollbar placed at left :
$iX = 298
$iX = 279   $iY = 222

Scrollbar placed at right :
$iX = -1068
$iX = 279   $iY = 222

279 in all cases, what to ask for more ?
Especially the working 277 (in precedent post) seems "a bit too close" of LV border.

Guys, thank you so much. your 3 answers are really helpful. I would like to "mark as solution" the 3 of you but it seems impossible (I tried on 2 of you before I saw Nine post and didn't succeed) . Have a great evening

Edit: I wonder if a Trac ticket should be opened for this _GUICtrlListView_ClickItem() function

Edited June 16, 2021 by pixelsearch

[Nine]

Glad you like 

10 minutes ago, pixelsearch said:

I wonder if a Trac ticket should be opened

Yep there is definitely a bug there. À tout seigneur, tout honneur :  I will let you write it.

[pixelsearch]

Done. Trac Ticket #3827 created