_FileWriteToLine removes empty lines at the end of the file - (Moved)

[DonChunior]

#include <File.au3>
#include <FileConstants.au3>

Local $sTestfile = "_FileWriteToLine.txt"
Local $hTestfile = FileOpen($sTestfile, $FO_APPEND)
FileWriteLine($hTestfile, "Line 1")
FileWriteLine($hTestfile, "Line 2")
FileWriteLine($hTestfile, "Line 3")
FileClose($hTestfile)
_FileWriteToLine("_FileWriteToLine.txt", 2, "Overwritten", True)

The above example code first creates a text file that has four lines after FileClose:

1. Line 1
2. Line 2
3. Line 3
4. And an empty line.

After _FileWriteToLine only three lines are left:

1. Line 1
2. Overwritten
3. Line 3

The empty line has been removed by the function _FileWriteToLine!

[Melba23]

Moved to the appropriate forum.

Moderation Team

[FrancescoDiMuro]

@DonChunior
If you change the line 

FileWriteLine($hTestfile, "Line 3")

to 

FileWriteLine($hTestfile, "Line 3" & @CRLF)

the blank line at the end of the file won't be added, since FileWriteLine(), as it is stated in the Help file:

Quote

Parameters

filehandle/filename:	The handle of a file, as returned by a previous call to FileOpen(). Alternatively, you may use a string filename as the first parameter.
line                            :	The line of text to write to the text file. If the line does NOT end in @CR or @LF then a DOS linefeed (@CRLF) will be automatically added.

And, about the "magic" disappearing of the last line in the file, I think that's the effect of the _FileWriteToLine(), which is written like so:
 

expandcollapse popup

; #FUNCTION# ====================================================================================================================
; Author ........: cdkid
; Modified.......: partypooper, MrCreatoR
; ===============================================================================================================================
Func _FileWriteToLine($sFilePath, $iLine, $sText, $bOverWrite = False)
    If $iLine <= 0 Then Return SetError(4, 0, 0)
    If Not IsString($sText) Then
        $sText = String($sText)
        If $sText = "" Then Return SetError(6, 0, 0)
    EndIf
    If $bOverWrite = Default Then $bOverWrite = False
    If Not (IsBool($bOverWrite) Or $bOverWrite = 0 Or $bOverWrite = 1) Then Return SetError(5, 0, 0) ; For old versions.
    If Not FileExists($sFilePath) Then Return SetError(2, 0, 0)

    Local $aArray = FileReadToArray($sFilePath)
    Local $iUBound = UBound($aArray) - 1
    If ($iUBound + 1) < $iLine Then Return SetError(1, 0, 0)

    Local $hFileOpen = FileOpen($sFilePath, FileGetEncoding($sFilePath) + $FO_OVERWRITE)
    If $hFileOpen = -1 Then Return SetError(3, 0, 0)

    Local $sData = ""
    $iLine -= 1 ; Now the array is 0-based, so reduce the line number by 1.
    For $i = 0 To $iUBound
        If $i = $iLine Then
            If $bOverWrite Then
                If $sText Then $sData &= $sText & @CRLF
            Else
                $sData &= $sText & @CRLF & $aArray[$i] & @CRLF
            EndIf
        ElseIf $i < $iUBound Then
            $sData &= $aArray[$i] & @CRLF
        ElseIf $i = $iUBound Then
            $sData &= $aArray[$i]
        EndIf
    Next

    FileWrite($hFileOpen, $sData)
    FileClose($hFileOpen)
    Return 1
EndFunc   ;==>_FileWriteToLine

[DonChunior]

Hi Francesco,

thanks for your reply.

Thus, the problem seems to be that the _FileWriteToLine function completely rewrites the file and does not just edit the corresponding line!
Of course it is a matter of opinion whether this is a bug or not.

[FrancescoDiMuro]

I don't know if it is "intended".
By the way, let's see what @cdkid ( who has wrote the function ) has to say about

[BrewManNH]

3 hours ago, DonChunior said:

Of course it is a matter of opinion whether this is a bug or not.

Not a bug, works that way by design.

[Melba23]

FrancescoDiMuro,

It appears that your AutoIt version is not up to date - the function currently reads (v3.3.14.5):

expandcollapse popup

; #FUNCTION# ====================================================================================================================
; Author ........: cdkid
; Modified.......: partypooper, MrCreatoR, Melba23
; ===============================================================================================================================
Func _FileWriteToLine($sFilePath, $iLine, $sText, $bOverWrite = False, $bFill = False)
    If $bOverWrite = Default Then $bOverWrite = False
    If $bFill = Default Then $bFill = False
    If Not FileExists($sFilePath) Then Return SetError(2, 0, 0)
    If $iLine <= 0 Then Return SetError(4, 0, 0)
    If Not (IsBool($bOverWrite) Or $bOverWrite = 0 Or $bOverWrite = 1) Then Return SetError(5, 0, 0)
    If Not IsString($sText) Then
        $sText = String($sText)
        If $sText = "" Then Return SetError(6, 0, 0)
    EndIf
    If Not IsBool($bFill) Then Return SetError(7, 0, 0)
    ; Read current file into array
    Local $aArray = FileReadToArray($sFilePath)
    ; Create empty array if empty file
    If @error Then Local $aArray[0]
    Local $iUBound = UBound($aArray) - 1
    ; If Fill option set
    If $bFill Then
        ; If required resize array to allow line to be written
        If $iUBound < $iLine Then
            ReDim $aArray[$iLine]
            $iUBound = $iLine - 1
        EndIf
    Else
        If ($iUBound + 1) < $iLine Then Return SetError(1, 0, 0)
    EndIf
    ; Write specific line - array is 0-based so reduce by 1 - and either replace or insert
    $aArray[$iLine - 1] = ($bOverWrite ? $sText : $sText & @CRLF & $aArray[$iLine - 1])
    ; Concatenate array elements
    Local $sData = ""
    For $i = 0 To $iUBound
        $sData &= $aArray[$i] & @CRLF
    Next
    $sData = StringTrimRight($sData, StringLen(@CRLF)) ; Required to strip trailing EOL
    ; Write data to file
    Local $hFileOpen = FileOpen($sFilePath, FileGetEncoding($sFilePath) + $FO_OVERWRITE)
    If $hFileOpen = -1 Then Return SetError(3, 0, 0)
    FileWrite($hFileOpen, $sData)
    FileClose($hFileOpen)
    Return 1
EndFunc   ;==>_FileWriteToLine

So, as the latest author of the function.....

DonChunior,

Quote

the _FileWriteToLine function completely rewrites the file and does not just edit the corresponding line!

As you can see from the above code, that is exactly what it does - there is no other way to allow for the function to both insert and delete lines. So, as BrewManNH has pointed out, what you are seeing is by design and not a bug.

M23