Sets paragraph spacing of paragraphs having selected text or, if none selected, sets it for text inserted at the insertion point
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaSpacing ( $hWnd [, $vInter = Default [, $iBefore = Default [, $iAfter = Default]]] )
| $hWnd | Handle to the control |
| $vInter | [optional] spacing between lines: either: a number - in space units or: " |
| $iBefore | [optional] spacing before paragraph(s) (in space units) |
| $iAfter | [optional] spacing after paragraph(s) (in space units) |
| Success: | True. |
| Failure: | False and sets the @error flag to non-zero. |
| @error: | 101 - $hWnd is not a handle 103 - $iBefore is neither a positive number nor zero 104 - $iAfter is neither a positive number nor zero 1021 - $vInter is invalid 1022 - Only 1, 1.5 and 2 line spacing can be set via " |
Only settings which are not defaulted are set.
To set "space units", call _GUICtrlRichEdit_SetSpaceUnit(). Initially inches.
_GUICtrlRichEdit_GetParaSpacing, _GUICtrlRichEdit_SetSpaceUnit
Search EM_SETPARAFORMAT in MSDN Library.
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>
Global $g_idLblMsg, $g_hRichEdit
Example()
Func Example()
Local $hGui, $iMsg, $idBtnNext, $iStep = 0
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
$g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$idBtnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState(@SW_SHOW)
_GUICtrlRichEdit_SetText($g_hRichEdit, "First paragraph")
Report("0. Para with default settings")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($g_hRichEdit) ; needed unless script crashes
; GUIDelete() ; is OK too
Exit
Case $iMsg = $idBtnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Second paragraph")
_GUICtrlRichEdit_SetParaSpacing($g_hRichEdit, "2 lines", .2, .25)
Report("1. Spacing of second paragraph is ")
Case 2
_GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 2)
Report("2. Settings of first paragraph in the selection are ")
Case 3
_GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
_GUICtrlRichEdit_SetParaSpacing($g_hRichEdit, Default, .1)
Report("3. Change spacing of both paragraphs")
Case 4
; Stream all text to the Desktop so you can look at Indents settings in Word
_GUICtrlRichEdit_Deselect($g_hRichEdit)
_GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($idBtnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Example
Func Report($sMsg)
$sMsg = $sMsg & @CRLF & @CRLF & "Get function returns " & @CRLF & _GUICtrlRichEdit_GetParaSpacing($g_hRichEdit)
GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc ;==>Report