CommInterface.au3: Difference between revisions

From AutoIt Wiki
Jump to navigation Jump to search
(fix error in _CommAPI_TransmitData)
(replace ReceiveData & ReceiveLine with ReceiveBinary & ReceiveString)
Line 41: Line 41:
; ===============================================================================================================================
; ===============================================================================================================================
Func _CommAPI_ClosePort(Const $hFile)
Func _CommAPI_ClosePort(Const $hFile)
Local $fResult = _WinAPI_CloseHandle($hFile)
Local $fSuccess = _WinAPI_CloseHandle($hFile)
If @error Then Return SetError(@error, 0, False)
If @error Then Return SetError(@error, 0, False)
If Not $fResult Then Return SetError(-1, @ScriptLineNumber, False)
If Not $fSuccess Then Return SetError(-1, @ScriptLineNumber, False)
Return $fResult
Return $fSuccess
EndFunc  ;==>_CommAPI_ClosePort
EndFunc  ;==>_CommAPI_ClosePort


Line 134: Line 134:


; #FUNCTION# ====================================================================================================================
; #FUNCTION# ====================================================================================================================
; Name ..........: _CommAPI_ReceiveData
; Name ..........: _CommAPI_ReceiveBinary
; Description ...: Receives data (RxD/RX/RD) to a specified communications device.
; Description ...: Receives data (RxD/RX/RD) to a specified communications device.
; Syntax ........: _CommAPI_ReceiveData(Const $hFile[, $iTimeout = 1[, $iMaxLen = 0]])
; Syntax ........: _CommAPI_ReceiveBinary(Const $hFile[, $iTimeout = 1[, $iMaxLength = 0[, $vSeparator = ""]]])
; Parameters ....: $hFile              - [in] A handle to the communications device.
; Parameters ....: $hFile              - [in] A handle to the communications device.
;                  $iTimeout            - [in] An integer value for total read timeout in milliseconds.
;                  $iTimeout            - [in] An integer value for total read timeout in milliseconds.
;                                              Is activated only by positive values.
;                                              Is activated only by positive values.
;                  $iMaxLen            - [in] An integer value for maximum length of result.
;                  $iMaxLength          - [in] An integer value for maximum length of result.
;                                              Is activated only by positive values.
;                                              Is activated only by positive values.
; Return values .: Success - Received string
;                  $vSeparator          - [in] A value which is used as a separator.
;                  Failure - Received string
;                                              Is activated only by non-empty values.
; Return values .: Success - Received binary data (including separator)
;                  Failure - Received binary data
;                  @error  - 1 unable to use the DLL file
;                  @error  - 1 unable to use the DLL file
;                            2 unknown "return type"
;                            2 unknown "return type"
Line 153: Line 155:
; Author ........:
; Author ........:
; Modified ......:
; Modified ......:
; Remarks .......: If the result contains Chr(0), you should convert the result with function Binary().
; Remarks .......:
; Related .......: _CommAPI_TransmitData
; Related .......: _CommAPI_ReceiveString, _CommAPI_TransmitData
; Link ..........: http://msdn.microsoft.com/en-us/library/aa365467(v=vs.85).aspx
; Link ..........: http://msdn.microsoft.com/en-us/library/aa365467(v=vs.85).aspx
; Example .......: No
; Example .......: No
; ===============================================================================================================================
; ===============================================================================================================================
Func _CommAPI_ReceiveData(Const $hFile, Const $iTimeout = 1, Const $iMaxLen = 0)
Func _CommAPI_ReceiveBinary(Const $hFile, Const $iTimeout = 1, Const $iMaxLength = 0, Const $vSeparator = "")
Local $tBuffer = DllStructCreate("wchar")
Local $bSeparator = Binary($vSeparator)
Local $iSepLength = BinaryLen($bSeparator)
Local $fSuccess = False
Local $tBuffer = DllStructCreate("BYTE")
Local $pBuffer = DllStructGetPtr($tBuffer)
Local $iRead = 0
Local $vResult = Binary("")
Local $iResLength = 0
Local $hTimer = TimerInit()
Local $hTimer = TimerInit()
Local $iWritten = 0
While True
Local $sResult = ""
$fSuccess = _WinAPI_ReadFile($hFile, $pBuffer, 1, $iRead)
While 1
If @error Then Return SetError(@error, @ScriptLineNumber, $vResult)
Local $fResult = _WinAPI_ReadFile($hFile, DllStructGetPtr($tBuffer), 1, $iWritten)
If Not $fSuccess Then Return SetError(-1, @ScriptLineNumber, $vResult)
If @error Then Return SetError(@error, @ScriptLineNumber, $sResult)
If $iRead Then
If Not $fResult Then Return SetError(-1, @ScriptLineNumber, $sResult)
$vResult &= BinaryMid(Binary(DllStructGetData($tBuffer, 1)), 1, 1)
If $iWritten Then
$iResLength = BinaryLen($vResult)
$sResult &= DllStructGetData($tBuffer, 1)
If $iResLength = $iMaxLength And $iMaxLength > 0 Then Return $vResult
If $iMaxLen > 0 And $iMaxLen = StringLen($sResult) Then Return $sResult
If $bSeparator = BinaryMid($vResult, 1 + $iResLength - $iSepLength) Then Return $vResult
Else
Else
If $sResult Then Return $sResult
If $vResult And Not $iSepLength Then Return $vResult
If $iTimeout >= 0 And $iTimeout < TimerDiff($hTimer) Then Return SetError(-2, @ScriptLineNumber, $sResult)
If $iTimeout > 0 And $iTimeout < TimerDiff($hTimer) Then Return SetError(-2, @ScriptLineNumber, $vResult)
EndIf
EndIf
WEnd
WEnd
Return $sResult
Return $vResult
EndFunc  ;==>_CommAPI_ReceiveData
EndFunc  ;==>_CommAPI_ReceiveBinary


; #FUNCTION# ====================================================================================================================
; #FUNCTION# ====================================================================================================================
; Name ..........: _CommAPI_ReceiveLine
; Name ..........: _CommAPI_ReceiveString
; Description ...: Receives data (RxD/RX/RD) to a specified communications device.
; Description ...: Receives data (RxD/RX/RD) to a specified communications device.
; Syntax ........: _CommAPI_ReceiveLine(Const $hFile[, $sSeparator = @CRLF[, $iTimeout = 1[, $iMaxLen = 0]]])
; Syntax ........: _CommAPI_ReceiveString(Const $hFile[, $iTimeout = 1[, $iMaxLength = 0[, $sSeparator = ""]]])
; Parameters ....: $hFile              - [in] A handle to the communications device.
; Parameters ....: $hFile              - [in] A handle to the communications device.
;                  $sSeparator          - [in] A string value which is used as a separator.
;                  $iTimeout            - [in] An integer value for total read timeout in milliseconds.
;                  $iTimeout            - [in] An integer value for total read timeout in milliseconds.
;                                              Is activated only by positive values.
;                                              Is activated only by positive values.
;                  $iMaxLen            - [in] An integer value for maximum length of result.
;                  $iMaxLength          - [in] An integer value for maximum length of result.
;                                              Is activated only by positive values.
;                                              Is activated only by positive values.
; Return values .: Success - Received string including separator
;                  $sSeparator          - [in] A value which is used as a separator.
;                                              Is activated only by non-empty values.
;                  $iFlag              - [in] Flag for function BinaryToString().
; Return values .: Success - Received string (including separator)
;                  Failure - Received string
;                  Failure - Received string
;                            Received binary data in case of @error = -3
;                  @error  - 1 unable to use the DLL file
;                  @error  - 1 unable to use the DLL file
;                            2 unknown "return type"
;                            2 unknown "return type"
Line 197: Line 209:
;                          -1 function fails (To get extended error information, call _WinAPI_GetLastError or _WinAPI_GetLastErrorMessage)
;                          -1 function fails (To get extended error information, call _WinAPI_GetLastError or _WinAPI_GetLastErrorMessage)
;                          -2 timeout
;                          -2 timeout
;                          -3 error in BinaryToString
; Author ........:
; Author ........:
; Modified ......:
; Modified ......:
; Remarks .......: If the result contains Chr(0), you should convert the result with function Binary().
; Remarks .......:
;                  To remove separator from result, you can use function StringTrimRight($sResult, StringLen($sSeparator)).
; Related .......: _CommAPI_ReceiveBinary, _CommAPI_TransmitData
; Related .......: _CommAPI_TransmitData
; Link ..........: http://msdn.microsoft.com/en-us/library/aa365467(v=vs.85).aspx
; Link ..........: http://msdn.microsoft.com/en-us/library/aa365467(v=vs.85).aspx
; Example .......: No
; Example .......: No
; ===============================================================================================================================
; ===============================================================================================================================
Func _CommAPI_ReceiveLine(Const $hFile, Const $sSeparator = @CRLF, Const $iTimeout = 1, Const $iMaxLen = 0)
Func _CommAPI_ReceiveString(Const $hFile, Const $iTimeout = 1, Const $iMaxLength = 0, Const $sSeparator = "", Const $iFlag = 1)
Local $tBuffer = DllStructCreate("wchar")
Local $bResult = _CommAPI_ReceiveBinary($hFile, $iTimeout, $iMaxLength, StringToBinary($sSeparator, $iFlag))
Local $iLength = StringLen($sSeparator)
Local $iError = @error
Local $hTimer = TimerInit()
Local $iExtended = @extended
Local $iWritten = 0
Local $sResult = ""
Local $sResult = ""
While 1
If $bResult Then
Local $fResult = _WinAPI_ReadFile($hFile, DllStructGetPtr($tBuffer), 1, $iWritten)
$sResult = BinaryToString($bResult, $iFlag)
If @error Then Return SetError(@error, @ScriptLineNumber, $sResult)
If @error Then SetError(-3, @ScriptLineNumber, $bResult)
If Not $fResult Then Return SetError(-1, @ScriptLineNumber, $sResult)
EndIf
If $iWritten Then
Return SetError($iError, $iExtended, $sResult)
$sResult &= DllStructGetData($tBuffer, 1)
EndFunc  ;==>_CommAPI_ReceiveString
If $iMaxLen > 0 And $iMaxLen = StringLen($sResult) Then Return $sResult
If StringRight($sResult, $iLength) == $sSeparator Then Return $sResult
Else
If $iTimeout >= 0 And $iTimeout < TimerDiff($hTimer) Then Return SetError(-2, @ScriptLineNumber, $sResult)
EndIf
WEnd
Return $sResult
EndFunc


; #FUNCTION# ====================================================================================================================
; #FUNCTION# ====================================================================================================================
Line 243: Line 246:
; Modified ......:
; Modified ......:
; Remarks .......:
; Remarks .......:
; Related .......: _CommAPI_ReceiveData
; Related .......: _CommAPI_ReceiveBinary, _CommAPI_ReceiveString
; Link ..........: http://msdn.microsoft.com/en-us/library/aa365747(v=vs.85).aspx
; Link ..........: http://msdn.microsoft.com/en-us/library/aa365747(v=vs.85).aspx
; Example .......: No
; Example .......: No
Line 251: Line 254:
Local $iLength = BinaryLen($vData)
Local $iLength = BinaryLen($vData)
Local $iWritten = 0
Local $iWritten = 0
Local $tBuffer = DllStructCreate("byte[" & $iLength & "]")
Local $tBuffer = DllStructCreate("BYTE[" & $iLength & "]")
DllStructSetData($tBuffer, 1, $bData)
DllStructSetData($tBuffer, 1, $bData)
Local $fResult = _WinAPI_WriteFile($hFile, DllStructGetPtr($tBuffer), $iLength, $iWritten)
Local $fSuccess = _WinAPI_WriteFile($hFile, DllStructGetPtr($tBuffer), $iLength, $iWritten)
If @error Then Return SetError(@error, @ScriptLineNumber, 0)
If @error Then Return SetError(@error, @ScriptLineNumber, 0)
If Not $fResult Then Return SetError(-1, @ScriptLineNumber, $iWritten)
If Not $fSuccess Then Return SetError(-1, @ScriptLineNumber, $iWritten)
Return $iWritten
Return $iWritten
EndFunc  ;==>_CommAPI_TransmitData
EndFunc  ;==>_CommAPI_TransmitData
</syntaxhighlight>
</syntaxhighlight>

Revision as of 14:15, 4 April 2014

; #INDEX# =======================================================================================================================
; Name ..........: CommInterface.au3
; Title .........: Communications Functions of Windows API
; Description ...: Communications Functions of Windows API calls that have been translated to AutoIt functions.
; Version Date ..: 2014-04-03
; AutoIt Version : 3.3.8.1
; Link ..........: http://msdn.microsoft.com/en-us/library/aa363194(v=vs.85).aspx
; Tag(s) ........: RS-232, serial port, COM port
; Author(s) .....:
; Dll(s) ........: kernel32.dll
; Error handling : Everytime @extended is set, it is filled with @ScriptLineNumber of the error.
; ===============================================================================================================================

#include-once
#include "CommAPIHelper.au3"
#include "CommUtilities.au3"
#include <WinAPI.au3>
#NoAutoIt3Execute
#AutoIt3Wrapper_Au3Check_Parameters=-q -d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w- 7

; #FUNCTION# ====================================================================================================================
; Name ..........: _CommAPI_ClosePort
; Description ...: CLoses a specified communications device.
; Syntax ........: _CommAPI_ClosePort(Const $hFile)
; Parameters ....: $hFile               - [in] A handle to the communications device.
; Return values .: Success - True
;                  Failure - False
;                  @error  - 1 unable to use the DLL file
;                            2 unknown "return type"
;                            3 "function" not found in the DLL file
;                            4 bad number of parameters
;                            5 bad parameter
;                           -1 function fails (To get extended error information, call _WinAPI_GetLastError or _WinAPI_GetLastErrorMessage)
; Author ........:
; Modified ......:
; Remarks .......:
; Related .......: _CommAPI_OpenPort
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _CommAPI_ClosePort(Const $hFile)
	Local $fSuccess = _WinAPI_CloseHandle($hFile)
	If @error Then Return SetError(@error, 0, False)
	If Not $fSuccess Then Return SetError(-1, @ScriptLineNumber, False)
	Return $fSuccess
EndFunc   ;==>_CommAPI_ClosePort

; #FUNCTION# ====================================================================================================================
; Name ..........: _CommAPI_OpenCOMPort
; Description ...: Opens a COM Port.
; Syntax ........: _CommAPI_OpenCOMPort(Const $iPort[, $iBaudRate = Default[, $iParity = Default[, $iByteSize = Default[,
;                  $iStopBits = Default]]]])
; Parameters ....: $iPort               - [in] A port number.
;                  $iBaudRate           - [in] The baud rate at which the communications device operates.
;                  $iParity             - [in] The parity scheme to be used.
;                  $iByteSize           - [in] Specifies the number of data bits in a character.
;                  $iStopBits           - [in] Specifies the number of stop bits that define the end of a character: 1, 1.5, or 2.
; Return values .: Success - Open handle to a specified communications device
;                  Failure - 0
;                  @error  - 1 unable to use the DLL file
;                            2 unknown "return type"
;                            3 "function" not found in the DLL file
;                            4 bad number of parameters
;                            5 bad parameter
;                            11 struct not a correct struct returned by DllStructCreate
;                            12 element value out of range
;                            13 index would be outside of the struct
;                            14 element data type is unknown
;                            15 index <= 0
;                           -1 function fails (To get extended error information, call _WinAPI_GetLastError or _WinAPI_GetLastErrorMessage)
; Author ........:
; Modified ......:
; Remarks .......:
; Related .......: _CommAPI_OpenPort, _CommAPI_ClosePort, _CommAPI_CreateModeString
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _CommAPI_OpenCOMPort(Const $iPort, Const $iBaudRate = Default, Const $iParity = Default, Const $iByteSize = Default, Const $iStopBits = Default)
	Local $sMode = _CommAPI_CreateModeString($iPort, $iBaudRate, $iParity, $iByteSize, $iStopBits)
	Local $hFile = _CommAPI_OpenPort($sMode)
	If @error Then Return SetError(@error, @extended, 0)
	Return $hFile
EndFunc   ;==>_CommAPI_OpenCOMPort

; #FUNCTION# ====================================================================================================================
; Name ..........: _CommAPI_OpenPort
; Description ...: Opens a specified communications device.
; Syntax ........: _CommAPI_OpenPort(Const $sMode)
; Parameters ....: $sMode               - [in] A device-definition string.
; Return values .: Success - Open handle to a specified communications device
;                  Failure - 0
;                  @error  - 1 unable to use the DLL file
;                            2 unknown "return type"
;                            3 "function" not found in the DLL file
;                            4 bad number of parameters
;                            5 bad parameter
;                            11 struct not a correct struct returned by DllStructCreate
;                            12 element value out of range
;                            13 index would be outside of the struct
;                            14 element data type is unknown
;                            15 index <= 0
;                           -1 function fails (To get extended error information, call _WinAPI_GetLastError or _WinAPI_GetLastErrorMessage)
; Author ........:
; Modified ......:
; Remarks .......:
; Related .......: _CommAPI_OpenCOMPort, _CommAPI_ClosePort, _CommAPI_SetCommState
; Link ..........: http://msdn.microsoft.com/en-us/library/aa365430(v=vs.85).aspx
; Example .......: No
; ===============================================================================================================================
Func _CommAPI_OpenPort(Const $sMode)
	Local $sFileName = "\\.\" & StringLeft($sMode, StringInStr($sMode, ":") - 1)
	Local $hFile = _WinAPI_CreateFile($sFileName, 3, 6)
	If @error Then Return SetError(@error, @ScriptLineNumber, 0)
	If $hFile <= 0 Then Return SetError(-1, @ScriptLineNumber, 0)

	Local $tDCB = DllStructCreate($tagDCB)
	Local $tCommTimeouts = DllStructCreate($tagCOMMTIMEOUTS)

	_CommAPI_BuildCommDCB($sMode, $tDCB)
	If @error Then Return SetError(@error, @extended, 0)

	_CommAPI_SetCommTimeoutsElement($tCommTimeouts, "ReadTotalTimeoutMultiplier", 1)
	If @error Then Return SetError(@error, @extended, 0)

	_CommAPI_SetCommTimeoutsElement($tCommTimeouts, "WriteTotalTimeoutMultiplier", 1)
	If @error Then Return SetError(@error, @extended, 0)

	If Not _CommAPI_SetCommState($hFile, $tDCB) Then Return SetError(@error, @extended, 0)
	If Not _CommAPI_SetCommTimeouts($hFile, $tCommTimeouts) Then Return SetError(@error, @extended, 0)

	Return $hFile
EndFunc   ;==>_CommAPI_OpenPort

; #FUNCTION# ====================================================================================================================
; Name ..........: _CommAPI_ReceiveBinary
; Description ...: Receives data (RxD/RX/RD) to a specified communications device.
; Syntax ........: _CommAPI_ReceiveBinary(Const $hFile[, $iTimeout = 1[, $iMaxLength = 0[, $vSeparator = ""]]])
; Parameters ....: $hFile               - [in] A handle to the communications device.
;                  $iTimeout            - [in] An integer value for total read timeout in milliseconds.
;                                              Is activated only by positive values.
;                  $iMaxLength          - [in] An integer value for maximum length of result.
;                                              Is activated only by positive values.
;                  $vSeparator          - [in] A value which is used as a separator.
;                                              Is activated only by non-empty values.
; Return values .: Success - Received binary data (including separator)
;                  Failure - Received binary data
;                  @error  - 1 unable to use the DLL file
;                            2 unknown "return type"
;                            3 "function" not found in the DLL file
;                            4 bad number of parameters
;                            5 bad parameter
;                           -1 function fails (To get extended error information, call _WinAPI_GetLastError or _WinAPI_GetLastErrorMessage)
;                           -2 timeout
; Author ........:
; Modified ......:
; Remarks .......:
; Related .......: _CommAPI_ReceiveString, _CommAPI_TransmitData
; Link ..........: http://msdn.microsoft.com/en-us/library/aa365467(v=vs.85).aspx
; Example .......: No
; ===============================================================================================================================
Func _CommAPI_ReceiveBinary(Const $hFile, Const $iTimeout = 1, Const $iMaxLength = 0, Const $vSeparator = "")
	Local $bSeparator = Binary($vSeparator)
	Local $iSepLength = BinaryLen($bSeparator)
	Local $fSuccess = False
	Local $tBuffer = DllStructCreate("BYTE")
	Local $pBuffer = DllStructGetPtr($tBuffer)
	Local $iRead = 0
	Local $vResult = Binary("")
	Local $iResLength = 0
	Local $hTimer = TimerInit()
	While True
		$fSuccess = _WinAPI_ReadFile($hFile, $pBuffer, 1, $iRead)
		If @error Then Return SetError(@error, @ScriptLineNumber, $vResult)
		If Not $fSuccess Then Return SetError(-1, @ScriptLineNumber, $vResult)
		If $iRead Then
			$vResult &= BinaryMid(Binary(DllStructGetData($tBuffer, 1)), 1, 1)
			$iResLength = BinaryLen($vResult)
			If $iResLength = $iMaxLength And $iMaxLength > 0 Then Return $vResult
			If $bSeparator = BinaryMid($vResult, 1 + $iResLength - $iSepLength) Then Return $vResult
		Else
			If $vResult And Not $iSepLength Then Return $vResult
			If $iTimeout > 0 And $iTimeout < TimerDiff($hTimer) Then Return SetError(-2, @ScriptLineNumber, $vResult)
		EndIf
	WEnd
	Return $vResult
EndFunc   ;==>_CommAPI_ReceiveBinary

; #FUNCTION# ====================================================================================================================
; Name ..........: _CommAPI_ReceiveString
; Description ...: Receives data (RxD/RX/RD) to a specified communications device.
; Syntax ........: _CommAPI_ReceiveString(Const $hFile[, $iTimeout = 1[, $iMaxLength = 0[, $sSeparator = ""]]])
; Parameters ....: $hFile               - [in] A handle to the communications device.
;                  $iTimeout            - [in] An integer value for total read timeout in milliseconds.
;                                              Is activated only by positive values.
;                  $iMaxLength          - [in] An integer value for maximum length of result.
;                                              Is activated only by positive values.
;                  $sSeparator          - [in] A value which is used as a separator.
;                                              Is activated only by non-empty values.
;                  $iFlag               - [in] Flag for function BinaryToString().
; Return values .: Success - Received string (including separator)
;                  Failure - Received string
;                            Received binary data in case of @error = -3
;                  @error  - 1 unable to use the DLL file
;                            2 unknown "return type"
;                            3 "function" not found in the DLL file
;                            4 bad number of parameters
;                            5 bad parameter
;                           -1 function fails (To get extended error information, call _WinAPI_GetLastError or _WinAPI_GetLastErrorMessage)
;                           -2 timeout
;                           -3 error in BinaryToString
; Author ........:
; Modified ......:
; Remarks .......:
; Related .......: _CommAPI_ReceiveBinary, _CommAPI_TransmitData
; Link ..........: http://msdn.microsoft.com/en-us/library/aa365467(v=vs.85).aspx
; Example .......: No
; ===============================================================================================================================
Func _CommAPI_ReceiveString(Const $hFile, Const $iTimeout = 1, Const $iMaxLength = 0, Const $sSeparator = "", Const $iFlag = 1)
	Local $bResult = _CommAPI_ReceiveBinary($hFile, $iTimeout, $iMaxLength, StringToBinary($sSeparator, $iFlag))
	Local $iError = @error
	Local $iExtended = @extended
	Local $sResult = ""
	If $bResult Then
		$sResult = BinaryToString($bResult, $iFlag)
		If @error Then SetError(-3, @ScriptLineNumber, $bResult)
	EndIf
	Return SetError($iError, $iExtended, $sResult)
EndFunc   ;==>_CommAPI_ReceiveString

; #FUNCTION# ====================================================================================================================
; Name ..........: _CommAPI_TransmitData
; Description ...: Transmits data (TxD/TX/TD) to a specified communications device.
; Syntax ........: _CommAPI_TransmitData(Const $hFile, Const $sData)
; Parameters ....: $hFile               - [in] A handle to the communications device.
;                  $vData               - [in] A string value to transmit.
; Return values .: Success - Number of written bytes
;                  Failure - Number of written bytes
;                  @error  - 1 unable to use the DLL file
;                            2 unknown "return type"
;                            3 "function" not found in the DLL file
;                            4 bad number of parameters
;                            5 bad parameter
;                           -1 function fails (To get extended error information, call _WinAPI_GetLastError or _WinAPI_GetLastErrorMessage)
; Author ........:
; Modified ......:
; Remarks .......:
; Related .......: _CommAPI_ReceiveBinary, _CommAPI_ReceiveString
; Link ..........: http://msdn.microsoft.com/en-us/library/aa365747(v=vs.85).aspx
; Example .......: No
; ===============================================================================================================================
Func _CommAPI_TransmitData(Const $hFile, Const $vData)
	Local $bData = Binary($vData)
	Local $iLength = BinaryLen($vData)
	Local $iWritten = 0
	Local $tBuffer = DllStructCreate("BYTE[" & $iLength & "]")
	DllStructSetData($tBuffer, 1, $bData)
	Local $fSuccess = _WinAPI_WriteFile($hFile, DllStructGetPtr($tBuffer), $iLength, $iWritten)
	If @error Then Return SetError(@error, @ScriptLineNumber, 0)
	If Not $fSuccess Then Return SetError(-1, @ScriptLineNumber, $iWritten)
	Return $iWritten
EndFunc   ;==>_CommAPI_TransmitData
Retrieved from "https://www.autoitscript.com/w/index.php?title=CommInterface.au3&oldid=12353"