How to Get the Command Line that a Running Process was Ran With?

[Zohar]

Hi

 

If you run ProcessExplorer, and add a column called "Command Line",

(can be found via RightClicking the Column Headers, and going to the Process Image tab)

you can see the command that the process was started with.

 

How can I get it programmatically inside AutoIt, for a process which I have its PID?

 

Thank you

[computergroove]

I would think you could just use ProcessList

https://www.autoitscript.com/autoit3/docs/functions/ProcessList.htm

If you already know the pid then you can compare it to the array created by processList (remember to use a loop so if a new process starts then it will include it in the array).

Share what you have for getting the PID (code)

Edited September 4, 2014 by computergroove

[spudw2k]

You could use WMI to retrieve the CommandLine.  Change the value of $PID in the example below for a demo.

; Generated by AutoIt Scriptomatic
$wbemFlagReturnImmediately = 0x10
$wbemFlagForwardOnly = 0x20
$colItems = ""
$strComputer = "localhost"
$PID = "0"
$Output=""
$Output = $Output & "Computer: " & $strComputer  & @CRLF
$Output = $Output & "==========================================" & @CRLF
$objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\root\CIMV2")
$colItems = $objWMIService.ExecQuery("SELECT * FROM Win32_Process WHERE ProcessID=" & $PID, "WQL", _
                                          $wbemFlagReturnImmediately + $wbemFlagForwardOnly)
If IsObj($colItems) then
   For $objItem In $colItems
      $Output = $Output & "Caption: " & $objItem.Caption & @CRLF
      $Output = $Output & "CommandLine: " & $objItem.CommandLine & @CRLF
      $Output = $Output & "ProcessId: " & $objItem.ProcessId & @CRLF
      if Msgbox(1,"WMI Output",$Output) = 2 then ExitLoop
      $Output=""
   Next
Else
   Msgbox(0,"WMI Output","No WMI Objects Found for class: " & "Win32_Process" )
Endif

[Exit]

$PID = @AutoItPID ; just to pick a PID

$oWMI = ObjGet("winmgmts:\\" & @ComputerName & "\root\CIMV2")
If @error Then
    RunWait(@ComSpec & ' /c net start winmgmt  ', '', @SW_HIDE)
    RunWait(@ComSpec & ' /c net continue winmgmt  ', '', @SW_HIDE)
    $oWMI = ObjGet("winmgmts:\\" & @ComputerName & "\root\CIMV2")
EndIf
$oProcesses = $oWMI.ExecQuery("SELECT * FROM Win32_Process", "WQL", 0x30)
For $oProcess In $oProcesses
    If $oProcess.ProcessId = $PID Then ExitLoop
Next
MsgBox(262144, Default, $oProcess.CommandLine, 0)

Edit: spudw2k was quicker

Edited September 4, 2014 by Exit

[Gianni]

this >link could also be of interest

[spudw2k]

this >link could also be of interest

Even better.

[UEZ]

Or just check out

_WinAPI_GetProcessCommandLine 

function in the help file.

Br,

UEZ

Edited September 4, 2014 by UEZ

[Gianni]

Or just check out

_WinAPI_GetProcessCommandLine 

function in the help file.

Br,

UEZ

Even better.

[Zohar]

Thank you all

 

Or just check out

_WinAPI_GetProcessCommandLine 

function in the help file.

Br,

UEZ

 

I cannot find this function in the help file.

I assume it's because I am not using the latest version..

I use v3.3.6.1..
 

[Gianni]

Thank you all

 

 

I cannot find this function in the help file.

I assume it's because I am not using the latest version..

I use v3.3.6.1..

 

 

you can use >this then

[BrewManNH]

Thank you all

 

 

I cannot find this function in the help file.

I assume it's because I am not using the latest version..

I use v3.3.6.1..

 

Yes, it's because you're using a very old version, so that function isn't in there. _WinAPIEx was added to the UDFs back in December 2013 to version 3.3.10.0.

[Zohar]

OK I understand.

BTW, maybe I should tell you what is the bigger picture.

I am writing a small function that will prevent more than 1 instance of a script running.

the code to do it is quite simple:

Func    CheckIfAnotherInstanceLikeMeExists()
Local   $Array_ProcessList  =ProcessList(@ScriptName)
Return ($Array_ProcessList[0][0]>1)
EndFunc

This code resides in a Common UDF that I created, and use among my scripts.

 

The problem:

It works for compiled scripts, but not for not-yet-compiled(au3) scripts.

Why?

Because compiled scripts have their process name like the name of the script, for example "SomeScript.exe".

When scripts that are still in source are ran, their process name is "AutoIt3.exe".

So I want my function to work also if the script is not compiled yet.

I found via ProcessExplorer that the CommandLine data holds the name of the script.

But is there another way to do it?

Edited September 4, 2014 by Zohar

[Jos]

What's wrong with the _Singleton() UDF?

Jos

[jguinch]

Something like this ?

#include <WinAPIProc.au3>

$iPID = @AutoItPID
$sFullExe = @AutoItExe
$sExe = StringRegExpReplace($sFullExe, ".*\\", "")

$aProcessList = ProcessList($sExe)
For $i = 1 To $aProcessList[0][0]
    If $aProcessList[$i][1] = $iPID Then ContinueLoop
    $sFileName = _WinAPI_GetProcessFileName($aProcessList[$i][1])
    If $sFileName = $sFullExe Then
        ConsoleWrite("Launched two times !")
        Exit
    EndIf
Next

[Zohar]

jguinch:

Thank  you looks good, however I don't have this function too, due to my AutoIt version..

 

jos:

I completely forgot about it.. I will use it now, thank you