Ticket #492: GDIPlus_SomeImageGetISetMultiFrameFunctions.au3

File GDIPlus_SomeImageGetISetMultiFrameFunctions.au3, 5.5 KB (added by smashly, 17 years ago)

GDIPlus_SomeImageGetISetMultiFrameFunctions.au3

Line 
1#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
2#include <GDIPlus.au3>
3
4; #FUNCTION# ====================================================================================================================
5; Name...........: _GDIPlus_ImageGetFrameDimensionCount
6; Description ...: Gets the number of frame dimensions in an Image object.
7; Syntax.........: _GDIPlus_ImageGetFrameDimensionCount($hImage)
8; Parameters ....: $hImage      - Handle to an Image object
9; Return values .: Success      - Returns the number of frame dimensions in an Image object.
10;                  Failure      - @error <> 0
11; Author ........: Smashly
12; Modified.......:
13; Remarks .......:
14; Related .......: _GDIPlus_ImageGetFrameDimensionList, _GDIPlus_ImageGetFrameCount, _GDIPlus_ImageSelectActiveFrame
15; Link ..........; @@MsdnLink@@ GdipImageGetFrameDimensionsCount
16; Example .......;
17; ===============================================================================================================================
18Func _GDIPlus_ImageGetFrameDimensionCount($hImage)
19    Local $aResult
20   
21        $aResult = DllCall($ghGDIPDll, "int", "GdipImageGetFrameDimensionsCount", "hwnd", $hImage, "int*", 0)
22        If @error Then Return SetError(@error, @extended, -1)
23        Return SetError($aResult[0], 0, $aResult[2])
24EndFunc
25
26; #FUNCTION# ====================================================================================================================
27; Name...........: _GDIPlus_ImageGetFrameDimensionList
28; Description ...: Gets the identifiers for the frame dimensions of an Image object.
29; Syntax.........: _GDIPlus_ImageGetFrameDimensionList($hImage, $pGUID, $iFDC)
30; Parameters ....: $hImage      - Handle to an Image object
31;                  $pGUID       - Pointer to a $tagGUID struct.
32;                  $iFDC        - Frame Dimension Count as returned by _GDIPlus_ImageGetFrameDimensionCount
33; Return values .: Success      - True
34;                  Failure      - False
35; Author ........: Smashly
36; Modified.......:
37; Remarks .......:  This function will set the data in the $tagGUID struct.
38; Related .......: _GDIPlus_ImageGetFrameDimensionCount, _GDIPlus_ImageGetFrameCount,
39;                  _GDIPlus_ImageSelectActiveFrame, $tagGUID
40; Link ..........; @@MsdnLink@@ GdipImageGetFrameDimensionsList
41; Example .......;
42; ===============================================================================================================================
43Func _GDIPlus_ImageGetFrameDimensionList($hImage, $pGUID, $iFDC)
44    Local $aResult
45       
46        $aResult = DllCall($ghGDIPDll, "int", "GdipImageGetFrameDimensionsList", "hwnd", $hImage, "ptr", $pGUID, "int", $iFDC)
47    If @error Then Return SetError(@error, @extended, False)
48        Return SetError($aResult[0], 0, $aResult[0] = 0)
49EndFunc
50
51; #FUNCTION# ====================================================================================================================
52; Name...........: _GDIPlus_ImageGetFrameCount
53; Description ...: Gets the number of frames in a specified dimension of an Image object.
54; Syntax.........: _GDIPlus_ImageGetFrameCount($hImage, $pGUID)
55; Parameters ....: $hImage      - Handle to an Image object
56;                  $pGUID       - Pointer to a $tagGUID struct.
57;                  $iFDC        - Frame Dimension Count as returned by _GDIPlus_ImageGetFrameDimensionCount
58; Return values .: Success      - Returns the number of frames in the specified dimension of an Image object.
59;                  Failure      - @error <> 0
60; Author ........: Smashly
61; Modified.......:
62; Remarks .......:
63; Related .......:  _GDIPlus_ImageGetFrameDimensionCount, _GDIPlus_ImageGetFrameDimensionList,
64;                   _GDIPlus_ImageSelectActiveFrame, $tagGUID
65; Link ..........; @@MsdnLink@@ GdipImageGetFrameCount
66; Example .......;
67; ===============================================================================================================================
68Func _GDIPlus_ImageGetFrameCount($hImage, $pGUID)
69        Local $aResult
70       
71        $aResult = DllCall($ghGDIPDll, "int", "GdipImageGetFrameCount", "hwnd", $hImage, "ptr", $pGUID, "int*", 0)     
72        If @error Then Return SetError(@error, @extended, -1)
73        Return SetError($aResult[0], 0, $aResult[3])
74EndFunc
75
76; #FUNCTION# ====================================================================================================================
77; Name...........: _GDIPlus_ImageSelectActiveFrame
78; Description ...: Selects the frame in an Image object specified by a dimension and an index..
79; Syntax.........: _GDIPlus_ImageSelectActiveFrame($hImage, $pGUID, $iFDC)
80; Parameters ....: $hImage      - Handle to an Image object
81;                  $pGUID       - Pointer to a $tagGUID struct.
82;                  $iIndex      - Index of the frame to set active.
83; Return values .: Success      - True
84;                  Failure      - False
85; Author ........: Smashly
86; Modified.......:
87; Remarks .......: 
88; Related .......: _GDIPlus_ImageGetFrameCount, _GDIPlus_ImageGetFrameDimensionCount, _GDIPlus_ImageGetFrameCount, $tagGUID
89; Link ..........; @@MsdnLink@@ GdipImageSelectActiveFrame
90; Example .......;
91; ===============================================================================================================================
92Func _GDIPlus_ImageSelectActiveFrame($hImage, $pGUID, $iIndex)
93        Local $aResult
94       
95        $aResult = DllCall($ghGDIPDll, "int", "GdipImageSelectActiveFrame", "hwnd", $hImage, "ptr", $pGUID, "int", $iIndex)
96        If @error Then Return SetError(@error, @extended, False)
97        Return SetError($aResult[0], 0, $aResult[0] = 0)
98EndFunc