SubnetCalc [working]

[spudw2k]

I am working on a simple Subnet Calc GUI.  Here is the form; still working on GUI logic (starting with Subnet Mask logic).

Experiencing weird crash issue when trying to call _ArrayDisplay from within a WM_COMMAND func.
Shouldn't need _ArrayDisplay in final code, but just thought it was weird.
Explained below
 

expandcollapse popup

#Region - Includes and Globals
#AutoIt3Wrapper_UseX64=n
#include <Array.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiIPAddress.au3>
#include <GuiEdit.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode", 1)
Global $iDebug = False
Global $aGUI[1] = ["hwnd|id"]
Global Enum $hGUI = 1, $idDummyEnter, $idIPHost, $idIPSubnetMask, $idIPStart, $idIPEnd, $idIPNet, $idIPBroadcast, $idSubnetBits, $idHostCount, $iGUILast
ReDim $aGUI[$iGUILast]
#EndRegion - Includes and Globals

#Region - GUI Design
$aGUI[$hGUI] = GUICreate("IP Subnet Calc", 258, 330)
$aGUI[$idDummyEnter] = GUICtrlCreateDummy()
GUICtrlSetOnEvent(-1, "_Enter")

GUICtrlCreateGroup("Host", 8, 8, 241, 90)
GUICtrlSetFont(-1, 10, 800, 0, "Lucida Console")

GUICtrlCreateLabel("IP Addr:", 17, 35, 60, 17)
$aGUI[$idIPHost] = _GUICtrlIpAddress_Create($aGUI[$hGUI], 70, 33, 130, 18)

GUICtrlCreateLabel("/", 204, 35, 20, 17)
$aGUI[$idSubnetBits] = GUICtrlCreateInput("0", 212, 33, 24, 18, BitOR($GUI_SS_DEFAULT_INPUT, $ES_CENTER))

GUICtrlCreateLabel("Subnet:", 17, 67, 60, 17)
$aGUI[$idIPSubnetMask] = _GUICtrlIpAddress_Create($aGUI[$hGUI], 70, 65, 130, 18)

GUICtrlCreateGroup("", -99, -99, 1, 1)


GUICtrlCreateGroup("Network", 8, 108, 241, 212)
GUICtrlSetFont(-1, 10, 800, 0, "Lucida Console")

GUICtrlCreateLabel("Start IP:", 17, 135, 76, 17)
$aGUI[$idIPStart] = _GUICtrlIpAddress_Create($aGUI[$hGUI], 90, 133, 130, 18, $WS_DISABLED)

GUICtrlCreateLabel("End IP:", 17, 167, 60, 17)
$aGUI[$idIPEnd] = _GUICtrlIpAddress_Create($aGUI[$hGUI], 90, 165, 130, 18, $WS_DISABLED)

GUICtrlCreateLabel("No. Hosts:", 17, 199, 84, 17)
$aGUI[$idHostCount] = GUICtrlCreateInput("0", 120, 197, 68, 18, BitOR($GUI_SS_DEFAULT_INPUT, $ES_CENTER, $ES_READONLY))
GUICtrlSetBkColor(-1, 0xffffff)

GUICtrlCreateLabel("Net Addr:", 17, 250, 76, 17)
$aGUI[$idIPNet] = _GUICtrlIpAddress_Create($aGUI[$hGUI], 90, 248, 130, 18, $WS_DISABLED)

GUICtrlCreateLabel("Broadcast:", 17, 282, 76, 17)
$aGUI[$idIPBroadcast] = _GUICtrlIpAddress_Create($aGUI[$hGUI], 90, 280, 130, 18, $WS_DISABLED)

GUICtrlCreateGroup("", -99, -99, 1, 1)
#EndRegion - GUI Design

#Region - Execution / Main Loop
_GetIPandSubnet()
_UpdateForm()

Local $aAccelKeys[1][2] = [["{enter}", $aGUI[$idDummyEnter]]]
GUISetAccelerators($aAccelKeys)

GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
GUISetState(@SW_SHOW)

;Main Loop
While 1
    Sleep(10)
WEnd

Exit
#EndRegion - Execution / Main Loop

#Region - GUI Logic / User Defined Funcs
Func _Exit()
    Exit
EndFunc   ;==>_Exit

Func _Enter()
    Local $hWnd = ControlGetFocus($aGUI[$hGUI])
    Local $iX = Int(StringRight($hWnd, 1))
    Switch $iX
        Case 1 To 4
            ;IP Address Field Updated
            Return _UpdateForm()
        Case 5 To 8
            ;Subnet Mask Field Updated
            Return _UpdateForm(1)
        Case Else
            ;Subnet Bits Field Updated
            Return _UpdateForm()
    EndSwitch
EndFunc   ;==>_Enter

Func _GetIPandSubnet()
    ;Set Defaults if WMI COM Object fails
    For $iX = $idIPHost To $idIPBroadcast
        _GUICtrlIpAddress_Set($aGUI[$iX], "0.0.0.0")
    Next

    Local $oWMI = ObjGet("winmgmts:\\.\root\CIMV2")
    If Not IsObj($oWMI) Then Return 0

    Local $oCol = $oWMI.ExecQuery("SELECT IPAddress, IPSubnet, DefaultIPGateway FROM Win32_NetworkAdapterConfiguration WHERE IPEnabled = 'True'")
    Local $oEntity

    For $oEntity In $oCol
        _GUICtrlIpAddress_Set($aGUI[$idIPHost], $oEntity.IPAddress(0))
        _GUICtrlIpAddress_Set($aGUI[$idIPSubnetMask], $oEntity.IPSubnet(0))
    Next

    GUICtrlSetData($aGUI[$idSubnetBits], _IPSubnetMaskToBits(_GUICtrlIpAddress_GetArray($aGUI[$idIPSubnetMask])))

    $oCol = 0
    $oWMI = 0
EndFunc   ;==>_GetIPandSubnet

Func _IPCalcWildcardMask($iBits, $iAddresses)
    Local $aIP[4] = [0, 0, 0, 0]
    $aIP[3] = Mod($iAddresses, 2 ^ 8) + 1

    If $iBits <= 16 Then
        $aIP[2] = 255
    Else
        $aIP[2] = ($iAddresses - Mod($iAddresses, 2 ^ 8)) / 2 ^ 8
    EndIf

    If $iBits <= 8 Then
        $aIP[1] = 255
    Else
        $aIP[1] = ($iAddresses - Mod($iAddresses, 2 ^ 16)) / 2 ^ 16
    EndIf

    If $iBits >= 8 Then
        $aIP[0] = 0
    Else
        $aIP[0] = ($iAddresses - Mod($iAddresses, 2 ^ 24)) / 2 ^ 24
    EndIf

    If $iDebug Then ConsoleWrite("Wilcard Mask: ")
    For $iX = 0 To 3
        If $iDebug Then ConsoleWrite($aIP[$iX])
        If $iX < 3 Then
            If $iDebug Then ConsoleWrite(".")
        EndIf
    Next

    If $iDebug Then ConsoleWrite(@CRLF)
    Return $aIP
EndFunc   ;==>_IPCalcWildcardMask

Func _IPCalcNetAddr($aIPAddress, $aSubnetMask)
    Local $aIP[4]
    For $iX = 0 To 3
        $aIP[$iX] = BitAND($aIPAddress[$iX], $aSubnetMask[$iX])
    Next

    If $iDebug Then ConsoleWrite("Network Addr: ")
    For $iX = 0 To 3
        If $iDebug Then ConsoleWrite($aIP[$iX])
        If $iX < 3 Then
            If $iDebug Then ConsoleWrite(".")
        EndIf
    Next

    If $iDebug Then ConsoleWrite(@CRLF)
    Return $aIP
EndFunc   ;==>_IPCalcNetAddr

Func _IPCalcSubnetMask($aWildCardMask)
    Local $aIP[4]
    For $iX = 0 To 3
        $aIP[$iX] = (2 ^ 8) - $aWildCardMask[$iX] - 1
    Next

    If $iDebug Then ConsoleWrite("Subnet Mask: ")
    For $iX = 0 To 3
        If $iDebug Then ConsoleWrite($aIP[$iX])
        If $iX < 3 Then
            If $iDebug Then ConsoleWrite(".")
        EndIf
    Next

    If $iDebug Then ConsoleWrite(@CRLF)
    Return $aIP
EndFunc   ;==>_IPCalcSubnetMask

Func _IPCalcBroadcast($aWildCardMask, $aNetworkAddr)
    Local $aIP[4]
    For $iX = 0 To 3
        $aIP[$iX] = $aWildCardMask[$iX] + $aNetworkAddr[$iX]
    Next

    If $iDebug Then ConsoleWrite("Broadcast Addr: ")
    For $iX = 0 To 3
        If $iDebug Then ConsoleWrite($aIP[$iX])
        If $iX < 3 Then
            If $iDebug Then ConsoleWrite(".")
        EndIf
    Next

    If $iDebug Then ConsoleWrite(@CRLF)
    Return $aIP
EndFunc   ;==>_IPCalcBroadcast

Func _IPSubnetBitsToAddresses($iBits)
    If ($iBits < 0) Or ($iBits > 31) Then Return -1
    Return (2 ^ (32 - $iBits)) - 2
EndFunc   ;==>_IPSubnetBitsToAddresses

Func _IPSubnetBitsToMask($iBits)
    $iBits = Int($iBits)
    If ($iBits < 0) Or ($iBits > 31) Then Return -1
EndFunc   ;==>_IPSubnetBitsToMask

Func _IPSubnetMaskToBits($aIP)
    Local $hIP = "", $sHex = "", $iBitCount
    For $iX = 0 To 3
        $sHex &= Hex($aIP[$iX], 2)
    Next

    $hIP &= Dec($sHex, 2)

    If Not _IPSubnetMaskIsValid($hIP) Then Return -1

    For $iX = 0 To 3
        If $aIP[$iX] Then
            If BitAND(255, $aIP[$iX]) = 255 Then
                $iBitCount += 8
            Else
                For $iY = 7 To 1 Step -1
                    If BitAND($aIP[$iX], 256 - (2 ^ $iY)) = $aIP[$iX] Then
                        $iBitCount += (8 - $iY)
                        ExitLoop
                    EndIf
                Next
            EndIf
        EndIf
    Next

    Return $iBitCount
EndFunc   ;==>_IPSubnetMaskToBits

Func _IPSubnetMaskIsValid($iDecIP)
    Local $iSubnetDec = 0, $bIsValid = False
    For $iX = 0 To 32
        If (((2 ^ 32) - 1) - ((2 ^ $iX) - 1)) = $iDecIP Then
            $bIsValid = True
            ExitLoop
        EndIf
    Next

    Return $bIsValid
EndFunc   ;==>_IPSubnetMaskIsValid

Func _UpdateForm($iMode = 0)
    If $iMode = 1 Then
        $iBits = _IPSubnetMaskToBits(_GUICtrlIpAddress_GetArray($aGUI[$idIPSubnetMask]))
        If $iBits >= 0 Then
            GUICtrlSetData($aGUI[$idSubnetBits], $iBits)
            ToolTip("")
        Else
            ToolTip("Invalid Subnet Mask Detected")
            Return -1
        EndIf
    EndIf

    $aHostIP = _GUICtrlIpAddress_GetArray($aGUI[$idIPHost])

    Local $iBits = GUICtrlRead($aGUI[$idSubnetBits])
    If $iDebug Then ConsoleWrite("Bits: " & $iBits & @CRLF)

    Local $iAddresses = _IPSubnetBitsToAddresses($iBits)
    If $iDebug Then ConsoleWrite("Addrs: " & $iAddresses & @CRLF)

    $aWildCardMask = _IPCalcWildcardMask($iBits, $iAddresses)
    $aSubnetMask = _IPCalcSubnetMask($aWildCardMask)
    $aNetworkAddr = _IPCalcNetAddr($aHostIP, $aSubnetMask)
    $aBroadcastAddr = _IPCalcBroadcast($aWildCardMask, $aNetworkAddr)

    _GUICtrlIpAddress_SetArray($aGUI[$idIPSubnetMask], $aSubnetMask)
    GUICtrlSetData($aGUI[$idHostCount], $iAddresses)
    _GUICtrlIpAddress_SetArray($aGUI[$idIPNet], $aNetworkAddr)
    _GUICtrlIpAddress_SetArray($aGUI[$idIPBroadcast], $aBroadcastAddr)
    $aNetworkAddr[3] += 1
    $aBroadcastAddr[3] -= 1
    _GUICtrlIpAddress_SetArray($aGUI[$idIPStart], $aNetworkAddr)
    _GUICtrlIpAddress_SetArray($aGUI[$idIPEnd], $aBroadcastAddr)

    If $iDebug Then ConsoleWrite(@CRLF & @CRLF)
EndFunc   ;==>_UpdateForm

Func _WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
    Local $nNotifyCode = BitShift($wParam, 16)
    ;Local $nID = BitAND($wParam, 0x0000FFFF)
    Local $hCtrl = $lParam

    Select
        Case $hCtrl = $aGUI[$idIPHost]
            If $nNotifyCode <> 512 Then
                Return $GUI_RUNDEFMSG
            Else
                ;Left IP Host Field
                Return _UpdateForm()
            EndIf
        Case $hCtrl = $aGUI[$idIPSubnetMask]
            If $nNotifyCode <> 512 Then
                Return $GUI_RUNDEFMSG
            Else
                ;Left Subnet Mask Field
                Return _UpdateForm(1)
            EndIf
        Case $hCtrl = GUICtrlGetHandle($aGUI[$idSubnetBits])
            If $nNotifyCode <> 512 Then
                Return $GUI_RUNDEFMSG
            Else
                ;Left Subnet Bits Field
                Return _UpdateForm()
            EndIf
    EndSelect

    Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_COMMAND
#EndRegion - GUI Logic / User Defined Funcs

edit:
Changed HotKeySet functionality to GUISetAccelerators
Added missing octet to subnet mask octet array (240)

Updated on 2016-06-01

Edited June 1, 2016 by spudw2k

[guinness]

Don't use HotKeySet if you it's not necessary, I would personally advise using GUISetAccelerators. Secondly, is this example still in progress? As it didn't quite work for me. Sorry.

[BrewManNH]

Don't use any blocking functions inside a Window's message function, it can and probably will lock up your script or cause it to crash. _ArrayDisplay is definitely one of those functions you should never use in one.

[guinness]

 

Warning: blocking of running user functions which executes window messages with commands such as "Msgbox()" can lead to unexpected behavior, the return to the system should be as fast as possible !!!

Using Jos' Tidy (Ctrl+T) will add incorrect indentation to your code as well.

[spudw2k]

Don't use HotKeySet if you it's not necessary, I would personally advise using GUISetAccelerators. Secondly, is this example still in progress? As it didn't quite work for me. Sorry.

1) Thanks for the tip.  I didn't realize GUISetAccel operated differently than HotKeySet.

Can you elaborate a little (for my benefit) on why HotKeySet should be avoided?

2) Yes, it is still in progress.

Don't use any blocking functions inside a Window's message function, it can and probably will lock up your script or cause it to crash. _ArrayDisplay is definitely one of those functions you should never use in one.

By blocking do you mean script pausing events or something more significant?

[guinness]

HotKeySet is global across the system whereas using an accelerator key will only register when the GUI is active. Create a test script to see the difference.

Edited June 18, 2013 by guinness

[BrewManNH]

Anything that will cause the script to pause for a long period of time. _ArrayDisplay has a While loop in it that keeps it active until you close it, this causes the message function to lock up. Any modal windows, such as a message box, input box, or a File/Folder dialog box will probably do it too.

[guinness]

Anything that requires user input is a blocking function.

[spudw2k]

Good to know.  Thanks

[spudw2k]

Project has gone from incomplete to working for anyone whom this may be useful too.  See first post.