Returns the status of the sound
#include <Sound.au3>
_SoundStatus ( $aSndID )
| $aSndID | Sound ID array as returned by _SoundOpen() or a file name |
| Success: | the sound status. |
| Failure: | 0 and sets the @error flag to non-zero. |
| @error: | 3 = Invalid Sound ID. Use return array from _SoundOpen() or a valid file name. |
From MSDN:
All devices can return the "not ready", "paused", "playing", and "stopped" values.
Some devices can return the additional "open", "parked", "recording", and "seeking" values.
#include <MsgBoxConstants.au3>
#include <Sound.au3>
Local $aSound = _SoundOpen(@WindowsDir & "\media\tada.wav")
If @error = 2 Then
MsgBox($MB_SYSTEMMODAL, "Error", "The file does not exist")
Exit
ElseIf @extended <> 0 Then
Local $iExtended = @extended ; Assign because @extended will be set after DllStructCreate().
Local $tText = DllStructCreate("char[128]")
DllCall("winmm.dll", "short", "mciGetErrorStringA", "str", $iExtended, "struct*", $tText, "int", 128)
MsgBox($MB_SYSTEMMODAL, "Error", "The open failed." & @CRLF & "Error Number: " & $iExtended & @CRLF & "Error Description: " & DllStructGetData($tText, 1) & @CRLF & "Please Note: The sound may still play correctly.")
Else
MsgBox($MB_SYSTEMMODAL, "Success", "The file opened successfully")
EndIf
ConsoleWrite("After _SoundOpen: " & _SoundStatus($aSound) & @CRLF)
_SoundPlay($aSound)
ConsoleWrite("After _SoundPlay: " & _SoundStatus($aSound) & @CRLF)
Sleep(1000)
_SoundPause($aSound)
ConsoleWrite("After _SoundPause: " & _SoundStatus($aSound) & @CRLF)
Sleep(1000)
_SoundResume($aSound)
While 1
Sleep(100)
If _SoundPos($aSound, 2) = _SoundLength($aSound, 2) Then ExitLoop
WEnd
_SoundClose($aSound)