Buttons - GUICtrlSetOnEvent x20

[careca]

Hi, got this code that gets called when the correspondent button is clicked.

Wondering if there's a way to shorten this up, as right now i have 20 of these,

GUICtrlCreateButton("...", $FS1X, $FS1Y, 20, 22)
GUICtrlSetOnEvent(-1, "SelectFile1")
GUICtrlSetTip(-1, $Tip3, "FileSelect", 1)
GUICtrlCreateButton("...", $FS1X, $FS1Y + 30, 20, 22)
GUICtrlSetOnEvent(-1, "SelectFile2")
GUICtrlSetTip(-1, $Tip3, "FileSelect", 1)
GUICtrlCreateButton("...", $FS1X, $FS1Y + 60, 20, 22)
GUICtrlSetOnEvent(-1, "SelectFile3")
GUICtrlSetTip(-1, $Tip3, "FileSelect", 1)


Func SelectFile1()
    $FileDlgApp = FileOpenDialog('Select File', @DesktopDir, "All (*.*)")
    If Not @error Then
        IniWrite($Ini, "abc", "AppStr1", $FileDlgApp)
        GUICtrlSetData($UserAppStr[1], $FileDlgApp)
    EndIf
EndFunc   ;==>SelectFile1
;=============================================================================
Func SelectFile2()
    $FileDlgApp = FileOpenDialog('Select File', @DesktopDir, "All (*.*)")
    If Not @error Then
        IniWrite($Ini, "abc", "AppStr2", $FileDlgApp)
        GUICtrlSetData($UserAppStr[2], $FileDlgApp)
    EndIf
EndFunc   ;==>SelectFile2
;=============================================================================
Func SelectFile3()
    $FileDlgApp = FileOpenDialog('Select File', @DesktopDir, "All (*.*)")
    If Not @error Then
        IniWrite($Ini, "abc", "AppStr3", $FileDlgApp)
        GUICtrlSetData($UserAppStr[3], $FileDlgApp)
    EndIf
EndFunc   ;==>SelectFile3

Thanks

[spudw2k]

I would do something like this (tailor as necessary)

$idBtnSelect1 = GUICtrlCreateButton("...", $FS1X, $FS1Y, 20, 22)
GUICtrlSetOnEvent(-1, "SelectButtonEvent")
GUICtrlSetTip(-1, $Tip3, "FileSelect", 1)
$idBtnSelect2 = GUICtrlCreateButton("...", $FS1X, $FS1Y + 30, 20, 22)
GUICtrlSetOnEvent(-1, "SelectButtonEvent")
GUICtrlSetTip(-1, $Tip3, "FileSelect", 1)
$idBtnSelect3 = GUICtrlCreateButton("...", $FS1X, $FS1Y + 60, 20, 22)
GUICtrlSetOnEvent(-1, "SelectButtonEvent")
GUICtrlSetTip(-1, $Tip3, "FileSelect", 1)


Func SelectButtonEvent()
    Switch @GUI_CtrlId
        Case $idBtnSelect1
            SelectFile(1)
        Case $idBtnSelect2
            SelectFile(2)
        Case $idBtnSelect3
            SelectFile(3)
    EndSwitch
EndFunc

Func SelectFile($iKey)
    $FileDlgApp = FileOpenDialog('Select File', @DesktopDir, "All (*.*)")
    If Not @error Then
        IniWrite($Ini, "abc", "AppStr" & $iKey, $FileDlgApp)
        GUICtrlSetData($UserAppStr[$iKey], $FileDlgApp)
    EndIf
EndFunc

 

[careca]

Looks like a good idea.

thank you.

 

[careca]

End result for 20 buttons if anyone cares.

Did some changes but i used the base principle. thanks.

$SelBut[1] = GUICtrlCreateButton("...", $FS1X, $FS1Y, 20, 22)
GUICtrlSetOnEvent(-1, "SelectFile")
GUICtrlSetTip(-1, $Tip3, "FileSelect", 1)
$SelBut[2] = GUICtrlCreateButton("...", $FS1X, $FS1Y + 30, 20, 22)
GUICtrlSetOnEvent(-1, "SelectFile")
GUICtrlSetTip(-1, $Tip3, "FileSelect", 1)
$SelBut[3] = GUICtrlCreateButton("...", $FS1X, $FS1Y + 60, 20, 22)
GUICtrlSetOnEvent(-1, "SelectFile")
GUICtrlSetTip(-1, $Tip3, "FileSelect", 1)

Func SelectFile()
    Local $f = 1
    For $f = 1 To 20
        If @GUI_CtrlId = $SelBut[$f] Then
            $FileDlgApp = FileOpenDialog('Select File', @DesktopDir, "All (*.*)")
            If Not @error Then
                IniWrite($Ini, "Triggers", "AppStr" & $f, $FileDlgApp)
                GUICtrlSetData($UserAppStr[$f], $FileDlgApp)
            EndIf
        EndIf
    Next
EndFunc   ;==>SelectFile