Plasma_kIt

[spudw2k]

Here's a fun tool I put together.  It's a Plasma sandbox.  More features to come.

This page was a useful resource for learning about this kind of Plasma implementation.

Warning! Not Epileptic Friendly (probably)! Use at own Risk!
I tried to curve the "default/initial" Plasma patterns so they aren't too erratic.  That doesn't mean you can't alter the Plasmas to be more erratic.  If you are sensitive to flashing colors and lights, use due caution.  

expandcollapse popup

#Region - Includes and Globals
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <ComboConstants.au3>
#include <GuiComboBox.au3>
#include <SliderConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>
#include <Misc.au3>

;#include <Array.au3>

Opt("GUIOnEventMode", 1)
Local $hDLL = DllOpen("user32.dll")

Global Const $iWinMinWidth = @DesktopWidth * .25
Global Const $iWinMinHeight = @DesktopHeight * .25
Global $bIsPlaying = True, $bIsDrawing = False
Global $hTimerFPS
Global $iRows = 16, $iCols = 16
Global $iDisplayPlasma = 0, $iSelectPlasma = 0

Global $aPlasmaShapes[4] = ["($iX)", "($iY)", "($iX + $iY)", "Sqrt(($iX * $iX) + ($iY * $iY))"]
;~ Global $aPlasmas[4][7] = [[0, Random(6, 14, 1), 0, 0, 1, 0, 0], [1, Random(6, 14, 1), 0, 0, 0, 0, 0], [2, Random(8, 16,1 ), 0, 0, 1, 0, 0], [3, Random(8, 16, 1), 0, 0, Random(0,1,1), 0, 0]] ;Sine Wave | Spread | Position | Rotation | Spread Motion | Position Motion | Rotation Motion
Global $aPlasmas[4][7] = [[0, Random(6, 14, 1), 0, 0, 0, 0, 0], [1, Random(6, 14, 1), 0, 0, 0, 0, 0], [2, Random(8, 16,1 ), 0, 0, 0, 0, 0], [3, Random(8, 16, 1), 0, 0, 0, 0, 0]] ;Sine Wave | Spread | Position | Rotation | Spread Motion | Position Motion | Rotation Motion

Global $aPallete[256]
Global $aPalleteSettings[3][3] = [[0, 128, 128], [-1.75, 128, 128], [1.75, 128, 128]] ;Position | Spread | Value
Global $aPalleteDefaults = $aPalleteSettings
Global $iPalleteShift = 0, $bPalleteShift = True, $iPalletShiftDirection = -5
#EndRegion - Includes and Globals
#Region - Main GUI
Global $aGUI[1] = ["id|hWnd"]
Global Enum $hGUI = 1, $idMnuFile, $idMnuFileExit, $idMnuFilePlay, $idMnuOptions, $idMnuOptionsPallete, $idMnuOptionsPalleteShift, $idMnuOptionsEditor, $idMnuOptionsZoom, $idMnuOptionsZoomIn, $idMnuOptionsZoomOut, $iGUILast
ReDim $aGUI[$iGUILast]
Global Const $sVersion = "0.1"
Global Const $sTitle = "Plasma_kIt - Version " & $sVersion

$aGUI[$hGUI] = GUICreate($sTitle, $iWinMinWidth, $iWinMinHeight, -1, -1, BitOR($WS_SIZEBOX, $WS_MAXIMIZEBOX, $WS_MINIMIZEBOX))
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
$aGUI[$idMnuFile] = GUICtrlCreateMenu("&File")
$aGUI[$idMnuFilePlay] = GUICtrlCreateMenuItem("&Pause", $aGUI[$idMnuFile])
GUICtrlSetOnEvent(-1, "_PlayToggle")
$aGUI[$idMnuFileExit] = GUICtrlCreateMenuItem("E&xit", $aGUI[$idMnuFile])
GUICtrlSetOnEvent(-1, "_Exit")
$aGUI[$idMnuOptions] = GUICtrlCreateMenu("&Options")
$aGUI[$idMnuOptionsPallete] = GUICtrlCreateMenuItem("Pallete Mixer", $aGUI[$idMnuOptions])
GUICtrlSetOnEvent(-1, "_GUIPallete_Show")
$aGUI[$idMnuOptionsPalleteShift] = GUICtrlCreateMenuItem("Pallete Shift", $aGUI[$idMnuOptions])
GUICtrlSetState(-1, $GUI_CHECKED)
GUICtrlSetOnEvent(-1, "_GUIPallete_ShiftToggle")
$aGUI[$idMnuOptionsEditor] = GUICtrlCreateMenuItem("Plasma Editor", $aGUI[$idMnuOptions])
GUICtrlSetOnEvent(-1, "_GUIPlasmaEditor_Show")
$aGUI[$idMnuOptionsZoom] = GUICtrlCreateMenu("Zoom", $aGUI[$idMnuOptions])
$aGUI[$idMnuOptionsZoomIn] = GUICtrlCreateMenuItem("Zoom In" & @TAB & "+", $aGUI[$idMnuOptionsZoom])
GUICtrlSetOnEvent(-1, "_Zoom")
$aGUI[$idMnuOptionsZoomOut] = GUICtrlCreateMenuItem("Zoom Out" & @TAB & "-", $aGUI[$idMnuOptionsZoom])
GUICtrlSetOnEvent(-1, "_Zoom")
_GDIPlus_Startup() ;Start GDI+ UDF
Global Const $hDC = _WinAPI_GetDC($aGUI[$hGUI])
Global Const $hHBitmap = _WinAPI_CreateCompatibleBitmap($hDC, @DesktopWidth, @DesktopHeight)
Global Const $hDC_backbuffer = _WinAPI_CreateCompatibleDC($hDC)
Global Const $DC_obj = _WinAPI_SelectObject($hDC_backbuffer, $hHBitmap)
$hBackbuffer = _GDIPlus_GraphicsCreateFromHDC($hDC_backbuffer)
;_GDIPlus_GraphicsSetSmoothingMode($hBackbuffer, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ;Sets the graphics object rendering quality (antialiasing)
$hBrush = _GDIPlus_BrushCreateSolid(0x00000000) ;Brush for Coloring/Painting LED Pixels

Local $aAccelKeys[5][2] = [["{+}", $aGUI[$idMnuOptionsZoomIn]], ["{NUMPADADD}", $aGUI[$idMnuOptionsZoomIn]], ["{-}", $aGUI[$idMnuOptionsZoomOut]], ["{NUMPADSUB}", $aGUI[$idMnuOptionsZoomOut]], ["{pause}", $aGUI[$idMnuFilePlay]]]
GUISetAccelerators($aAccelKeys)
#EndRegion - Main GUI
#Region - Pallete Mixer GUI
Global $aGUIPallete[1] = ["id|hWnd"]
Global Enum $hGUIPallete = 1, $idSliderRPosition, $idSliderRValue, $idSliderRSpread, $idSliderGPosition, $idSliderGValue, _
        $idSliderGSpread, $idSliderBPosition, $idSliderBValue, $idSliderBSpread, $idBtnResetPallete, $iGUIPalleteLast
ReDim $aGUIPallete[$iGUIPalleteLast]
$aGUIPallete[$hGUIPallete] = GUICreate("Pallete Mixer", 338, 260, -1, -1)
GUISetOnEvent($GUI_EVENT_CLOSE, "_GUIPallete_Hide")
$aGUIPallete[$idSliderRPosition] = GUICtrlCreateSlider(8, 132, 97, 33, $TBS_ENABLESELRANGE)
GUICtrlSetLimit(-1, 20, -20)
;~ GUICtrlSetOnEvent(-1, "_GUIPallete_SettingsChange")
$aGUIPallete[$idSliderRValue] = GUICtrlCreateSlider(48, 56, 33, 73, BitOR($TBS_VERT, $TBS_ENABLESELRANGE))
GUICtrlSetLimit(-1, 128, 0)
;~ GUICtrlSetOnEvent(-1, "_GUIPallete_SettingsChange")
$aGUIPallete[$idSliderRSpread] = GUICtrlCreateSlider(8, 168, 97, 33, $TBS_ENABLESELRANGE)
GUICtrlSetLimit(-1, 24, 2)
;~ GUICtrlSetOnEvent(-1, "_GUIPallete_SettingsChange")

$aGUIPallete[$idSliderGPosition] = GUICtrlCreateSlider(120, 132, 97, 33, $TBS_ENABLESELRANGE)
GUICtrlSetLimit(-1, 20, -20)
;~ GUICtrlSetOnEvent(-1, "_GUIPallete_SettingsChange")
$aGUIPallete[$idSliderGValue] = GUICtrlCreateSlider(160, 56, 33, 73, BitOR($TBS_VERT, $TBS_ENABLESELRANGE))
GUICtrlSetLimit(-1, 128, 0)
;~ GUICtrlSetOnEvent(-1, "_GUIPallete_SettingsChange")
$aGUIPallete[$idSliderGSpread] = GUICtrlCreateSlider(120, 168, 97, 33, $TBS_ENABLESELRANGE)
GUICtrlSetLimit(-1, 24, 2)
;~ GUICtrlSetOnEvent(-1, "_GUIPallete_SettingsChange")

$aGUIPallete[$idSliderBPosition] = GUICtrlCreateSlider(232, 132, 97, 33, $TBS_ENABLESELRANGE)
GUICtrlSetLimit(-1, 20, -20)
;~ GUICtrlSetOnEvent(-1, "_GUIPallete_SettingsChange")
GUICtrlSetData(-1, 9)
$aGUIPallete[$idSliderBValue] = GUICtrlCreateSlider(272, 56, 33, 73, BitOR($TBS_VERT, $TBS_ENABLESELRANGE))
GUICtrlSetLimit(-1, 128, 0)
;~ GUICtrlSetOnEvent(-1, "_GUIPallete_SettingsChange")
$aGUIPallete[$idSliderBSpread] = GUICtrlCreateSlider(232, 168, 97, 33, $TBS_ENABLESELRANGE)
GUICtrlSetLimit(-1, 24, 2)
GUICtrlSetData(-1, 11)
;~ GUICtrlSetOnEvent(-1, "_GUIPallete_SettingsChange")

GUICtrlCreateLabel("RED", 46, 200, 30, 20)
GUICtrlCreateLabel("GREEN", 150, 200, 38, 20)
GUICtrlCreateLabel("BLUE", 268, 200, 30, 20)
$aGUIPallete[$idBtnResetPallete] = GUICtrlCreateButton("Reset", 136, 236, 67, 17)
GUICtrlSetOnEvent(-1, "_GUIPallete_Reset")

GUISetAccelerators($aAccelKeys)

Global Const $hDCPallete = _WinAPI_GetDC($aGUIPallete[$hGUIPallete])
Global Const $hHBitmapPallete = _WinAPI_CreateCompatibleBitmap($hDCPallete, 320, 40)
Global Const $hDC_backbufferPallete = _WinAPI_CreateCompatibleDC($hDCPallete)
Global Const $DC_objPallete = _WinAPI_SelectObject($hDC_backbufferPallete, $hHBitmapPallete)
Global Const $hBackbufferPallete = _GDIPlus_GraphicsCreateFromHDC($hDC_backbufferPallete)
Global $hBrushPallete = _GDIPlus_BrushCreateSolid(0xFF000000)
;~ _GDIPlus_GraphicsSetSmoothingMode($hBackbuffer, $GDIP_SMOOTHINGMODE_HIGHQUALITY) ;Sets the graphics object rendering quality (antialiasing)
_GUIPallete_Update()
_GUIPallete_Reset()
#EndRegion - Pallete Mixer GUI
#Region - Plasma Editor GUI
Global $aGUIPlasmaEditor[1] = ["id|hWnd"]
Global Enum $hGUIPlasmaEditor = 1, $idCmbPlasmaSelector, $idCmbPlasmaDisplay, $idBtnPlasmaAdd, $idBtnPlasmaDel, $idCmbPlasmaShape, $idSliderPlasmaSpread, $idCmbPlasmaSpread, $idSliderPlasmaRotation, $idCmbPlasmaRotation, $idSliderPlasmaPosition, $idCmbPlasmaPosition, $iGUIPlasmaEditorLast
ReDim $aGUIPlasmaEditor[$iGUIPlasmaEditorLast]

$aGUIPlasmaEditor[$hGUIPlasmaEditor] = GUICreate("Plasma Editor", 419, 323, -1, -1)
GUISetOnEvent($GUI_EVENT_CLOSE, "_GUIPlasmaEditor_Hide")
GUICtrlCreateLabel("Display", 16, 8, 95, 17)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
$aGUIPlasmaEditor[$idCmbPlasmaDisplay] = GUICtrlCreateCombo("", 16, 24, 121, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "All Combined|Selected Plasma", "All Combined")
GUICtrlSetOnEvent(-1, "_GUIPlasmaEditor_PlasmaDisplay")
GUICtrlCreateLabel("Selected Plasma", 24, 96, 120, 17)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
$aGUIPlasmaEditor[$idBtnPlasmaAdd] = GUICtrlCreateButton("Add Plasma", 160, 16, 113, 33)
GUICtrlSetOnEvent(-1, "_GUIPlasmaEditor_PlasmaAddRem")
GUICtrlSetState(-1, $GUI_DISABLE)
$aGUIPlasmaEditor[$idBtnPlasmaDel] = GUICtrlCreateButton("Remove Plasma", 296, 16, 113, 33)
GUICtrlSetOnEvent(-1, "_GUIPlasmaEditor_PlasmaAddRem")
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlCreateGroup("Plasma Controls", 8, 64, 401, 249)
GUICtrlSetFont(-1, 8, 800, 0, "MS Sans Serif")
$aGUIPlasmaEditor[$idCmbPlasmaSelector] = GUICtrlCreateCombo("", 24, 112, 121, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "Plasma #1|Plasma #2|Plasma #3|Plasma #4", "Plasma #1")
GUICtrlSetOnEvent(-1, "_GUIPlasmaEditor_PlasmaSelect")
GUICtrlCreateLabel("Shape", 174, 96, 35, 17)
$aGUIPlasmaEditor[$idCmbPlasmaShape] = GUICtrlCreateCombo("", 174, 112, 113, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "Horizontal|Vertical|Diagonal|Circular", "Horizontal")
GUICtrlSetOnEvent(-1, "_GUIPlasmaEditor_PlasmaSetShape")
GUICtrlCreateLabel("Spread", 24, 145, 38, 17)
$aGUIPlasmaEditor[$idSliderPlasmaSpread] = GUICtrlCreateSlider(16, 160, 257, 25, $TBS_FIXEDLENGTH)
GUICtrlSetLimit(-1, 255, 5)
$aGUIPlasmaEditor[$idCmbPlasmaSpread] = GUICtrlCreateCombo("", 280, 160, 113, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "Static|Oscillate", "Static")
GUICtrlSetOnEvent(-1, "_GUIPlasmaEditor_PlasmaSetSpread")
GUICtrlCreateLabel("Rotation", 24, 201, 44, 17)
GUICtrlSetState(-1, $GUI_DISABLE)
$aGUIPlasmaEditor[$idSliderPlasmaRotation] = GUICtrlCreateSlider(16, 216, 257, 25, $TBS_FIXEDLENGTH)
GUICtrlSetState(-1, $GUI_DISABLE)
$aGUIPlasmaEditor[$idCmbPlasmaRotation] = GUICtrlCreateCombo("", 280, 216, 113, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "Static|Oscillate", "Static")
GUICtrlSetOnEvent(-1, "_GUIPlasmaEditor_PlasmaSetRotation")
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlCreateLabel("Position", 24, 257, 41, 17)
GUICtrlSetState(-1, $GUI_DISABLE)
$aGUIPlasmaEditor[$idSliderPlasmaPosition] = GUICtrlCreateSlider(16, 272, 257, 25, $TBS_FIXEDLENGTH)
GUICtrlSetLimit(-1, 127, -127)
GUICtrlSetState(-1, $GUI_DISABLE)
$aGUIPlasmaEditor[$idCmbPlasmaPosition] = GUICtrlCreateCombo("", 280, 272, 113, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "Static|Oscillate", "Static")
GUICtrlSetOnEvent(-1, "_GUIPlasmaEditor_PlasmaSetPosition")
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlCreateGroup("", -99, -99, 1, 1)

_GUIPlasmaEditor_PlasmaSettingsLoad($iSelectPlasma)
;_GUIPlasmaEditor_PlasmaControlsLock()
GUISetAccelerators($aAccelKeys)
#EndRegion - Plasma Editor GUI
#Region - Initialization and Main Loop
GUIRegisterMsg($WM_GETMINMAXINFO, "_WM_GETMINMAXINFO")
GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")

GUISetState(@SW_SHOW, $aGUI[$hGUI])

While 1
    If $bIsPlaying And Not $bIsDrawing Then _DrawScreen(_RenderPlasma())
    Sleep(10)
WEnd
#EndRegion - Initialization and Main Loop
#Region - Main GUI Functions
Func _DrawScreen($aPixels)
    ;If Function called while Drawing Return 0
    If $bIsDrawing Then Return 0
    ;Set Drawing Status Indictaor
    $bIsDrawing = True
    ;Create Timer for Drawing Performance/Duration
    Local $hTimer = TimerInit()
    ;Erase Bitmap Graphic
    _GDIPlus_GraphicsClear($hBackbuffer, 0xFFFFFFFF)
    ;Capture Client Window Size
    $aWinClientSize = WinGetClientSize($aGUI[$hGUI])
    ;Setup Variables
    Local $iPixelIndex = 0
    Local $iCol = $iCols
    Local $iRow = $iRows
    Local $iWidth = $aWinClientSize[0] / $iCol
    Local $iHeight = $aWinClientSize[1] / $iRow
    ;Draw Pixel Grid (Top-Left to Bottom Right)
    For $iY = 0 To $iRow - 1
        For $iX = 0 To $iCol - 1
            Local $dARGB = $aPixels[$iPixelIndex]
            ;Set Brush Color
            _GDIPlus_BrushSetSolidColor($hBrush, $dARGB)
            ;Draw "Pixel"
            _GDIPlus_GraphicsFillRect($hBackbuffer, $iX * $iWidth, $iY * $iHeight, $iWidth, $iHeight, $hBrush)
            ;Increment Pixel Counter
            $iPixelIndex += 1
            If $iPixelIndex = UBound($aPixels) Then $iPixelIndex = 0
        Next
    Next
    ;Draw Bitmap to Screen
    _WinAPI_BitBlt($hDC, 0, 0, $aWinClientSize[0], $aWinClientSize[1], $hDC_backbuffer, 0, 0, $SRCCOPY) ;blit drawn bitmap to GUI
    ;FPS Counter
    $hTimer = TimerDiff($hTimer)
;~  ConsoleWrite("Whole Process time: " & Round($hTimer / 1000, 3) & @CRLF)
    If $bIsPlaying Then
        If TimerDiff($hTimerFPS) >= 998 Then
            Local $iFPS = Round(1000 / $hTimer, 2)
            WinSetTitle($aGUI[$hGUI], "", $sTitle & "  (" & $iFPS & " FPS)  " & $iCols & " x " & $iRows)
            $hTimerFPS = TimerInit()
        EndIf
    Else
        ;Show FPS in Window Title
        WinSetTitle($aGUI[$hGUI], "", $sTitle)
    EndIf
    $bIsDrawing = False
EndFunc   ;==>_DrawScreen

Func _Exit()
    ; Clean up resources
    _GUIPallete_Exit()
    GUIDelete($aGUIPallete[$hGUIPallete])
    GUIDelete($aGUIPlasmaEditor[$hGUIPlasmaEditor])
    GUIDelete($aGUI[$hGUI])
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hBackbuffer)
    _WinAPI_SelectObject($hDC, $DC_obj)
    _WinAPI_DeleteObject($hHBitmap)
    _WinAPI_ReleaseDC($hGUI, $hDC)
    _GDIPlus_Shutdown()
    DllClose($hDLL)
    Exit
EndFunc   ;==>_Exit

Func _PlayToggle()
    ;Toggle Play State
    If Not $bIsPlaying Then
        ;Start Playing
        $bIsPlaying = True
        $hTimerFPS = TimerInit()
        GUICtrlSetData($aGUI[$idMnuFilePlay], "&Pause")
    Else
        ;Stop Playing
        $bIsPlaying = False
        GUICtrlSetData($aGUI[$idMnuFilePlay], "&Play")
    EndIf
EndFunc   ;==>_PlayToggle

Func _RenderPlasma()
    ;Setup Variables
    Local $aWorkPallete = $aPallete
    Local $iRow = $iRows
    Local $iCol = $iCols
    Local $iGridSize = $iRow * $iCol
    Local $aPixels[$iGridSize]
    Local $iIndex = 0
    Local $iPlasma = 0
    Local $iPlasmas
    Local $iDisplayPlasmaNumber = $iDisplayPlasma
    Local $iSine, $iSpread, $iPosition
    ;Loop Through Pixel Grid and Calculate Plasma(s)
    For $iY = 0 To $iRow - 1
        For $iX = 0 To $iCol - 1
            $iPlasmas = 0
            If Not $iDisplayPlasmaNumber Then
                For $iZ = 0 To UBound($aPlasmas) - 1
                    $iSine = $aPlasmas[$iZ][0]
                    ;Spread Motions
                    If $aPlasmas[$iZ][4] Then
                        $aPlasmas[$iZ][4] += ($aPlasmas[$iZ][1] * 0.00001125)
                        $iSpread = -7*Sin($aPlasmas[$iZ][4])+9
                    Else
                        $iSpread = $aPlasmas[$iZ][1]
                    EndIf
                    $iPosition = $aPlasmas[$iZ][2]
                    $iPlasma = Execute("128.0 + (128.0 * Sin(" & $aPlasmaShapes[$iSine] & " / " & $iSpread & "))")
                    $iPlasmas += $iPlasma
                Next
            Else
                $iSine = $aPlasmas[$iDisplayPlasmaNumber - 1][0]
                ;Spread Motions
                If $aPlasmas[$iDisplayPlasmaNumber - 1][4] Then
                    $aPlasmas[$iDisplayPlasmaNumber - 1][4] += ($aPlasmas[$iDisplayPlasmaNumber - 1][1] * 0.005)
                    $iSpread = Sin($aPlasmas[$iDisplayPlasmaNumber - 1][4])/2
                Else
                    $iSpread = $aPlasmas[$iDisplayPlasmaNumber - 1][1]
                EndIf
                $iPosition = $aPlasmas[$iDisplayPlasmaNumber - 1][2]
                ;$iPlasmas = Execute("128.0 + (128.0 * Sin(" & $aPlasmaShapes[$aPlasmas[$iDisplayPlasmaNumber - 1][0]] & " / " & $aPlasmas[$iDisplayPlasmaNumber - 1][1] & ") - " & $aPlasmas[$iDisplayPlasmaNumber - 1][2] & ")")
                $iPlasmas = Execute("128.0 + (128.0 * Sin(" & $aPlasmaShapes[$iSine] & " / " & $iSpread & "))")
            EndIf
            $iPlasma = Int($iPlasmas)
            ;Account for Pallete Shift
            $iPlasma += $iPalleteShift
            ;Wrap Pixel Pallete Color
            If $iPlasma >= 256 Then
                Do
                    $iPlasma -= 256
                Until $iPlasma < 256
            EndIf
            If $iPlasma <= -1 Then
                Do
                    $iPlasma += 256
                Until $iPlasma > -1
            EndIf
            ;Set Pixel Color value from Pallete
            $aPixels[$iIndex] = $aWorkPallete[$iPlasma]
            ;Increment Pixel Index Counter
            $iIndex += 1
            If $iIndex = $iGridSize Then $iIndex = 0
        Next
    Next
    ;Pallete Shift Logic
    If $bPalleteShift Then
        $iPalleteShift += $iPalletShiftDirection
        If $iPalleteShift >= 256 Then $iPalleteShift = 0
        If $iPalleteShift <= -1 Then $iPalleteShift = 255
    EndIf

    Return $aPixels
EndFunc   ;==>_RenderPlasma

Func _WM_GETMINMAXINFO($hwnd, $Msg, $wParam, $lParam)
    ;Only Control Size of Main GUI
    If $hwnd <> $aGUI[$hGUI] Then Return Default
    $tagMaxinfo = DllStructCreate("int;int;int;int;int;int;int;int;int;int", $lParam)
    DllStructSetData($tagMaxinfo, 7, $iWinMinWidth) ; min X
    DllStructSetData($tagMaxinfo, 8, $iWinMinHeight) ; min Y
    Return 0
EndFunc   ;==>_WM_GETMINMAXINFO

Func _WM_NOTIFY($hwnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")

    ;Local $tInfo
    If Not _IsPressed("01", $hDLL) Then Return Default

    Switch $iIDFrom
        Case $aGUIPallete[$idSliderRPosition]
            Switch $iCode
                Case $NM_CUSTOMDRAW
                    _GUIPallete_ColorSet(0, -1, GUICtrlRead($iIDFrom))
            EndSwitch
            Return 0
        Case $aGUIPallete[$idSliderRValue]
            Switch $iCode
                Case $NM_CUSTOMDRAW
                    _GUIPallete_ColorSet(0, GUICtrlRead($iIDFrom))
            EndSwitch
            Return 0
        Case $aGUIPallete[$idSliderRSpread]
            Switch $iCode
                Case $NM_CUSTOMDRAW
                    _GUIPallete_ColorSet(0, -1, "", GUICtrlRead($iIDFrom))
            EndSwitch
            Return 0
        Case $aGUIPallete[$idSliderGPosition]
            Switch $iCode
                Case $NM_CUSTOMDRAW
                    _GUIPallete_ColorSet(1, -1, GUICtrlRead($iIDFrom))
            EndSwitch
            Return 0
        Case $aGUIPallete[$idSliderGValue]
            Switch $iCode
                Case $NM_CUSTOMDRAW
                    _GUIPallete_ColorSet(1, GUICtrlRead($iIDFrom))
            EndSwitch
            Return 0
        Case $aGUIPallete[$idSliderGSpread]
            Switch $iCode
                Case $NM_CUSTOMDRAW
                    _GUIPallete_ColorSet(1, -1, "", GUICtrlRead($iIDFrom))
            EndSwitch
            Return 0
        Case $aGUIPallete[$idSliderBPosition]
            Switch $iCode
                Case $NM_CUSTOMDRAW
                    _GUIPallete_ColorSet(2, -1, GUICtrlRead($iIDFrom))
            EndSwitch
            Return 0
        Case $aGUIPallete[$idSliderBValue]
            Switch $iCode
                Case $NM_CUSTOMDRAW
                    _GUIPallete_ColorSet(2, GUICtrlRead($iIDFrom))
            EndSwitch
            Return 0
        Case $aGUIPallete[$idSliderBSpread]
            Switch $iCode
                Case $NM_CUSTOMDRAW
                    _GUIPallete_ColorSet(2, -1, "", GUICtrlRead($iIDFrom))
            EndSwitch
            Return 0
        Case $aGUIPlasmaEditor[$idSliderPlasmaSpread]
            Switch $iCode
                Case $NM_CUSTOMDRAW
                    $aPlasmas[$iSelectPlasma][1] = 0.2 * GUICtrlRead($iIDFrom)
            EndSwitch
            Return 0
        Case $aGUIPlasmaEditor[$idSliderPlasmaRotation]
            Switch $iCode
                Case $NM_CUSTOMDRAW

            EndSwitch
            Return 0
        Case $aGUIPlasmaEditor[$idSliderPlasmaPosition]
            Switch $iCode
                Case $NM_CUSTOMDRAW
                    $aPlasmas[$iSelectPlasma - 1][2] = GUICtrlRead($iIDFrom)
            EndSwitch
            Return 0
    EndSwitch

    Return 0
EndFunc   ;==>_WM_NOTIFY

Func _Zoom()
    Local $bPlaying = $bIsPlaying
    If $bPlaying Then $bIsPlaying = False
    Local $iCtrlID = @GUI_CtrlId
    Switch $iCtrlID
        Case $aGUI[$idMnuOptionsZoomOut]
            $iCols += 2
            $iRows += 2
            If $iCols >= 4 * 8 Then $iCols = 4 * 8
            If $iRows >= 4 * 8 Then $iRows = 4 * 8
        Case $aGUI[$idMnuOptionsZoomIn]
            $iCols -= 2
            $iRows -= 2
            If $iCols <= 4 Then $iCols = 4
            If $iRows <= 4 Then $iRows = 4
    EndSwitch
    If $bPlaying Then $bIsPlaying = $bPlaying
EndFunc   ;==>_Zoom
#EndRegion - Main GUI Functions
#Region - Pallete Mixer GUI Functions
Func _GUIPallete_ColorSet($iColor, $iValue = -1, $iPosition = "", $iSpread = "")
    If $iValue >= 0 Then $aPalleteSettings[$iColor][2] = (128.0 - $iValue)
    If $iPosition Then $aPalleteSettings[$iColor][0] = (0.25 * $iPosition)
    If $iSpread Then $aPalleteSettings[$iColor][1] = ($iSpread ^ 2)
    Return _GUIPallete_Update()
EndFunc   ;==>_GUIPallete_ColorSet

Func _GUIPallete_Draw()
    ;Draw Color Pallete in Palette Mixer GUI
    _GDIPlus_GraphicsClear($hBackbufferPallete, 0xFF000000)
    Local $iX = 0
    For $iColor = 1 To 256
        Local $dARGB = $aPallete[$iColor - 1]
        ;Set Brush Color
        _GDIPlus_BrushSetSolidColor($hBrushPallete, $dARGB)
        ;Draw Color Bar to Bitmap
        _GDIPlus_GraphicsFillRect($hBackbufferPallete, $iX, 0, 320 / 256, 40, $hBrushPallete)
        $iX += (320 / 256)
    Next
    ;Write Bitmap to Screen
    Return _WinAPI_BitBlt($hDCPallete, 8, 8, 320, 40, $hDC_backbufferPallete, 0, 0, $SRCCOPY) ;blit drawn bitmap to GUI
EndFunc   ;==>_GUIPallete_Draw

Func _GUIPallete_Exit()
    ; Clean up resources
    GUIDelete()
    _GDIPlus_BrushDispose($hBrushPallete)
    _GDIPlus_GraphicsDispose($hBackbufferPallete)
    _WinAPI_SelectObject($hDCPallete, $DC_objPallete)
    _WinAPI_DeleteObject($hHBitmapPallete)
    _WinAPI_ReleaseDC($aGUIPallete[$hGUIPallete], $hDCPallete)
    Return 1
EndFunc   ;==>_GUIPallete_Exit

Func _GUIPallete_Hide()
    Return GUISetState(@SW_HIDE, $aGUIPallete[$hGUIPallete])
EndFunc   ;==>_GUIPallete_Hide

Func _GUIPallete_Reset()
    $aPalleteSettings = $aPalleteDefaults
    GUICtrlSetData($aGUIPallete[$idSliderRPosition], $aPalleteSettings[0][0] / 0.25)
    GUICtrlSetData($aGUIPallete[$idSliderRValue], 128 - $aPalleteSettings[0][2])
    GUICtrlSetData($aGUIPallete[$idSliderRSpread], Sqrt($aPalleteSettings[0][1]))
    GUICtrlSetData($aGUIPallete[$idSliderGPosition], $aPalleteSettings[1][0] / 0.25)
    GUICtrlSetData($aGUIPallete[$idSliderGValue], 128 - $aPalleteSettings[1][2])
    GUICtrlSetData($aGUIPallete[$idSliderGSpread], Sqrt($aPalleteSettings[1][1]))
    GUICtrlSetData($aGUIPallete[$idSliderBPosition], $aPalleteSettings[2][0] / 0.25)
    GUICtrlSetData($aGUIPallete[$idSliderBValue], 128 - $aPalleteSettings[2][2])
    GUICtrlSetData($aGUIPallete[$idSliderBSpread], Sqrt($aPalleteSettings[2][1]))
    Return _GUIPallete_Update()
EndFunc   ;==>_GUIPallete_Reset

Func _GUIPallete_ShiftToggle()
    ;Toggle Pallete Shift
    Local $iCtrlState = GUICtrlRead(@GUI_CtrlId)
    If BitAND($iCtrlState, $GUI_CHECKED) Then
        ;Disable PalleteShift
        $bPalleteShift = False
        GUICtrlSetState(@GUI_CtrlId, $GUI_UNCHECKED)
    Else
        ;Enable PalleteShift
        $bPalleteShift = True
        GUICtrlSetState(@GUI_CtrlId, $GUI_CHECKED)
    EndIf
EndFunc   ;==>_GUIPallete_ShiftToggle

Func _GUIPallete_Show()
    GUISetState(@SW_SHOW, $aGUIPallete[$hGUIPallete])
    _GUIPallete_Draw()
EndFunc   ;==>_GUIPallete_Show

Func _GUIPallete_Update()
    ;Re-Calculate Work Color Pallete
    For $iStep = 0 To 255
        Local $iR = Int($aPalleteSettings[0][2] + ($aPalleteSettings[0][2] * Sin((3.1415 * $iStep / $aPalleteSettings[0][1]) - $aPalleteSettings[0][0])))
        Local $iG = Int($aPalleteSettings[1][2] + ($aPalleteSettings[1][2] * Sin((3.1415 * $iStep / $aPalleteSettings[1][1]) - $aPalleteSettings[1][0])))
        Local $iB = Int($aPalleteSettings[2][2] + ($aPalleteSettings[2][2] * Sin((3.1415 * $iStep / $aPalleteSettings[2][1]) - $aPalleteSettings[2][0])))
        $aPallete[$iStep] = "0xFF" & Hex($iR, 2) & Hex($iG, 2) & Hex($iB, 2)
    Next
    Return _GUIPallete_Draw()
EndFunc   ;==>_GUIPallete_Update
#EndRegion - Pallete Mixer GUI Functions
#Region - Plasma Editor GUI Functions
Func _GUIPlasmaEditor_Hide()
    GUISetState(@SW_HIDE, $aGUIPlasmaEditor[$hGUIPlasmaEditor])
EndFunc   ;==>_GUIPlasmaEditor_Hide

Func _GUIPlasmaEditor_PlasmaAddRem()

EndFunc   ;==>_GUIPlasmaEditor_PlasmaAddRem

Func _GUIPlasmaEditor_PlasmaDisplay()
    Local $sSelection = GUICtrlRead($aGUIPlasmaEditor[$idCmbPlasmaDisplay])
    If $sSelection = "All Combined" Then
        $iDisplayPlasma = 0
    Else
        $iDisplayPlasma = _GUICtrlComboBox_GetCurSel($aGUIPlasmaEditor[$idCmbPlasmaSelector])+1
    EndIf
    Return $iDisplayPlasma
EndFunc   ;==>_GUIPlasmaEditor_PlasmaDisplay

Func _GUIPlasmaEditor_PlasmaSelect()
    Local $sSelection = GUICtrlRead($aGUIPlasmaEditor[$idCmbPlasmaSelector])
    $iSelectPlasma = _GUICtrlComboBox_GetCurSel($aGUIPlasmaEditor[$idCmbPlasmaSelector])
    _GUIPlasmaEditor_PlasmaDisplay()
    Return _GUIPlasmaEditor_PlasmaSettingsLoad($iSelectPlasma)
EndFunc   ;==>_GUIPlasmaEditor_PlasmaSelect

Func _GUIPlasmaEditor_PlasmaSetPosition()

EndFunc   ;==>_GUIPlasmaEditor_PlasmaSetPosition

Func _GUIPlasmaEditor_PlasmaSetRotation()

EndFunc   ;==>_GUIPlasmaEditor_PlasmaSetRotation

Func _GUIPlasmaEditor_PlasmaSetShape()
    $aPlasmas[$iSelectPlasma][0] = _GUICtrlComboBox_GetCurSel($aGUIPlasmaEditor[$idCmbPlasmaShape])
EndFunc   ;==>_GUIPlasmaEditor_PlasmaSetShape

Func _GUIPlasmaEditor_PlasmaSetSpread()
    $aPlasmas[$iSelectPlasma][4] = _GUICtrlComboBox_GetCurSel($aGUIPlasmaEditor[$idCmbPlasmaSpread])
EndFunc   ;==>_GUIPlasmaEditor_PlasmaSetSpread

Func _GUIPlasmaEditor_PlasmaSettingsLoad(ByRef $iPlasma)
    GUICtrlSetData($aGUIPlasmaEditor[$idSliderPlasmaSpread],$aPlasmas[$iPlasma][1]/0.2)
    _GUICtrlComboBox_SetCurSel($aGUIPlasmaEditor[$idCmbPlasmaShape],$aPlasmas[$iPlasma][0])
    If $aPlasmas[$iPlasma][4] Then
        _GUICtrlComboBox_SetCurSel($aGUIPlasmaEditor[$idCmbPlasmaSpread],1)
    Else
        _GUICtrlComboBox_SetCurSel($aGUIPlasmaEditor[$idCmbPlasmaSpread],0)
    EndIf
    Return 1
EndFunc   ;==>_GUIPlasmaEditor_PlasmaSettingsLoad

Func _GUIPlasmaEditor_Show()
    GUISetState(@SW_SHOW, $aGUIPlasmaEditor[$hGUIPlasmaEditor])
EndFunc   ;==>_GUIPlasmaEditor_Show
#EndRegion - Plasma Editor GUI Functions

edit: Minor tweaks

Edited October 6, 2017 by spudw2k

[Guest]

Looks cool.
It works slow in hgih resolution
I am not surprised, this is probably because Autoit is slow.
Anything related to image processing should not be done in Autoit unless you do it for fun..

This is the first time that I see code that written like my suggestion

[spudw2k]

Thanks.  Yes, unfortunately higher res is much slower. I was considering porting my script at some point to VS2015, but that's going to be a bit of a learning curve for me.

I usually only use "Regions" when my scripts grow very big. I find them useful for organizing code as well.

[UEZ]

I added the ASM code _ASM_DrawRectFilled  to speedup a little bit the draw function:

expandcollapse popup

;coded by UEZ build 2016-02-12
#pragma compile(Icon, "c:\Program Files (x86)\AutoIt3\Icons\au3.ico")
#AutoIt3Wrapper_Run_Au3Stripper=y
#Au3Stripper_Parameters=/so /pe /rm
#AutoIt3Wrapper_Run_After=del /f /q "%scriptdir%\%scriptfile%_stripped.au3"

#include <GDIPlus.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>

_GDIPlus_Startup()
Global $hGUI, $iFPS = 0, $iShowFPS = 0, $bExit, $pBitmap, $hHBitmap
Global Const $iW = 384, $iH = 256, $sTitle = "GDI+ Plasma v5"
Global Const $fPi = ACos(-1)
AutoItSetOption("GUIOnEventMode", 1)

GDIPlus_Plasmav5()

AutoItSetOption("GUIOnEventMode", 0)
_GDIPlus_Shutdown()


Func GDIPlus_Plasmav5()
    $bExit = False
    $hGUI = GUICreate($sTitle, $iW, $iH)
    GUISetState(@SW_SHOW, $hGUI)

    ;create canvas elements
    Local Const $hDC = _WinAPI_GetDC($hGUI)
    Local Const $hDC_backbuffer = _WinAPI_CreateCompatibleDC($hDC)
    Local Const $hHBitmap = _WinAPI_BitmapCreateDIB($iW, $iH, $pBitmap)
    Local Const $DC_obj = _WinAPI_SelectObject($hDC_backbuffer, $hHBitmap)
    Local Const $hCanvas = _GDIPlus_GraphicsCreateFromHDC($hDC_backbuffer)
;~  _GDIPlus_GraphicsSetSmoothingMode($hCanvas, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
    _GDIPlus_GraphicsSetPixelOffsetMode($hCanvas, $GDIP_PIXELOFFSETMODE_HIGHQUALITY)

    Local Const $hBrush_FPS = _GDIPlus_BrushCreateSolid(0xF0101010), _
                $hFormat_FPS = _GDIPlus_StringFormatCreate(), _
                $hFamily_FPS = _GDIPlus_FontFamilyCreate("Arial"), _
                $hFont_FPS = _GDIPlus_FontCreate($hFamily_FPS, 8), _
                $tLayout_FPS = _GDIPlus_RectFCreate(0, 0, 60, 16)

    $iFPS = 0
    GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit_About")

    Local $fTime = 0, $iSizeW = 8, $iSizeH = 8, $cx, $cy, $v, $iX, $iY, $f1, $iColor

    Local $tCodeBuffer = DllStructCreate("byte ASM[192]") ;reserve memory for ASM opcodes
    $tCodeBuffer.ASM = "0x8B7424048B7C2408558B6F1831C08B078985A800000083ADA8000000018B47048985AC00000083ADAC000000018B47088985B00000008B470C8985B40000008B47108985B80000008B47148985BC000000E8020000005DC3505351528B9DB00000008B8DB800000031C00385AC0000000385B4000000F7A5BC0000000385B00000000385A8000000890C8683ADB00000000177D4899DB000000083ADB40000000175C55A595B58C3000000000000000000000000000000000000000000000000" ;write opcodes into memory (struct) / length: 192
    Local $tRect = DllStructCreate("dword iPosX;dword iPosY;dword iW; dword iH;dword ARGB;dword iWidth;dword iBase")
    $tRect.iW = $iSizeW
    $tRect.iH = $iSizeH
    $tRect.iWidth = $iW
    $tRect.iBase = DllStructGetPtr($tCodeBuffer) ;pointer to asm code in the memory

    AdlibRegister("CalcFPS", 1000)

    Do
        For $iY = 0 To $iH - $iSizeH Step $iSizeH
            For $iX = 0 To $iW - $iSizeW Step $iSizeW

                $cx = $iX + 128 * Sin(Dist($fTime * 1.5, $iX, $iY, 32) / 48)
                $cy = $iY + 92 * Cos(Dist($iY, 128, $fTime * 2.5, 8) / 32)
                $v = Cos(Sqrt($cx * $cx + $cy * $cy) / 512 + $fTime)

                $f1 = $v * $fPi
                $tRect.ARGB = 0xFF000000 + _
                              BitShift((Abs(Cos($f1 / 2)) * 0xFF), -16) + _
                              BitShift((Abs(Sin($f1 * 2)) * 0xFF), -8) + _
                              Int(Abs(Cos($f1 / 1.5)) * 0xFF)

                $tRect.iPosX = $iX
                $tRect.iPosY = $iY

                DllCallAddress("uint:cdecl", $tRect.iBase, "ptr", $pBitmap, "struct*", $tRect)

                $fTime += 0.0000075

            Next
        Next

        _GDIPlus_GraphicsDrawStringEx($hCanvas, "FPS: " & $iShowFPS, $hFont_FPS, $tLayout_FPS, $hFormat_FPS, $hBrush_FPS)
        _WinAPI_BitBlt($hDC, 0, 0, $iW, $iH, $hDC_backbuffer, 0, 0, $SRCCOPY)

        $iFPS += 1
        If $bExit Then ExitLoop
    Until Not Sleep(10)

    AdlibUnRegister("CalcFPS")
    ;release resources
    _GDIPlus_FontDispose($hFont_FPS)
    _GDIPlus_FontFamilyDispose($hFamily_FPS)
    _GDIPlus_StringFormatDispose($hFormat_FPS)
    _GDIPlus_BrushDispose($hBrush_FPS)
    _GDIPlus_GraphicsDispose($hCanvas)
    _WinAPI_SelectObject($hDC, $DC_obj)
    _WinAPI_DeleteObject($hHBitmap)
    _WinAPI_ReleaseDC($hGUI, $hDC)
    GUIDelete($hGUI)
EndFunc   ;==>GDIPlus_Plasmav5

Func Dist($a, $b, $c, $d)
    Return Sqrt(($a - $c) * ($a - $c) + ($b - $d) * ($b - $d))
EndFunc

Func _Exit_About()
    $bExit = True
EndFunc   ;==>_Exit_About

Func CalcFPS() ;display FPS
    $iShowFPS = $iFPS
    $iFPS = 0
EndFunc   ;==>CalcFPS

Func _WinAPI_BitmapCreateDIB($iWidth, $iHeight, ByRef $pHBitmap)
    Local $tBMI = DllStructCreate($tagBITMAPINFO)
    $tBMI.biSize = DllStructGetSize($tBMI) - 4
    $tBMI.biWidth = $iWidth
    $tBMI.biHeight = -$iHeight
    $tBMI.biPlanes = 1
    $tBMI.biBitCount = 32
    Local $aResult = DllCall("gdi32.dll", "ptr", "CreateDIBSection", "hwnd", 0, "struct*", $tBMI, "uint", 0, "ptr*", 0, "ptr", 0, "uint", 0)
    $pHBitmap = $aResult[4]
    Return $aResult[0]
EndFunc

 

8x8 px @384x256: without ASM ~ 7 fps, with ASM ~13 fps.

 

Might be useful for you.

Edited February 12, 2016 by UEZ

[spudw2k]

On 2/12/2016 at 0:09 PM, UEZ said:

I added the ASM code _ASM_DrawRectFilled  to speedup a little bit the draw function:
...
Might be useful for you.

Last week I got around to checking out some of your examples and stumbled across the ASM examples including the  _ASM_DrawRectFilled func.  I was curious what impact it would have on my script.  I'll have to give it a shot.

Edited February 15, 2016 by spudw2k

[Guest]

Try to make this:

 

 

I didn't I imagined and expected that is the best game that included in Windows is the Magnifier tool.
it is very fun game.

Edited February 15, 2016 by Guest

[Lakes]

Looks like a wind tunnel simulator.