Function Reference

ControlListView

Sends a command to a ListView32 control.

ControlListView ( "title", "text", controlID, "command" [, option1 [, option2]] )

Parameters

title The title/hWnd/class of the window to access. See Title special definition.
text The text of the window to access. See Text special definition.
controlID The control to interact with. See Controls.
command The command to send to the control (see below).
option1 [optional] Additional parameter required by some commands.
option2 [optional] Additional parameter required by some commands.

Return Value

Return depends on command as table below shows. In case of an error (such as an invalid command or window/control could not be found) then @error is set to 1.

Command, Option1, Option2 Operation
"DeSelect", From [, To] Deselects one or more items.
"FindItem", "string to find" [, SubItem] Returns the item index of the string. Returns -1 if the string is not found.
"GetItemCount" Returns the number of list items.
"GetSelected" [, option] Returns a string containing the item index of selected items. If option=0 (default) only the first selected item is returned. If option=1 then all the selected items are returned delimited by |, e.g: "0|3|4|10". If no items are selected a blank "" string is returned.
"GetSelectedCount" Returns the number of items that are selected.
"GetSubItemCount" Returns the number of subitems.
"GetText", Item, SubItem Returns the text of a given item/subitem.
"IsSelected", Item Returns 1 if the item is selected, otherwise returns 0.
"Select", From [, To] Selects one or more items.
"SelectAll" Selects all items.
"SelectClear" Clears the selection of all items.
"SelectInvert" Inverts the current selection.
"ViewChange", "view" Changes the current view. Valid views are "list", "details", "smallicons", "largeicons".


In a "Details" view of a ListView32 control, the "item" can be thought of as the "row" and the "subitem" as the "column".

Remarks

Some commands may fail when using a 32-bit AutoIt process to read from a 64-bit process. Likewise commands may fail when using a 64-bit AutoIt process to read from a 32-bit process.

Related

ControlCommand

Example

#include <MsgBoxConstants.au3>

ControlListView(@ProgramFilesDir & "\AutoIt3", "", "SysListView321", "SelectAll")
ControlListView(@ProgramFilesDir & "\AutoIt3", "", "SysListView321", "Deselect", 2, 5)
MsgBox($MB_SYSTEMMODAL, "", ControlListView(@ProgramFilesDir & "\AutoIt3", "", "SysListView321", "GetText", 9, 0))
MsgBox($MB_SYSTEMMODAL, "", ControlListView(@ProgramFilesDir & "\AutoIt3", "", "SysListView321", "FindItem", "14 KB", 1))
MsgBox($MB_SYSTEMMODAL, "", ControlListView(@ProgramFilesDir & "\AutoIt3", "", "SysListView321", "GetSelected", 1))