CommInterface.au3: Difference between revisions
Jump to navigation
Jump to search
(updated @error handling; new parameter MaxLen for function _CommAPI_ReceiveData; new function _CommAPI_ReceiveLine) |
(fix reading error Chr(128) to Chr(255)) |
||
| Line 4: | Line 4: | ||
; Title .........: Communications Functions of Windows API | ; Title .........: Communications Functions of Windows API | ||
; Description ...: Communications Functions of Windows API calls that have been translated to AutoIt functions. | ; Description ...: Communications Functions of Windows API calls that have been translated to AutoIt functions. | ||
; Version Date ..: 2014-03 | ; Version Date ..: 2014-04-03 | ||
; AutoIt Version : 3.3.8.1 | ; AutoIt Version : 3.3.8.1 | ||
; Link ..........: http://msdn.microsoft.com/en-us/library/aa363194(v=vs.85).aspx | ; Link ..........: http://msdn.microsoft.com/en-us/library/aa363194(v=vs.85).aspx | ||
| Line 150: | Line 150: | ||
; =============================================================================================================================== | ; =============================================================================================================================== | ||
Func _CommAPI_ReceiveData(Const $hFile, Const $iTimeout = 1, Const $iMaxLen = 0) | Func _CommAPI_ReceiveData(Const $hFile, Const $iTimeout = 1, Const $iMaxLen = 0) | ||
Local $tBuffer = DllStructCreate("char") | Local $tBuffer = DllStructCreate("char[2]") | ||
Local $hTimer = TimerInit() | Local $hTimer = TimerInit() | ||
Local $iWritten = 0 | Local $iWritten = 0 | ||
| Line 195: | Line 195: | ||
; =============================================================================================================================== | ; =============================================================================================================================== | ||
Func _CommAPI_ReceiveLine(Const $hFile, Const $sSeparator = @CRLF, Const $iTimeout = 1, Const $iMaxLen = 0) | Func _CommAPI_ReceiveLine(Const $hFile, Const $sSeparator = @CRLF, Const $iTimeout = 1, Const $iMaxLen = 0) | ||
Local $tBuffer = DllStructCreate("char") | Local $tBuffer = DllStructCreate("char[2]") | ||
Local $iLen = StringLen($sSeparator) | Local $iLen = StringLen($sSeparator) | ||
Local $hTimer = TimerInit() | Local $hTimer = TimerInit() | ||
Revision as of 08:39, 3 April 2014
; #INDEX# =======================================================================================================================
; Name ..........: CommInterface.au3
; Title .........: Communications Functions of Windows API
; Description ...: Communications Functions of Windows API calls that have been translated to AutoIt functions.
; Version Date ..: 2014-04-03
; AutoIt Version : 3.3.8.1
; Link ..........: http://msdn.microsoft.com/en-us/library/aa363194(v=vs.85).aspx
; Tag(s) ........: RS-232, serial port, COM port
; Author(s) .....:
; Dll(s) ........: kernel32.dll
; Error handling : Everytime @extended is set, it is filled with @ScriptLineNumber of the error.
; ===============================================================================================================================
#include-once
#include "CommAPIHelper.au3"
#include "CommUtilities.au3"
#include <WinAPI.au3>
#NoAutoIt3Execute
#AutoIt3Wrapper_Au3Check_Parameters=-q -d -w 1 -w 2 -w 3 -w- 4 -w 5 -w 6 -w- 7
; #FUNCTION# ====================================================================================================================
; Name ..........: _CommAPI_ClosePort
; Description ...: CLoses a specified communications device.
; Syntax ........: _CommAPI_ClosePort(Const $hFile)
; Parameters ....: $hFile - [in] A handle to the communications device.
; Return values .: Success - True
; Failure - False
; @error - 1 unable to use the DLL file
; 2 unknown "return type"
; 3 "function" not found in the DLL file
; 4 bad number of parameters
; 5 bad parameter
; Author ........:
; Modified ......:
; Remarks .......:
; Related .......: _CommAPI_OpenPort
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _CommAPI_ClosePort(Const $hFile)
Local $fResult = _WinAPI_CloseHandle($hFile)
If @error Then Return SetError(@error, 0, False)
Return $fResult
EndFunc ;==>_CommAPI_ClosePort
; #FUNCTION# ====================================================================================================================
; Name ..........: _CommAPI_OpenCOMPort
; Description ...: Opens a COM Port.
; Syntax ........: _CommAPI_OpenCOMPort(Const $iPort[, $iBaudRate = Default[, $iParity = Default[, $iByteSize = Default[,
; $iStopBits = Default]]]])
; Parameters ....: $iPort - [in] A port number.
; $iBaudRate - [in] The baud rate at which the communications device operates.
; $iParity - [in] The parity scheme to be used.
; $iByteSize - [in] Specifies the number of data bits in a character.
; $iStopBits - [in] Specifies the number of stop bits that define the end of a character: 1, 1.5, or 2.
; Return values .: Success - The open handle to a specified communications device.
; Failure - 0
; @error - 1 unable to use the DLL file
; 2 unknown "return type"
; 3 "function" not found in the DLL file
; 4 bad number of parameters
; 5 bad parameter
; Author ........:
; Modified ......:
; Remarks .......:
; Related .......: _CommAPI_OpenPort, _CommAPI_ClosePort, _CommAPI_CreateModeString
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _CommAPI_OpenCOMPort(Const $iPort, Const $iBaudRate = Default, Const $iParity = Default, Const $iByteSize = Default, Const $iStopBits = Default)
Local $sMode = _CommAPI_CreateModeString($iPort, $iBaudRate, $iParity, $iByteSize, $iStopBits)
Local $hFile = _CommAPI_OpenPort($sMode)
If @error Then Return SetError(@error, @extended, 0)
Return $hFile
EndFunc ;==>_CommAPI_OpenCOMPort
; #FUNCTION# ====================================================================================================================
; Name ..........: _CommAPI_OpenPort
; Description ...: Opens a specified communications device.
; Syntax ........: _CommAPI_OpenPort(Const $sMode)
; Parameters ....: $sMode - [in] A device-definition string.
; Return values .: Success - The open handle to a specified communications device.
; Failure - 0
; @error - 1 unable to use the DLL file
; 2 unknown "return type"
; 3 "function" not found in the DLL file
; 4 bad number of parameters
; 5 bad parameter
; 11 struct not a correct struct returned by DllStructCreate
; 12 element value out of range
; 13 index would be outside of the struct
; 14 element data type is unknown
; 15 index <= 0
; -1 function fails (To get extended error information, call _WinAPI_GetLastError or _WinAPI_GetLastErrorMessage)
; Author ........:
; Modified ......:
; Remarks .......:
; Related .......: _CommAPI_OpenCOMPort, _CommAPI_ClosePort, _CommAPI_SetCommState
; Link ..........: http://msdn.microsoft.com/en-us/library/aa365430(v=vs.85).aspx
; Example .......: No
; ===============================================================================================================================
Func _CommAPI_OpenPort(Const $sMode)
Local $sFileName = "\\.\" & StringLeft($sMode, StringInStr($sMode, ":") - 1)
Local $hFile = _WinAPI_CreateFile($sFileName, 3, 6)
If @error Then Return SetError(@error, @ScriptLineNumber, 0)
If $hFile <= 0 Then Return SetError(-1, @ScriptLineNumber, 0)
Local $tDCB = DllStructCreate($tagDCB)
Local $tCommTimeouts = DllStructCreate($tagCOMMTIMEOUTS)
_CommAPI_BuildCommDCB($sMode, $tDCB)
If @error Then Return SetError(@error, @extended, 0)
_CommAPI_SetCommTimeoutsElement($tCommTimeouts, "ReadTotalTimeoutMultiplier", 1)
If @error Then Return SetError(@error, @extended, 0)
_CommAPI_SetCommTimeoutsElement($tCommTimeouts, "WriteTotalTimeoutMultiplier", 1)
If @error Then Return SetError(@error, @extended, 0)
If Not _CommAPI_SetCommState($hFile, $tDCB) Then Return SetError(@error, @extended, 0)
If Not _CommAPI_SetCommTimeouts($hFile, $tCommTimeouts) Then Return SetError(@error, @extended, 0)
Return $hFile
EndFunc ;==>_CommAPI_OpenPort
; #FUNCTION# ====================================================================================================================
; Name ..........: _CommAPI_ReceiveData
; Description ...: Receives data (RxD/RX/RD) to a specified communications device.
; Syntax ........: _CommAPI_ReceiveData(Const $hFile[, $iTimeout = 1[, $iMaxLen = 0]])
; Parameters ....: $hFile - [in] A handle to the communications device.
; $iTimeout - [in] An integer value for total read timeout in milliseconds.
; Is activated only by positive values.
; $iMaxLen - [in] An integer value for maximum length of result.
; Is activated only by positive values.
; Return values .: Success - Received string
; Failure - Received or empty string
; @error - 1 unable to use the DLL file
; 2 unknown "return type"
; 3 "function" not found in the DLL file
; 4 bad number of parameters
; 5 bad parameter
; -2 timeout
; Author ........:
; Modified ......:
; Remarks .......: If the result contains Chr(0), you should convert the result with function Binary().
; Related .......: _CommAPI_TransmitData
; Link ..........: http://msdn.microsoft.com/en-us/library/aa365467(v=vs.85).aspx
; Example .......: No
; ===============================================================================================================================
Func _CommAPI_ReceiveData(Const $hFile, Const $iTimeout = 1, Const $iMaxLen = 0)
Local $tBuffer = DllStructCreate("char[2]")
Local $hTimer = TimerInit()
Local $iWritten = 0
Local $sResult = ""
While 1
_WinAPI_ReadFile($hFile, DllStructGetPtr($tBuffer), 1, $iWritten)
If @error Then Return SetError(@error, @ScriptLineNumber, $sResult)
If $iWritten Then
$sResult &= DllStructGetData($tBuffer, 1)
If $iMaxLen > 0 And $iMaxLen = StringLen($sResult) Then Return $sResult
Else
If $sResult Then Return $sResult
If $iTimeout >= 0 And $iTimeout < TimerDiff($hTimer) Then Return SetError(-2, @ScriptLineNumber, $sResult)
EndIf
WEnd
Return $sResult
EndFunc ;==>_CommAPI_ReceiveData
; #FUNCTION# ====================================================================================================================
; Name ..........: _CommAPI_ReceiveLine
; Description ...: Receives data (RxD/RX/RD) to a specified communications device.
; Syntax ........: _CommAPI_ReceiveLine(Const $hFile[, $sSeparator = @CRLF[, $iTimeout = 1[, $iMaxLen = 0]]])
; Parameters ....: $hFile - [in] A handle to the communications device.
; $sSeparator - [in] A string value which is used as a separator.
; $iTimeout - [in] An integer value for total read timeout in milliseconds.
; Is activated only by positive values.
; $iMaxLen - [in] An integer value for maximum length of result.
; Is activated only by positive values.
; Return values .: Success - Received string including separator
; Failure - Received or empty string
; @error - 1 unable to use the DLL file
; 2 unknown "return type"
; 3 "function" not found in the DLL file
; 4 bad number of parameters
; 5 bad parameter
; -2 timeout
; Author ........:
; Modified ......:
; Remarks .......: If the result contains Chr(0), you should convert the result with function Binary().
; To remove separator from result, you can use function StringTrimRight($sResult, StringLen($sSeparator)).
; Related .......: _CommAPI_TransmitData
; Link ..........: http://msdn.microsoft.com/en-us/library/aa365467(v=vs.85).aspx
; Example .......: No
; ===============================================================================================================================
Func _CommAPI_ReceiveLine(Const $hFile, Const $sSeparator = @CRLF, Const $iTimeout = 1, Const $iMaxLen = 0)
Local $tBuffer = DllStructCreate("char[2]")
Local $iLen = StringLen($sSeparator)
Local $hTimer = TimerInit()
Local $iWritten = 0
Local $sResult = ""
While 1
_WinAPI_ReadFile($hFile, DllStructGetPtr($tBuffer), 1, $iWritten)
If @error Then Return SetError(@error, @ScriptLineNumber, $sResult)
If $iWritten Then
$sResult &= DllStructGetData($tBuffer, 1)
If $iMaxLen > 0 And $iMaxLen = StringLen($sResult) Then Return $sResult
If StringRight($sResult, $iLen) == $sSeparator Then Return $sResult
Else
If $iTimeout >= 0 And $iTimeout < TimerDiff($hTimer) Then Return SetError(-2, @ScriptLineNumber, $sResult)
EndIf
WEnd
Return $sResult
EndFunc
; #FUNCTION# ====================================================================================================================
; Name ..........: _CommAPI_TransmitData
; Description ...: Transmits data (TxD/TX/TD) to a specified communications device.
; Syntax ........: _CommAPI_TransmitData(Const $hFile, Const $sData)
; Parameters ....: $hFile - [in] A handle to the communications device.
; $sData - [in] A string value to transmit.
; Return values .: Success - The number of bytes written.
; Failure - 0
; @error - 1 unable to use the DLL file
; 2 unknown "return type"
; 3 "function" not found in the DLL file
; 4 bad number of parameters
; 5 bad parameter
; Author ........:
; Modified ......:
; Remarks .......:
; Related .......: _CommAPI_ReceiveData
; Link ..........: http://msdn.microsoft.com/en-us/library/aa365747(v=vs.85).aspx
; Example .......: No
; ===============================================================================================================================
Func _CommAPI_TransmitData(Const $hFile, Const $sData)
Local $iWritten = 0
Local $tBuffer = DllStructCreate("byte[" & StringLen($sData) & "]")
DllStructSetData($tBuffer, 1, $sData)
_WinAPI_WriteFile($hFile, DllStructGetPtr($tBuffer), StringLen($sData), $iWritten)
If @error Then Return SetError(@error, @ScriptLineNumber, 0)
Return $iWritten
EndFunc ;==>_CommAPI_TransmitData