Drop-down list

[KatoXY]

Hello,

I want to write a script and I need use GUI command but I don’t know which 

I need in my script a list with all records from array or excel book. This list has to look like drop-down list with fonts in MS Word or their size.

Could you show me?

I looked again on AutoIt Help. There are many function with drop down list.

I have to precise describe what I need and then I ask again.

Edited March 31, 2011 by KatoXY

[Melba23]

KatoXY,

The control is know as a Combo and you can produce one by using GUICtrlCreateCombo.

If you want to fill it from an array, I would recommend doing something like this:

#include <GUIConstantsEx.au3>

; Here is the array
Global $aArray[5] = ["A", "B", "C", "D", "E"]

; And here we get the elements into a list
$sList = ""
For $i = 0 To UBound($aArray) - 1
    $sList &= "|" & $aArray[$i]
Next

; Create a GUI
#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

; Create the combo
$hCombo = GUICtrlCreateCombo("", 10, 10, 200, 20)
; And fill it
GUICtrlSetData($hCombo, $sList)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

All clear? Please ask if not.

M23

[KatoXY]

Yes it's clear and great.

I have 2d array and in ComboBox I want only 1st column, so I improve your script:

; Here is the array
Global $aArray[5][2] = [["Andy", "Football"], ["Jon", "Swimming"], ["Jeremy", "Tennis"], ["Carol", "Basketball"], ["Vicky", "Hockey"]]

; And here we get the elements into a list
$sList = ""
For $i = 0 To UBound($aArray,1) -1
    $sList &= "|" & $aArray[$i][0]
Next

; Create a GUI
#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

; Create the combo
$hCombo = GUICtrlCreateCombo("", 10, 10, 200, 20)
; And fill it
GUICtrlSetData($hCombo, $sList)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd
[/code]

Then I need to see label, list or small window, next to ComboBox, with data from 2nd column of my array

and create dependency: when I chose in Combo i.e: Jeremy then I see Tennis in label, window.

How to do it?

[Melba23]

KatoXY,

Perhaps like this?

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <Array.au3>

; Here is the array
Global $aArray[5][2] = [["Andy", "Football"], ["Jon", "Swimming"], ["Jeremy", "Tennis"], ["Carol", "Basketball"], ["Vicky", "Hockey"]]

; And here we get the elements into a list
$sList = ""
For $i = 0 To UBound($aArray,1) -1
    $sList &= "|" & $aArray[$i][0]
Next

; Create a GUI
#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

; Create the combo
$hCombo = GUICtrlCreateCombo("", 10, 10, 200, 20)
; And fill it
GUICtrlSetData($hCombo, $sList)

; Create label
$hLabel = GUICtrlCreateLabel("", 220, 15, 200, 20)

GUISetState()
While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hCombo
            $sName = GUICtrlRead($hCombo)
            $iIndex = _ArraySearch($aArray, $sName)
            If Not @error Then
                GUICtrlSetData($hLabel, $aArray[$iIndex][1])
            EndIf
    EndSwitch
WEnd

M23

[KatoXY]

Yeah, It's working very good. You are

It helps me write my script.

I will contact you If I have some trouble

Thanks

[Melba23]

atoXY,

I will contact you If I have some trouble

Just post in the forum - if I am not around someone else will help.

M23

[Skysnake]

Thank you for this. I just posted on another thread about much the same thing. There is documentation on Combo boxes and documentation on Arrays, but I struggled (really!) to find an example of getting an array into a Combo box - and this one is just so smart - with lots of extra goodies, and the example is clear and simple

Could this perhaps, please, be included in the standard documentation? Perhaps as an 'Advanced Example' in the GUICtrlCreateCombo help item?

Thank you for your efforts. 

[Melba23]

Skysnake,

All you need do to get an array into a combo is to convert the array to a string - and the _ArrayToString function will do that for you if you do not want write your own.

But thanks for the compliments.

M23

[heroeda]

On 3/31/2011 at 3:41 PM, Melba23 said:

KatoXY,

 

Perhaps like this?

 

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <Array.au3>

; Here is the array
Global $aArray[5][2] = [["Andy", "Football"], ["Jon", "Swimming"], ["Jeremy", "Tennis"], ["Carol", "Basketball"], ["Vicky", "Hockey"]]

; And here we get the elements into a list
$sList = ""
For $i = 0 To UBound($aArray,1) -1
    $sList &= "|" & $aArray[$i][0]
Next

; Create a GUI
#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

; Create the combo
$hCombo = GUICtrlCreateCombo("", 10, 10, 200, 20)
; And fill it
GUICtrlSetData($hCombo, $sList)

; Create label
$hLabel = GUICtrlCreateLabel("", 220, 15, 200, 20)

GUISetState()
While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hCombo
            $sName = GUICtrlRead($hCombo)
            $iIndex = _ArraySearch($aArray, $sName)
            If Not @error Then
                GUICtrlSetData($hLabel, $aArray[$iIndex][1])
            EndIf
    EndSwitch
WEnd

M23

How If need Global $aArray = "Combo.ini"

[Data]
[Andy Football]
[Jon Swimming] 
[Jeremy Tennis]
[Carol Basketball]
[Vicky Hockey]

 

Edited February 23, 2017 by heroeda

[Melba23]

heroeda,

If you correctly format your ini file than IniReadSection will give you a 2D array to use:

[Data]
Andy=Football
Jon=Swimming 
Jeremy=Tennis
Carol=Basketball
Vicky=Hockey

#include <Array.au3>

$aData = IniReadSection("Combo.ini", "Data")

_ArrayDisplay($aData, "", Default, 8)

M23

P.S. When you reply, please use the "Reply to this topic" button at the top of the thread or the "Reply to this topic" editor at the bottom rather than the "Quote" button - I know what I wrote and it just pads the thread unnecessarily.

 

[heroeda]

M23

why combo list not show 

Global $aArray[5][2] <------ this code delete or not.

Edited February 27, 2017 by heroeda

[heroeda]

Solved and thanks Melba23

I change code:

$aData = IniReadSection("Combo.ini","Data")
$aArray = $aData

; List element
$sList = ""

For $i = 0 To UBound($aArray,1) -1
    $sList &= "|" & $aArray[$i][0]

 

 

[spudw2k]

Just a quick comment/critique.  Creating another Array variable and copying the $aData array to it is unnecessary/erroneous, unless you really need to retain the original array; but since you are just reading from it and not updating it I don't think that adds any value here.  I would however suggest some error checking to ensure that the variable is in fact an array.  Something to chew on:

$aData = IniReadSection("Combo.ini","Data")
If @error Or Not IsArray($aData) Then
    ;Error condition logic - Notify user, exit function, what-have-you
EndIf

; List element
$sList = ""

For $i = 0 To UBound($aData,1) -1
    $sList &= "|" & $aData[$i][0]

 

[antonioj84]

can someone help me with this,  I have 1 drop list base on selection radio1 or radio2   it will display a different content to select on the list

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 255, 253, 192, 124)
$Radio1 = GUICtrlCreateRadio("Radio1", 40, 48, 65, 17)  ; IF RADIO1 SELECTED LIST0 IS SELECTED
$Radio2 = GUICtrlCreateRadio("Radio2", 128, 48, 65, 17)  ;IF RADIO2 SELECTED LIST1 IS SELECTED
$Group1 = GUICtrlCreateGroup("POS", 24, 24, 177, 49)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

Global $slist[1]                      ;index to keep list 0,1
Global $aArray0[5] = [1,2,3,4,5]    ;VALUE LIST0
Global $aArray1[5] = [6,7,8,9,10]   ;VALUE LIST1

; fill both arrary0, array1 with the content for list 0 and list 1 respectively
$sList[0] = ""
;~$slist[1] = ""

For $i = 0 To UBound($aArray0) - 1
    $sList[0] &= "|" & $aArray0[$i]

;~For $j = 0 To UBound($aArray1) - 1
;~    $sList[1] &= "|" & $aArray1[$j]
;~Next
Next

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

 

Edited April 10, 2017 by antonioj84
ok

[spudw2k]

What do you need help with?  I didn't see a clear question above...so I'll guess.

• Displaying the list?
  • How do you want it displayed? (ArrayDisplay, Listview, ConsoleWrite, etc.)
• Assigning the desired list to $sList?
• Other?

Edited April 10, 2017 by spudw2k

[antonioj84]

Hi spudw2k,

If radio1 or radio2 is selected the dropdown list content for selecting will be different.

Radio0 will list on the dropdown 1,2,3,4,5

Radio1 will list on the dropdown

5,6,7,8,910

Note bien, there is only on dropdown list only the content for selection will be different base on the checked option radio0 or radio1

[spudw2k]

Ok, should be easy enough.  Do you have more code with the dropdown list control already in place?  Is it a combobox?

Also, just a thought....will your arrays be changing during runtime, or will they always be defined, hardcoded in the script?  You might as well just have them be strings to begin with.  That way you don't have to do any additional processing/formatting before applying the data to the dropdown.

[antonioj84]

Kool, the array values are hard-coded and won't change, sure i can have them as a string.

I need assistance in filling the 2  $list[1] from the $array0 and $array1

[spudw2k]

Well, if you use strings instead, you don't need to bother with populating the $slist[1].  

Global $slist[1]                      ;index to keep list 0,1
Global $aArray0[5] = [1,2,3,4,5]    ;VALUE LIST0
Global $aArray1[5] = [6,7,8,9,10]   ;VALUE LIST1

;would become
Global $sList1 = "|1|2|3|4|5"
Global $sList2 = "|6|7|8|9|10"

Also, an array with only 1 index ($sList[1]) doesn't add any value that I can see that you can't accomplish with a string, or am I missing something?   If you really want to do it using arrays, I won't stop you.  Just trying to make things simpler for ya.  You were on your way there with your for loop.  
 

Edited April 10, 2017 by spudw2k
added preceding GUISeparatorChar to list strings to ease updating combo

[antonioj84]

$sList1=""
If GUICtrlRead($Box1) = $GUI_CHECKED Then
   $sList1 = "|1|2|3|4|5"
EndIf
$sList1=""
If GUICtrlRead($Box2) = $GUI_CHECKED Then
  $sList1 = "|6|7|8|9|10"
EndIf

this solution will work for sure, however I was shooting for my solution