id	summary	reporter	owner	description	type	status	milestone	component	version	severity	resolution	keywords	cc
511	GUICtrlCreateTab - doc precision	Zedna		"Please add folowing:

'''When you create control on the Tab by UDF function (_GUICtrlCreate) and not by internal AutoIt's function (GUICtrlCreate) you must show/hide this control yourself.'''

Also this example can be added as workaround example for this situation (mixed native/UDF controls on Tab)


{{{
#include <WindowsConstants.au3>
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <IPAddressConstants.au3>
#include <TabConstants.au3>
#include <GuiIPAddress.au3>
#include <GuiTab.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate(""Form1"", 593, 453, 193, 115)
$Tab1 = GUICtrlCreateTab(16, 24, 521, 385)
$hTab = GUICtrlGetHandle($Tab1)
GUICtrlSetResizing(-1, $GUI_DOCKWIDTH+$GUI_DOCKHEIGHT)
$TabSheet1 = GUICtrlCreateTabItem(""TabSheet1"")
$IPAddress1 = _GUICtrlIpAddress_Create($Form1, 56, 112, 130, 21)
_GUICtrlIpAddress_Set($IPAddress1, ""0.0.0.0"")
$TabSheet2 = GUICtrlCreateTabItem(""TabSheet2"")
$MyButton1 = GUICtrlCreateButton(""MyButton1"", 104, 120, 100, 30, 0)
GUICtrlCreateTabItem("""")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

GUIRegisterMsg($WM_NOTIFY, ""WM_NOTIFY"")

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndTab, $fValid
    $hWndTab = $hTab

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, ""hWndFrom""))
    $iIDFrom = DllStructGetData($tNMHDR, ""IDFrom"")
    $iCode = DllStructGetData($tNMHDR, ""Code"")
    Switch $hWndFrom
        Case $hWndTab
            Switch $iCode
                Case $TCN_SELCHANGE
                    If _GUICtrlTab_GetCurSel($hTab) = 0 Then ; zero based index of current selected TabItem
                        _GUICtrlIpAddress_ShowHide ($IPAddress1, @SW_SHOW)
                    Else
                        _GUICtrlIpAddress_ShowHide ($IPAddress1, @SW_HIDE)
                    EndIf
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY
}}}

Here is link to related post:
[http://www.autoitscript.com/forum/index.php?showtopic=72894&st=0&p=531772&#entry531772]"	Feature Request	closed		Documentation		None	Rejected