Arrays

From AutoIt Wiki
Jump to navigation Jump to search

Initial notes

This is a small tutorial on how to use arrays in AutoIt.

We will try to target those people learning a programming language for the first time. So, be prepared for some spoon feeding.

The code assumes you use the SciTE editor. There is a minimal version of SciTE included in the latest stable release of AutoIt (version 3.2.0.1 and above). To understand how arrays and associated functions work, it is imperative that you try and play with the samples that we provide here. Make sure you understand how each step works before you go on to the next one.

We also recommend reading the UnitTesting wiki page and follow the guide lines you find there. (ok the page is not finished, but it will hopefully be when it is needed). It will make your life a lot easier later on when you have forgot how something is suppose to work. Try to adopt the samples you find in this article to a unit testing framework.

What is an array

An array is an identifier containing elements or variables (if you like), referenced by the identifier and an index. Now we could have said a variable containing variables referenced by the variable and an index but I think that makes even less sense to most of us.

This sounds complex. So, why should you learn about arrays? The short answer is that data structures are fundamental to programming.

Declaring Arrays in AutoIt

You declare an array in the same manner as you would declare any variable in AutoIt. But when you know it is an array, you add information on how many elements you want to have in the array. This information is provided by adding brackets after the identifier and a number indicating how many elements you want the array to hold. 

 Global $arr[4] ; Will make space for 4 elements.
 Local  $arr[1] ; Will make space for 1 element.
 ;NOTE! Avoid using Dim.  Use Global or Local instead.
 Dim    $arr[3] ; Will make space for 3 elements.

Making space for 1 element may seem ridiculous, but further down the road we shall see how we can have arrays grow and shrink. So when we declare an array with 1 element, it is usually just a place holder.

In AutoIt, you can also declare an array as a normal variable and later get an array assigned to it from a function. Note about the "from a function" part: this can refer to a user-defined function or an AutoIt internal built-in function. The point is, a variable does not need to hold an array before the array is assigned to it. 

 Local $arr = StringSplit("This is my string. I want to split it in sentences.", ".")

Now to make really certain we have an array from StringSplit, we should check it with the IsArray($variable) built-in function. 

 If IsArray($arr) Then 
     ; DO work on the array
 EndIf

Assigning Data to Array Elements

When we declare the array we make some room in memory for future data. We want to assign some data to the items in the array. Now here is the catch. The array always starts at index 0. So, the first element in the array will be accessed by 0, the second element in the array is accessed at by 1 and so on. 

 Local $arr[3] ; Make room for three elements
 ;Assign some data
 $arr[0]="Element 1"
 $arr[1]="Element 2"
 $arr[2]="Element 3"

You can also assign all the data in one smack like this: 

 Local $arr[3] = ["element 1", "element 2", "element 3"]

This 0-based indexing is quite common in most computer languages, but it can be a source of headaches to programmers until it becomes second nature to them. For example, every time you want to loop through a range of elements and the range includes the last element, you have to subtract one from the number of items your array is holding, to get the index of the last item. I.E., An array with 3 elements has a last index of 2.

So if you don't take 0-based indexing into consideration in your code, you may ask for something outside the memory area set aside for the array. When you do, you get an error message (Array variable has incorrect number of subscripts or subscript dimension range exceeded) and your script will cease execution.

Accessing Data in Arrays

Let's walk all elements in the previous sample: 

 Local $arr[3] = ["element 1", "element 2", "element 3"] 
 For $i = 0 to 3 - 1 ; We have an array with three elements but the last index is two.
     ConsoleWrite($arr[$i] & @LF)
 Next

Determine array size with UBound

The "3 - 1" construct used in the last sample looked strange. It is not a good idea to hard-code size like that. So lets improve our sample a little. 

 Local $iMax = 3
 Local $arr[$iMax] = ["Element 1", "Element 2", "Element 3"]
 For $i = 0 to $iMax - 1
     ConsoleWrite($arr[$i] & @LF)
 Next

Now that's a bit cleaner. It's also a lot easier to increase or decrease the size of the array.
But say you don't know the size of the array upfront because it may come in a variable size when created dynamically.

 Local $iMax Local $data="Element 1|Element 2|Element 3" ; The string in data will be split into an array everywhere | is encountered Local $arr = StringSplit($data, "|") If IsArray($arr) Then     $iMax = UBound($arr); get array size     ConsoleWrite("Items in the array: " & $iMax & @LF)     For $i = 0 to $iMax - 1; subtract 1 form size to prevent out of bounds error         ConsoleWrite($arr[$i] & @LF)     Next EndIf

When you run the above code you will see that $iMax is 4 and not 3 as you might have expected. The reason for this is that the developer of the StringSplit() function thought it was a good idea to use the first item (item 0) to keep a count of valid items in the array. This makes sense in many situations as you now have an array containing data with an index starting at 1. So our sample code can now be rewritten like this. 

 Local $iMax
 Local $data="Element 1|Element 2|Element 3"
 ; The string in data will be split into an array everywhere | is encountered
 Local $arr = StringSplit($data, "|")  
 If IsArray($arr) Then 
     For $i = 1 to $arr[0]
         ConsoleWrite($arr[$i] & @LF)
     Next
 EndIf

There is another good reason for keeping the count in $arr[0]. When you start to use arrays extensively, you will encounter situations where you have to create an array without knowing how many of the elements you will use. Resizing the array is a relatively expensive operation (in CPU cycles) in most languages.

Now consider our example if our initial array has reserved space for 10 items but we end up only using 3. In this case iterating the array using UBound will force us to check for empty elements. While iterating with $arr[0] needs no other change than maintaining the correct count in $arr[0]. 

 Local $iMax=10
 ;NOTE: We have added the count in the first element
 Local $arr[$iMax] = [3, "Element 1", "Element 2", "Element 3"]
 ;NOTE: We use the count in $arr[0] to indicate the last item and we start from index=1
 For $i = 1 to $arr[0]
     ConsoleWrite($arr[$i] & @LF)
 Next

Changing array sizes with ReDim

As arrays are critical to algorithm implementations, and in AutoIt even more so as there is no other means of grouping data, we have to understand how to let it grow and shrink. This is where the keyword ReDim comes into the picture.

Let's make an example. We want our array to hold data lines but we don't know how many items we need. We make a guess, in this case 5. Now, we use that array to hold data we get from a loop with a random number of itterations. If the array are to small it should automatically be increased. Before we dump the array to output, we should adjust the it to the exact size it is supposed to be. 

 Local $iMax=5
 ;NOTE: We have added the count in the first element
 Local $arr[$iMax] = [0] ;Initiate the array and place a counter in the first element.
 Local $i
 ;Get a random number between 0 and 20
 Local $rnd = Random(0, 20, 1)
 For $i = 1 to $rnd
     ; Check that the array is big enough
     If UBound($arr) = $i Then 
         ; Resize the array
         ReDim $arr[$arr[0] + $iMax]
     EndIf
     $arr[$i] = "Item " & $i
     ; Remember to update the count or last item
     $arr[0] = $i
 Next
 ;Adjust the array size. This time it is probably downward to the size of 
 ;$arr[0] + 1 (remember the first item is $arr[0]
 ReDim $arr[$arr[0]+1]
 ;Now dump the result
 For $i = 1 to $arr[0]
     ConsoleWrite("$arr[" & $i & "]:=" & $arr[$i] &  @LF)
 Next
 ; Visually check that the values are sound
 ConsoleWrite( "Ubound($arr)=:=" & UBound($arr) & ", $arr[0]:=" & $arr[0] & ", $rnd:=" & $rnd & @LF)

Note how the array now has first been adjusted to a multiple of $iMax and in the last part adjusted down to a size matching the data items.

Multi dimensional arrays

Now what is a good explanation of an multi dimensional array? It could be a table where you access one item in the table at the time. 

 Local  $arr[3][3] = [[1, 2, 3], [2, 3, 4], [3, 4, 5]]
 Local $i, $j
 For $i = 0 to UBound( $arr, 1) - 1
   For $j = 0 to UBound($arr, 2) - 1
	  ConsoleWrite("$arr[" & $i & "][" & $j & "]:=" & $arr[$i][$j] & @LF)
   Next 
   ConsoleWrite(@LF)
 Next

But you can add dimensions, how many was not mentioned in the help files limits page as of writing. But drop me a note if you find a problem where it is easier to add dimensions rather than using other techniques.

Here is a 4 dimensional sample. You tell me how that initializer is for readability. 

; NOTE: Then next line is supposed to be on one line
Local $arr[3][3][3][3] = [[[[1, 2, 3],[2, 3, 4],[3, 4, 5]], _
		[[1, 2, 3],[2, 3, 4],[3, 4, 5]],[[1, 2, 3],[2, 3, 4],[3, 4, 5]]], _
		[[[1, 2, 3],[2, 3, 4],[3, 4, 5]],[[1, 2, 3],[2, 3, 4],[3, 4, 5]], _
		[[1, 2, 3],[2, 3, 4],[3, 4, 5]]],[[[1, 2, 3],[2, 3, 4],[3, 4, 5]], _
		[[1, 2, 3],[2, 3, 4],[3, 4, 5]],[[1, 2, 3],[2, 3, 4],[3, 4, 5]]]]

Local $i, $j, $k, $l
For $i = 0 To UBound($arr, 1) - 1
	For $j = 0 To UBound($arr, 2) - 1
		For $k = 0 To UBound($arr, 3) - 1
			For $l = 0 To UBound($arr, 4) - 1
				ConsoleWrite("$arr[" & $i & "][" & $j & "][" & $k & _
						"][" & $l & "]:=" & $arr[$i][$j][$k][$l] & @LF)
			Next
		Next
	Next
	ConsoleWrite(@LF)
Next

Arrays in arrays

You may save an array in an array element (item). The thing is, there is no way to directly access that array, stored in the element, again. You have to go through a variable to get access to the embedded array.

Remember this. There are issues if you pass an array containing arrays into a function and the embedded array is changed inside that function. So, to conclude this, do not use arrays embedded in an array unless you absolutely have to, and are prepared to do rigorously testing to make sure your code work as you expect it to.

That said, here is an example 

   Local $arr[3]
   Local $a1[3] = [2, "a1-1","a1-2"]
   Local $a2[3] = [2, "a2-1","a2-2"]
   $arr[1] = $a1
   $arr[2] = $a2
   $arr[0] = 2
   Local $i , $j
   Local $dumy
   For $i = 1 to $arr[0]
       $dumy = $arr[$i]
       If IsArray($dumy) Then 
           For $j = 1 to $dumy[0]
	       ConsoleWrite("$i:=" & $i & ", $dumy[" & $j & "]:=" & $dumy[$j] & @LF)
	   Next 
        Else 
           ConsoleWrite("!UPS, What happened? Expected an array" & @LF)
	EndIf 
   Next

Passing arrays to a function

There is no hocus pocus about this. Only a few rules.

  • You can not declare the variable to hold the array in the function declaration as an array. So, users could pass on a variable. So you have to check that the variable holds an array before you do array specific operations on it.
  • You don't have to, but you should, specify the variable to hold the array as ByRef.


Now, during the tutorial you have probably noticed that there is a lot of code that is equal in each sample. I'm especially thinking about the code we have used to output the array content. Let's make life easier and create a debug function 

 Func dbgArray(ByRef $arr, $msg="")
     If $msg <> "" Then 
         ConsoleWrite("*** " & $msg & " ***" & @LF)
     EndIf
     Local $i
     For $i = 0 to UBound($arr) - 1
        ConsoleWrite("$arr[" & $i & "]:=" & $arr[$i] &  @LF)
     Next
     ConsoleWrite( "Ubound($arr)=:=" & UBound($arr) & ", $arr[0]:=" & $arr[0] & @LF)   
 EndFunc

And let's make a little function to fill our arrays with something. Note how the ArrayFiller makes sure it works on an array. 

 Func ArrayFiller(ByRef $arr)
     If IsArray($arr) Then 
         ReDim $arr[3] ;Notice we might discard content in this operation
     Else
         Local $foo[3]
         $arr = $foo
     EndIf 
     ;Fill the array
     $arr[0] = 2
     $arr[1] = "Fill 1"
     $arr[2] = "Fill 2"
 EndFunc

And finally some code using the new functions 

   Local $arr1[1]
   ArrayFiller($arr1)
   dbgArray($arr1)

This code is a test on what happens when we pass a regular variable. 

   Local $arr2
   ArrayFiller($arr2)
   dbgArray($arr2)

Passing arrays from a function

As you could observe, in the previous samples, an array will be passed back and forth with the ByRef keyword infront of the variable holding the array in the function declaration.

We could also have used the Return keyword in a function. Lets re-work the ArrayFiller function to do this rather than using a variable ByRef. 

 Func ArrayFiller2()
   Local $arr = [3, "Fill 1", "Fill 2"]
   Return $arr
 EndFunc

And now we can use the function like this 

 Local $foo = ArrayFiller2()
 dbgArray($foo)

Forum FAQ about arrays

Feel free to add questions and answers you have encountered in the forum.

Accessing Arrays

Obviously one can assign arrays to variables:

$Array1=$Array1 .

One can also assign single array elements: 

$Array1[1]="blabla"

or

$Content=$Array1[1]

Comparing Arrays

You can not, however, compare complete arrays:

if $Array1 == $Array2 then $OK="equal"

I have the impressionthat such comparisions compare the memory adress of the arrays instead of the array elements values. And the adresses are always different for different arrays.


You have, instead to compare all elements one after the other. It might be a good idea to first compare arry sizes if that can vary for both the compared arrays!

Array UDF: array.au3

AutoIt features a large list of User-Defined Functions (UDF), among is a module supplying extra array functions. You can find a reference on those functions in AutoIt's Help file as the last main chapter named 'User Defined Functions Reference'.

Links

TODO

Update information about UBound($arr, 0). Create a section with utility functions? Include _ArrayWalk by @Saunders(http://www.autoitscript.com/forum/index.php?s=&showtopic=53390&view=findpost&p=410283)?

Retrieved from "https://www.autoitscript.com/w/index.php?title=Arrays&oldid=10881"