A little problem, how to set the text color of a statusbar? :)

[sunsunshine]

Statusbar,how to set the text color ?

[MrCreatoR]

I would use simple method:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
;

$hGUI = GUICreate("_GUICtrlSimpleStatusBar_Create Example", 400, 300)

$Input = GUICtrlCreateInput("New StatusBar Text", 50, 50, 200, 20)

$SetStatusData_Button = GUICtrlCreateButton("Set Text", 270, 50, 60, 20)

$StatusBar_Label = _GUICtrlSimpleStatusBar_Create($hGUI, "", 20)
_GUICtrlSimpleStatusBar_SetData($StatusBar_Label, "StatusBar Text", 0x0000FF, 0xFFFFFF, 11, 800, 0, "Georgia")

GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $SetStatusData_Button
            _GUICtrlSimpleStatusBar_SetData($StatusBar_Label, GUICtrlRead($Input))
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
Wend

Func _GUICtrlSimpleStatusBar_Create($hWnd_Parent, $sStatus_Text, $iHeight=16)
    Local $aGUI_Pos = WinGetPos($hWnd_Parent)
    Local $aGUI_ClientSize = WinGetClientSize($hWnd_Parent)
    Local $iCaptionHeight = $aGUI_Pos[3] - $aGUI_ClientSize[1]
    
    Local $nRet_StatusBar_Label = GUICtrlCreateLabel(" " & $sStatus_Text, _
        0, $aGUI_Pos[3]-$iHeight-$iCaptionHeight, $aGUI_Pos[2], $iHeight, $SS_SUNKEN)
    
    Return $nRet_StatusBar_Label
EndFunc

Func _GUICtrlSimpleStatusBar_SetData($nStatus,$sTxt,$nFntClr=-1,$nFntBkClr=-1,$iFntSz=-1,$iFntWeight=-1,$iFntAttr=-1,$sFntName=-1)
    GUICtrlSetData($nStatus, " " & $sTxt)
    GUICtrlSetFont($nStatus, $iFntSz, $iFntWeight, $iFntAttr, $sFntName)
    
    If $nFntClr <> -1 Then GUICtrlSetColor($nStatus, $nFntClr)
    If $nFntBkClr <> -1 Then GUICtrlSetBkColor($nStatus, $nFntBkClr)
    
    Return 1
EndFunc

[MrCreatoR]

But there is a solution for system statusbar control.

[sunsunshine]

Thank you very much, maybe we can use WINAPI function to solve this problem.

[MrCreatoR]

Thank you very much, maybe we can use WINAPI function to solve this problem.

It's used (and it's working) in the example from that link i gave you.