Regular Expression To Confirm an IPv4 Address

[gruntydatsun]

Hello,

Is this regular expression suitable for determining if a string is an IPv4 address?

/^(\d+.){3}\d+$/

Possible values     1-255.0-255.0-255.0-255

 

[guinness]

No, it just determines whether a string contains digits.digits.digits.digits. So 456.765.987.999 would be valid though is not a valid IP. Search the Forum for IP validation.

[jchd]

Try this:

Local $aIPs = [ _
    "10.89.185.2", _
    "0.96.0.194", _
    " 100.100 . 250.123", _
    "140.red.tde.net:80", _
    "256.100.526.210", _
    "108.9.10.626", _
    "141-52.8.80", _
    "141.24.249.129", _
    "141.24-249.129", _
    "141..249.130.", _
    "141.24.249.*1", _
    "141.24.33.161", _
    "141.24:.33.161", _
    "141.155.238.1438", _
    "141.24.033.162", _
    "141.24.33.192", _
    "141.16.94.X0" _
]

For $ipv4 In $aIPs
    ConsoleWrite($ipv4 & " -> " & (StringRegExp($ipv4, "^(?:[1-9]|[1-9]\d|1\d\d|2[0-4]\d|25[0-5])(?:\.(?:\d|[1-9]\d|1\d\d|2[0-4]\d|25[0-5])){3}$", 0) ? "" : "in") & "valid" & @LF)
Next

[mLipok]

very nice and handy RegExp   @jchd

mLipok

[Gianni]

also:

Func _isIPaddr($sIPAddr) ; returns true if argument is a plausible IP address
     If Not StringRegExp($sIPAddr, "^((25[0-5]|2[0-4]d|[01]?d?d).){3}(25[0-5]|2[0-4]d|[01]?d?d)$") Then Return SetError(1, 0, False)
     Return True
EndFunc ;==>_isIPaddr (*) do not use, see post >#6 below

Func _isSNmask($sSNmask) ; returns true if argument is a correct 4 digit network mask
    If Not StringRegExp($sSNmask, "^(((255\.){3}(255|254|252|248|240|224|192|128|0+))|((255\.){2}(255|254|252|248|240|224|192|128|0+)\.0)|((255\.)(255|254|252|248|240|224|192|128|0+)(\.0+){2})|((255|254|252|248|240|224|192|128|0+)(\.0+){3}))$") Then Return SetError(1, 0, False)
    Return True
EndFunc   ;==>_isSNmask

Edited July 30, 2014 by Chimp

[jchd]

This regexp is commonly found on regexp examples websites but unfortunately it's wrong:

ConsoleWrite("0.1.2.3" & " -> " & (_isIPaddr("0.1.2.3") ? "" : "in") & "valid" & @LF)

[funkey]

Different approaches, different results!?

expandcollapse popup

Local $aIPs[18] = [ _
    "10.89.185.2", _
    "0.96.0.194", _
    " 100.100 . 250.123", _
    "140.red.tde.net:80", _
    "256.100.526.210", _
    "108.9.10.626", _
    "141-52.8.80", _
    "141.24.249.129", _
    "141.24-249.129", _
    "141..249.130.", _
    "141.24.249.*1", _
    "141.24.33.161", _
    "141.24:.33.161", _
    "141.155.238.1438", _
    "141.24.033.162", _
    "141.24.33.192", _
    "141.16.94.X0", _
    "0.0.0.0" _
]

Local Const $AF_INET = 2
Local Const $tagIN_ADDR = "ulong S_addr;"

Local $tAddr_In = DllStructCreate($tagIN_ADDR)

ConsoleWrite("_InetPton:" & @LF)
For $ipv4 In $aIPs
    ConsoleWrite($ipv4 & " -> " & _InetPton($ipv4, $tAddr_In) & @LF)
Next

ConsoleWrite(@LF)
ConsoleWrite("StringRegExp:" & @LF)
For $ipv4 In $aIPs
    ConsoleWrite($ipv4 & " -> " & StringRegExp($ipv4, "^(?:[1-9]|[1-9]\d|1\d\d|2[0-4]\d|25[0-5])(?:\.(?:\d|[1-9]\d|1\d\d|2[0-4]\d|25[0-5])){3}$", 0) & @LF)
Next

ConsoleWrite(@LF)
ConsoleWrite("_IsValidIP:" & @LF)
For $ipv4 In $aIPs
    ConsoleWrite($ipv4 & " -> " & _IsValidIP($ipv4) & @LF)
Next

Func _InetPton($sIP, ByRef $tIN_ADDR, $iFamily = $AF_INET) ;IPv4 and IPv6 --> Vista and above
    Local $aRet = DllCall("ws2_32.dll", "int", "InetPtonW", "int", $iFamily, "wstr", $sIP, "struct*", $tIN_ADDR)
    Switch $aRet[0]
        Case -1
            Return SetError(1, 0, $aRet[0]) ; error, check with _WSAGetLastError()
        Case 0
            Return SetError(2, 0, $aRet[0]) ; wrong IP address
    EndSwitch
    Return $aRet[0]
EndFunc   ;==>_InetPton

Func _IsValidIP($sIP)
    Local $aIP = StringSplit($sIP, ".")
    If $aIP[0] <> 4 Then Return SetError(1, 0, 0)
    For $x = 1 To $aIP[0]
        If $aIP[$x] < 0 Or $aIP[$x] > 255 Then Return SetError(2, $x, 0)
    Next
    Return 1
EndFunc   ;==>_IsValidIP

[spudw2k]

@funkey

Regarding _IsValidIP, there are definately false positives (particularly when non number chars are used). I believe when you do an If statement with a "string" and don't do a literal compare (==) it will return 0.

I'm not sure why _InetPton accepts 0.96.0.194 and 0.0.0.0 as valid IP either, as they are typically not considered valid IPs (certainly not routable addresses anyway).
 

[BrewManNH]

Neither of those 2 functions are valid for IP addresses, they both return false positives. This one on the other hand doesn't have that problem, it returns the correct result.

You will need to change the comparison function though, because it doesn't return a simple 1 or 0 if not valid.

ConsoleWrite(@LF)
ConsoleWrite("_ValidIP:" & @LF)
For $ipv4 In $aIPs
    $bValid = (_ValidIP($ipv4) = -1) ? 0 : 1
    ConsoleWrite($ipv4 & " -> " & $bValid & @LF)
Next

[jchd]

It depends what you consider IP address. Local addresses don't have the limitations you mention.

[BrewManNH]

Anything that falls outside of a Class A/B/C address block I'd consider invalid, anything that falls inside a 10.xx.xx.xx/172.xx.xx.xx/192.xx.xx.xx I'd consider to be a private address, anything that starts with 0, 127 or 169 are invalid IP addresses. Anything that starts higher than 223 is a reserved address but can have special uses. Other than that, what you use on your own network is up to you.

RegEx is particularly problematic for finding valid IP address ranges, I've seen hundreds and they all fail simple tests.

[computergroove]

#include <Array.au3>
#include <File.au3>
#include <MsgBoxConstants.au3>

Local $aArray[5]
Local $ipAddr = "127.0.0.1"
$aArray = StringSplit($ipAddr, ".")
;_ArrayDisplay($aArray)

For $i = 1 to $aArray[0]
    If $aArray[$i] > 255 Then
        MsgBox(0,"Results","This is not a valid IP Address")
        Exit
    EndIf
Next

MsgBox(0,"Results","Test Passed")

How about this?

[guinness]

computergroove,

I am a little old fashioned, but I would be careful when comparing strings as integers. AutoIt is forgiving, but sometimes it can bite you when you least expect it. Also BrewManNH's version adopts the same approach albeit a little better and wrapped up in a usable function.

[ball58]

Try this one out. Works well for me...

$isIP = StringRegExp($string,'^(([0-1]?[0-9]?[1-9])|([0-1]?[1-9][0-9]?)|(1[0-9]?[0-9]?)|(2[0-4][0-9])|(25[0-4]))((.(([0-1]?[0-9]?[0-9])|(2[0-4][0-9])|(25[0-4]))){3})$')

[BrewManNH]

Try this one out. Works well for me...

$isIP = StringRegExp($string,'^(([0-1]?[0-9]?[1-9])|([0-1]?[1-9][0-9]?)|(1[0-9]?[0-9]?)|(2[0-4][0-9])|(25[0-4]))((.(([0-1]?[0-9]?[0-9])|(2[0-4][0-9])|(25[0-4]))){3})$')

That one works well, but still shows 127.xx.xx.xx/169.xx.xx.xx addresses as valid, neither of which is. It also marks as valid an IP address that ends in 0, which shouldn't be used in most cases.