OutlookEX UDF - Meeting Item

Here you find detailed information about how to work with Meeting items.

Tips & Tricks

Send a meeting invitation

Set property MeetingStatus to value '1' (the meeting has been scheduled) and send the item to the attendees.

Example:

#include <OutlookEx.au3>
; Open the connection to Outlook
Global $oOL = _OL_Open()
; Create an appointment and set some properties
$oItem = _OL_ItemCreate($oOL, $olAppointmentItem, "*\Calendar", "", _
  "Subject=Meeting", "Start=" & _DateAdd("D", 3, _NowCalcDate() & " 08:00:00"), "Duration=60", _
  "MeetingStatus=1")
; Add required recipients you want to invite to the meeting
_OL_ItemRecipientAdd($oOL, $oItem, Default, $olRequired, "Recipients name 1",  "Recipients name 2")
; Add optional recipients you want to invite to the meeting
_OL_ItemRecipientAdd($oOL, $oItem, Default, $olOptional, "Optional user 1")
; Add a meeting room
_OL_ItemRecipientAdd($oOL, $oItem, Default, $olResource, "Meeting Room 1")
; Send the meeting request
_OL_ItemSend($oOL, $oItem)

This creates an appointment in the senders calendar and sends a meeting request to the optional and required attendees plus the administrator of the meeting room. The meeting starts in 3 days from today at eight o'clock and lasts an hour.

Cancel a meeting and send cancel requests to the attendees

Set property MeetingStatus to value '5' (the scheduled meeting has been cancelled) and re-send the item to the attendees.

Example:

#include <OutlookEx.au3>
; Open the connection to Outlook
Global $oOL = _OL_Open()
; Get the appointment you want to cancel
$aResult = _OL_ItemFind($oOL, "*\Calendar", "", "[Subject]='Meeting'", "", "", "EntryID")
$oItem = _OL_ItemModify($oOL, $aResult[1][0], Default, "MeetingStatus=5")
; Send the meeting request
_OL_ItemSend($oOL, $oItem)

This removes the appointment from the senders calendar and sends a cancel request to every attendee.