Function Reference

_Date_Time_SystemTimeToFileTime

Converts a system time to file time format

#include <Date.au3>
_Date_Time_SystemTimeToFileTime ( $tSYSTEMTIME )

Parameters

$tSYSTEMTIME a $tagSYSTEMTIME structure to be converted or a pointer to it.

Return Value

Returns a $tagFILETIME structure that contains the converted file time.

Related

$tagFILETIME, $tagSYSTEMTIME

Example

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
        Local $tFile, $tSystem

        ; Create GUI
        GUICreate("Time", 400, 300)
        $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
        GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
        GUISetState(@SW_SHOW)

        ; Get system time
        $tSystem = _Date_Time_GetSystemTime()
        $tFile = _Date_Time_SystemTimeToFileTime($tSystem)
        MemoWrite("File time .: " & _Date_Time_FileTimeToStr($tFile))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Write a line to the memo control
Func MemoWrite($sMessage)
        GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite