_Fibonacci() - Calculate the Fibonacci number of a decimal value.

[guinness]

This function will calculate the Finonacci number based on a decimal value.

Function:

; #FUNCTION# ====================================================================================================================
; Name ..........: _Fibonacci
; Description ...: Calculate the Fibonacci number of a decimal value.
; Syntax ........: _Fibonacci($iIterations)
; Parameters ....: $iIterations - An integer value to iterate to.
; Return values .: Success - Fibonacci value
; Author ........: guinness & UEZ
; Link ..........: C++ example: https://en.wikipedia.org/wiki/Functional_programming#Coding_styles
; Example .......: Yes
; ===============================================================================================================================
Func _Fibonacci($iIterations)
    $iIterations = Int($iIterations)
    Local $iFirst = 0, $iSecond = 1, $iSum = 0
    If $iIterations > 92 Then
        $iSecond = 1.0
    EndIf
    For $i = 0 To ($iIterations - 1)
        $iSum = $iFirst + $iSecond
        $iFirst = $iSecond
        $iSecond = $iSum
    Next
    Return $iFirst
EndFunc   ;==>_Fibonacci

Function V3.9.9.4+

; #FUNCTION# ====================================================================================================================
; Name ..........: _Fibonacci
; Description ...: Calculate the Fibonacci number of a decimal value.
; Syntax ........: _Fibonacci($iIterations)
; Parameters ....: $iIterations - An integer value to iterate to.
; Return values .: Success - Fibonacci value
; Author ........: guinness & trancexx
; Link ..........: C++ example: https://en.wikipedia.org/wiki/Functional_programming#Coding_styles
; Example .......: Yes
; ===============================================================================================================================
Func _Fibonacci($iIterations)
    $iIterations = Int($iIterations)
    Local $iFirst = 0, $iSecond = ($iIterations > 92) ? 1.0 : 1, $iSum = 0
    For $i = 0 To ($iIterations - 1)
        $iSum = $iFirst + $iSecond
        $iFirst = $iSecond
        $iSecond = $iSum
    Next
    Return $iFirst
EndFunc   ;==>_Fibonacci

Example use of Function:

For $i = 0 To 20
    ConsoleWrite($i & ' >> ' & _Fibonacci($i) & @CRLF)
Next

Edited June 4, 2013 by guinness

[Exit]

I would suggest to insert the following line as first line of the function.

If $iIterations < 0 Or $iIterations > 92 Then Exit MsgBox(262144, "_Fibonacci Func", "Iteration value '" & $iIterations & "' out of bounds (0 to 92)", 0)

[guinness]

I would suggest to insert the following line as first line of the function.

If $iIterations < 0 Or $iIterations > 92 Then Exit MsgBox(262144, "_Fibonacci Func", "Iteration value '" & $iIterations & "' out of bounds (0 to 92)", 0)

True, though as you know functions should simply return, not Exit or invoke a MsgBox of some description.

[trancexx]

Well, you can always do something like this:

$iSecond = ($iIterations > 92) ? 1.0 : 1

...and then calculate _Fibonacci(1476)

[spudw2k]

$iSecond = ($iIterations > 92) ? 1.0 : 1

Can you please explain your statement ^

What's with the ? 1.0 : 1

Edited January 2, 2013 by spudw2k

[BrewManNH]

It's the new ternary notation in the beta version.

[guinness]

A replacement of _Iif in Misc.au3, thank goodness.

[UEZ]

I think the line must be

$iSecond = ($iIterations > 92) ? 1.0 * $iSum : 1 * $iSum

to work properly (on alpha version).

It switches from integer to floating point.

ConsoleWrite(_Fibonacci(1000) & @LF)

; #FUNCTION# ====================================================================================================================
; Name ..........: _Fibonacci
; Description ...: Calculate the Fibonacci number of a decimal value.
; Syntax ........: _Fibonacci($iIterations)
; Parameters ....: $iIterations - An integer value to iterate to.
; Return values .: Success - Fibonacci value
;                 Failure - -1 & sets @error to non-zero.
; Author ........: guinness
; Link ..........: C++ example: https://en.wikipedia.org/wiki/Functional_programming#Coding_styles
; Example .......: Yes
; ===============================================================================================================================
Func _Fibonacci($iIterations)
    If IsNumber($iIterations) = 0 Then
        $iIterations = Number($iIterations)
    EndIf
;~   If $iIterations < 0 Or $iIterations > 92 Then
;~       Return SetError(1, 0, -1)
;~   EndIf
    Local $iFirst = 0, $iSecond = 1, $iSum = 0
    For $i = 0 To ($iIterations - 1)
        $iSum = $iFirst + $iSecond
        $iFirst = $iSecond
        If $iIterations > 92 Then
            $iSecond = $iSum * 1.0
        Else
            $iSecond = $iSum
        EndIf
    Next
    Return $iFirst
EndFunc   ;==>_Fibonacci

Floating point can handle 64bit numbers...

Br,

UEZ

Edited January 3, 2013 by UEZ

[czardas]

I have to say this example by UEZ is really neat. Ah UEZ is here:

I like both examples.

Edited January 3, 2013 by czardas

[guinness]

See first post.

[UEZ]

@guinness: the code in post#8 is also working with current release (3.3.8.1).

Here some more variants:

Br,

UEZ

Edited January 3, 2013 by UEZ

[guinness]

I will update the initial version too and add your handle.

Edited January 3, 2013 by guinness

[trancexx]

I think the line must be

$iSecond = ($iIterations > 92) ? 1.0 * $iSum : 1 * $iSum

to work properly (on alpha version).

Actually no. More correct is to do it just the way I said - when declaring. You don't want unnecessary evaluations and mathematical operations inside the loop. Edited January 3, 2013 by trancexx

[guinness]

Updated first post.

[UEZ]

Actually no. More correct is to do it just the way I said - when declaring. You don't want unnecessary evaluations and mathematical operations inside the loop.

Yep, you are right again.

@guinness: maybe you can add also the recursive variant to your 1st post to complete iterative and recursive variants.

$n = 1000

ConsoleWrite(Fibonacci_r2($n) & @CRLF)

Func Fibonacci_r2($f)
    If $f < 2 Then Return $f
    If $f > 1476 Then Return 0
    Return Fibonacci_r2_(1, 1, $f)
EndFunc

Func Fibonacci_r2_($f1, $f2, $fn)
    If $fn < 3 Then Return $f2
    Return Fibonacci_r2_($f2, $f1 * 1.0 + $f2 * 1.0, $fn - 1)
EndFunc

As far as I can remember the code above was written by AspirinJunkie but I'm not sure...

Br,

UEZ

Edited January 4, 2013 by UEZ

[n1maS]

Nice work guinness!

Here's my version

Func _Fibonacci($iIterations)
Return (5 ^ -0.5) * ((((1 + (5 ^ 0.5)) / 2) ^ $iIterations) - (((1 - (5 ^ 0.5)) / 2) ^ $iIterations))
EndFunc

Edited January 4, 2013 by n1maS

[guinness]

Updated the function by removing the exclusive check for whether $iIterations is an integer and instead just cast as an Int.

Edited June 4, 2013 by guinness